perm filename UUOCON[KA,SYS] blob
sn#227162 filedate 1976-07-22 generic text, type C, neo UTF8
COMMENT ⊗ VALID 00104 PAGES
C REC PAGE DESCRIPTION
C00001 00001
C00009 00002 UUOCON NON-IO SECTION
C00012 00003 HERE WE FIGURE OUT WHOSE FAULT THE UUO IS AND WHO IT IS FOR
C00016 00004 UUO SETUP ROUTINES FOR P2
C00018 00005 UUOX - UUO FROM EXEC AT INTERUPT LEVEL. TRY TO FIGURE OUT WHAT TO DO
C00020 00006 SAVE USER'S ACS, GET A PDL
C00025 00007 USRXIT - RETURN FROM UUO ROUTINE.
C00028 00008 RESTORE ACS AND DISMISS UUO
C00032 00009 UUOSIM - UUO SIMULATION. UUOSY4
C00035 00010 CHNSET ROUTINE TO ASSIGN A CHANNEL NUMBER
C00037 00011 TABLE OF UUO DISPATCH ADDRESSES
C00039 00012 IOT UUO DISPATCH TABLE
C00041 00013 CALL AND CALLI
C00044 00014 CALL UUO DISPATCH TABLE
C00047 00015 STANFORD CALLIS
C00054 00016 MACROS TO DEFINE CALLI TABLES
C00055 00017 EXIT UUO ROUTINE
C00058 00018 RESET UUO ROUTINE
C00061 00019 RESETSEG - ROUTINE TO RESET ONE'S UPPER SEGMENT
C00062 00020 APRDKL ROUTINE TO KILL ANY CLOCK INTERRUPT REQUESTS FOR JOB J
C00063 00021 APRENB, SETPOV - ROUTINE TO SET UP APR FOR USER TRAPPING, PDLOV TRAP
C00066 00022 PEEK, SWITCH, PJOB, DATE, DAYCNT, ACCTIM, TIMER, JOBTIM, MSTIME UUO'S. STOTAC
C00069 00023 SLEEP PUT JOB TO SLEEP FOR NSECONDS
C00070 00024 DVCHR, DEVNUM
C00072 00025 GETPPN -- DSKPPN
C00075 00026 SETNAM, SETCRD, SETDDT, GETNAM
C00077 00027 WAIT, GETLN, SPCWAR (SPWBUT), EIOTM, LIOTM
C00078 00028 CRKSER -- READ THE PETIT CLOCK. DATIME, DAT2, VENTIM
C00082 00029 LOGIN UUO. FOR LOGIN CUSP ONLY.
C00085 00030 ROUTINE TO SET UP SCHEDULER DATA STRUCTURE FOR A JOB
C00086 00031 SETPRV, GETPRV
C00089 00032 RLEVEL, SLEVEL, SETRES - SERVICE LEVEL UUOS
C00096 00033 LOGOUT UUO
C00097 00034 SWAP UUO, RUN UUO
C00099 00035 SWAP UUO
C00104 00036 ROUTINE TO PICK UP BITS OF USER'S GOODIE TABLE
C00108 00037 SWAP UUO - LOG IN NEW JOB AND RUN THIS ON IT - PHANTOM STARTUP
C00112 00038 PNAME, USTAT
C00114 00039 TTYIOS, GET A TELETYPE'S DEVIOS
C00116 00040 WAKEME
C00119 00041 TRANSLATE SYSTEM CALL TO/FROM SIXBIT.
C00122 00042 CALTU: ANDI TAC1,777000
C00124 00043 CALT2: MOVSI TAC1,-IUUMAX*2-40 TOTAL # MAJOR OPCODES
C00126 00044 BEGIN SEGUUO ↔ SUBTTL UUO'S FOR HIGH SEGMENTS SETPR2, GETHI
C00131 00045 HERE WE ADDRESS CHECK HIS PR REQUEST
C00133 00046 GETPR2
C00134 00047 REMAP UUO, ALSO SEGXIT, SEGXT1 - COMMON SEGMENT UUO EXIT ROUTINE
C00139 00048 REMAP1 - INTIALIZE THE CONTENTS OF THE NEW SEGMENT.
C00144 00049 BLTUP - FAST UPWARDS BLT
C00150 00050 SETUWP UUO TO SET OR CLEAR USER WRITE-PROTECT BIT
C00153 00051 UNPURE, UNPURS
C00163 00052 CORE2
C00167 00053 ATTSEG - ATTACH HIGH SEGMENT
C00171 00054 SEARCH FOR A SEGMENT OF A GIVEN NAME
C00173 00055 DETSEG DETACH SEGMENT
C00176 00056 SEGNUM, SEGSIZ, SEGNAM
C00178 00057 SETNM2 CALLING . . .
C00181 00058 LINKUP
C00182 00059 RETURNS LIST OF JOB NUMBERS WHO POINT TO YOUR UPPER SEGMENT.
C00183 00060 SET PROTECTION ON A HIGH SEGMENT
C00185 00061 INTUUO RUNMSK, INTORM, INTACM, INTENS, INTIIP, INTIRQ
C00187 00062 INTENB - ENABLE INTERRUPTS . . .
C00189 00063 CLKENB, CLKENA - ENABLE FOR USER CLOCK INTERRUPTS
C00191 00064 DISMISS, DEBREAK
C00193 00065 INTGEN, USKIP, UWAIT, IWAIT
C00196 00066 IENBW, INTMSK, IMCALL, IMSKST, IMSKCL
C00198 00067 CLKINT UUO (CLKUUO) START UP A CLOCKED I-LEVEL JOB
C00199 00068 INTUUO - INTDEJ, IMSTW
C00201 00069 IWKMSK, IMSKCR
C00202 00070 INTDMP
C00204 00071 GXJOBN. INTDR1,INTDR2, ETC.
C00207 00072 INTIPI
C00209 00073 UUOCON - STANFORD SPECIAL IO ROUTINES CHNSTS, BUFLEN
C00210 00074 ROUTINE TO GET THE TIME CELLS AND CLEAR THEM
C00212 00075 RETURNS A CODE TELING WHETHER A JOB NAME IS LOGGED IN
C00214 00076 DEVUSE - HOW MANY JOBS ARE WAITING FOR A PARTICULAR DEVICE.
C00218 00077 JOBRD
C00226 00078 TMPCOR UUO - BEHAVES AS DESCRIBED IN DEC MANUAL
C00232 00079 FIND REQUESTED TMPCOR FILE
C00238 00080 MAIL UUO, FNDJOB
C00244 00081 UUOCON IO SECTION
C00246 00082 IOPUSH, IOPOP, IOPDL
C00251 00083 CLOSE UUO - CALLING SEQUENCE
C00252 00084 CLOSE UUO, CLOSE INPUT - WAIT FOR IO TO FINISH, FLUSH BUFFERS - CLOSE1
C00256 00085 CLOSE OUTPUT
C00260 00086 INBUF - CALLING SEQUENCE
C00261 00087 UOUTBF, UINBF, MINBF, MOUTBF. INBUF, OUTBUF, UINBF, UOUTBF - SETUP BUFFERS
C00265 00088 INIT AND OPEN UUOS
C00268 00089 INIT CODE - FIRST FIND DEVICE AND TRY TO ASSIGN IT
C00277 00090 UNITW. ASK HIM IF HE IS WILLING TO WAIT FOR THE DEVICE
C00281 00091 ENTER, LOOKUP - LONG DISPATCH TABLE UUOS
C00283 00092 RENAME, UTPCLR, USETO, USETI, UGETF, MTAPE
C00285 00093 SETFILE - GET A FILE NAME FROM USER'S TERMINAL
C00286 00094 INPUT UUO
C00288 00095 INPUT UUO.
C00294 00096 MORE INPUT - BCHECK, CALLIN, INPUTF, INDMP
C00297 00097 OUTPUT UUO - CALLING SEQUENCE
C00300 00098 UOUT - OUTPUT UUO
C00303 00099 OUT
C00310 00100 RELEASE A DEVICE
C00314 00101 RELDVW (RELEAS) - IF THERE IS ANYONE WAITING FOR THE DEVICE WAKE HIM UP.
C00315 00102 STATO, STATZ, GETSTS UUOS. USTATO, USTATZ, USTATS
C00317 00103 TIN, TOUT - IN AND OUT UUOS.
C00318 00104 SPACEWAR UUOS
C00319 ENDMK
C⊗;
SUBTTL UUOCON NON-IO SECTION
COMMENT %
UUOCON consists of the UUO trap handler, the CALL UUO routines, the
non-IO routines, and the device independent IO UUO routines. Some
UUOs dispatch to other routines outside of UUOCON.
Only System UUOs trap to the system. User UUOs (001 to 037) are
stored in user's 40 and execute user's 41 (note this is a special
feature on the PDP-6). On the PDP-6 System UUOs are stored in 40 and
execute 41. On the KA10, System UUOs are stored in 140 and execute
141.
If called from user mode, the System UUO trap routine will first save
the current ACs in the user's locations 0-17. (If a UUO is called
from the EXEC at UUO level, the user's ACs have already been saved in
relative 0-17.) Then the following ACs are loaded up before
dispatching:
P Pushdown pointer in system free storage.
J Current job number.
PROG JBTPAG of current job.
UUO The contents of loc 40 (or 140)
(In CALL and CALLI, the right half of UUO is the
same as the AC field of the UUO).
DDB Address of the device data block for this IO channel
IOS Device IO status word
DSER Address of the device service routine dispatch table.
UCHN The AC field of UUO (User's IO channel number).
TAC (In CALL and CALLI, TAC contains the user's ac)
The return address is placed in UUOPC(J), and the appropriate UUO
routine is called via PUSHJ P,. All UUO routines should return to
UUOCON via POPJ P, or by JRST CPOPJ1 which will cause the UUO to skip
return to the user. Upon returning from the UUO routine, UUOCON will
restore the ACs (if called from user mode), restore the APR
conditions, and return if the job is still runnable.
Since parts of UUOCON are not reentrant, care must be exercised if
any attempt is made to call a UUO from interrupt level. See the code
at INTRUN in CLKSER for one attempt at making UUOCON reentrant.
%
;HERE WE FIGURE OUT WHOSE FAULT THE UUO IS AND WHO IT IS FOR
;140/ 0 ;IMAGE OF THE UUO
;141/ JSR UUO0 ;TRAP INSTRUCTION
;UUO0/ 0 ;TRAP ADDRESS STORED HERE BY JSR
;UUO0+1/ JRST UUO1
;160/ 0 ;IMAGE OF ILLEGAL INSTR (105-127)
;161/ JSR UUO2
;UUO2/ 0
;UUO2+1/ JRST UUO3
IFKL10,<
↑KLUUOH:MOVEM 17,UUO.SA+17
MOVEI 17,UUO.SA
BLT 17,UUO.SA+16
MOVE 17,UUO.SA+17
DATAO KLPAG,[400100,,0] ;SET AC CONTEXT: CURRENT = 0, PREV = 1
EXCH TAC,KLUPT+425 ;GET PC OF THE UUO
MOVEM TAC,UUO0+P1PID ;STORE PC WHERE WE'LL LOOK FOR IT
EXCH TAC,KLUPT+425 ;RESTORE TAC. FALL INTO UUO1
>;IFKL10
NOKL10,<
↑UUO3: EXCH TAC,UUO2+P1PID ;TRAP TO LOCATION 160.
MOVEM TAC,UUO0+P1PID ;ILLEGAL FOR NOW.
MOVE TAC,@UU2LOC+P1PID
MOVEM TAC,@UUOLOC+P1PID
MOVE TAC,UUO2+P1PID ;RESTORE TAC.
↑UUO1: MOVEM 17,UUO.SA+17 ;SAVE ALL AC'S FOR ILLUUO FROM EXEC
MOVEI 17,UUO.SA
BLT 17,UUO.SA+16
>;NOKL10
MOVE 17,UUO.SA+17 ;RESTORE AC 17
CONSO PI,177⊗8 ;ARE WE AT INTERRUPT LEVEL?
JRST NOPCK ;NO.
EXCH TAC,UUO0+P1PID ;SAVE TAC, GET PC OF UUO + 1
TLNN TAC,USRMOD ;USER MODE?
JRST UUOX ;UUO FROM EXEC WHILE PI IN PROG - ILLEGAL
EXCH TAC,UUO0+P1PID ;RESTORE TAC
NOPCK: SKIPN SPWUUF+P1PID ;ARE WE RUNNING SPACEWAR NOW?
JRST UUO1B ;NO.
NOKL10,< MOVEM 17,SPWSAC+17
MOVEI 17,SPWSAC
BLT 17,SPWSAC+16 ;STUFF THE SPACEWAR AC'S AWAY. >
MOVEI PID,P1PID
JRST SPWUUO ;LET SPWSER PROCESS IT
UUO1B: MOVEM 17,USRSAV+P1PID ;SAVE AC 17
MOVE 17,UUO0+P1PID ;GET PROCESSOR FLAGS
TLNE 17,USRMOD ;IS UUO FROM MONITOR?
JRST UUO1A ;NO. ORDINARY FROM USER MODE
MOVE DAT,UUO0+P1PID ;UUO FROM EXEC - DON'T SAVE ACS.
MOVEI PID,P1PID
MOVE UUO,@UUOLOC(PID)
MOVE J,JOB(PID)
JRST UUOSY1 ;UUO FROM SYSTEM
UUO1A: SKIPE JOB+P1PID ;IS A JOB RUNNING?
JRST UUOSYS ;HAPPY
MOVEI PID,P1PID ;THERE IS NO JOB DATA AREA.
JRST NULJB ;RESTART THE AILING NULL JOB.
;UUO SETUP ROUTINES FOR P2
↑P2UUO3:EXCH TAC,UUO2+P2PID ;TRAP AT 60.
MOVEM TAC,UUO0+P2PID
MOVE TAC,@UU2LOC+P2PID
MOVEM TAC,@UUOLOC+P2PID ;SIMULATE TRAP TO 40
MOVE TAC,UUO2+P2PID ;RESTORE TAC.
↑P2UUO1:
IFN PRCONF-2,<
IFKL10,< SKPNKL ;KL10 LUUOS TRAP TO EXEC 40-41
JRST KLLUUO ;KL ISN'T SUPPOSED TO DO THIS! >;IFKL10
>;IFN PRCONF-2 ;SYSTEMS EXCEPT KA10 IS P2.
CONSO PI,177⊗8 ;TRAP AT 40. INTERRUPT LEVEL?
JRST P2NOPCK ;NO.
EXCH TAC,UUO0+P2PID
TLNN TAC,USRMOD ;FROM USER MODE?
JRST P2UUOX ;NO, LOSE
EXCH TAC,UUO0+P2PID
P2NOPCK:SKIPN SPWUUF+P2PID
JRST P2UU1B ;NOT SPACEWAR LEVEL
MOVEM 17,SP2SAC+17
MOVEI 17,SP2SAC
BLT 17,SP2SAC+16 ;SAVE SPACEWAR AC'S
MOVEI PID,P2PID
JRST SPWUUO ;LET SPWSER THINK ABOUT THIS
P2UU1B: MOVEM 17,USRSAV+P2PID ;SAVE AC 17
MOVE 17,UUO0+P2PID ;GET PROCESSOR FLAGS
TLNE 17,USRMOD ;IS UUO FROM MONITOR?
JRST P2UU1A ;USER LEVEL UUO
MOVE DAT,UUO0+P2PID ;SYSTEM UUO
MOVEI PID,P2PID
MOVE UUO,@UUOLOC(PID)
MOVE J,JOB(PID)
JRST UUOSY1
P2UU1A: SKIPLE 17,JOB+P2PID ;IS THERE A JOB RUNNING?
JRST U2OSYS ;THERE IS ONE.
MOVEI PID,P2PID ;NO CORE FOR JOB
JRST NULJB ;MUST BE AILING NULL JOB
;UUOX - UUO FROM EXEC AT INTERUPT LEVEL. TRY TO FIGURE OUT WHAT TO DO
UUOX: EXCH TAC,UUO0+P1PID ;RESTORE TAC, UUO0
CONO PI,PIOFF ;HOLD EVERYTHING
EXCH P,ERRPD+P1PID ;GET A PDL
PUSHACS
MOVEI PID,P1PID
JRST UUOX1
P2UUOX: EXCH TAC,UUO0+P2PID
CONO PI,PIOFF
EXCH P,ERRPD+P2PID
PUSHACS
MOVEI PID,P2PID
UUOX1: SOS UUO0(PID) ;FIX UP ADDRESS FOR PRINTING AND RETURN
PUSHJ P,DISMES
ASCIZ /UUO FROM EXEC WHILE PI IN PROGRESS.
PI = /
CONI PI,TAC
PUSHJ P,DISLOC
PUSHJ P,DISERR
[ASCIZ/
P = /]
DISARG OCT,<ERRPD(PID)> ;OLD STACK
[ASCIZ/ C(P) = /]
-1
HRRZ TAC,ERRPD(PID)
MOVE TAC,(TAC)
PUSHJ P,DISOCT
PUSHJ P,DISERR
[ASCIZ/
PC = /]
DISARG OCT,<UUO0(PID)>
[ASCIZ/ UUO = /]
DISARG OCT,<@UUOLOC(PID)>
[ASCIZ/
(WILL RETURN VIA JRST 2,@UUO0 AFTER TURNING ON PIS)
/]
-1
PUSHJ P,SYSFIX
JFCL ;COULDN'T FIX ERROR
JFCL ;COULDN'T FIND ERROR
PUSHJ P,DISFLUSH ;FIXED AN ERROR
PUSHJ P,DDTCALL
JUMPN PID,P2UUX2
POPACS
EXCH P,ERRPD(PID)
CONO PI,PION
JRST 2,@UUO0+P1PID ;TRY TO GO ON!
P2UUX2: POPACS
EXCH P,ERRPD(PID)
CONO PI,PION
JRST 2,@UUO0+P2PID
;SAVE USER'S ACS, GET A PDL
U2OSYS: HRRZ 17,JBTPAG(17) ;GOD FORBID YOU SHOULD EVER GET HERE!
LSH 17,=9 ;CALCULATE USER'S FIRST ADDRESS
MOVEM 16,16(17)
MOVEI 16,(17)
BLT 16,15(17)
MOVE TAC,USRSAV+P2PID
MOVEM TAC,17(17)
MOVEI PID,P2PID
MOVE J,JOB(PID) ;PICK UP JOB NUMBER
MOVE DAT,UUO0(PID) ;SAVE RETURN IN ACS
MOVE UUO,@UUOLOC(PID) ;AND SAVE UUO ALSO
SKIPE INTACT(PID)
SKIPA P,INTSP(PID) ;USE INTERRUPT LEVEL PDL
JRST LOSPDL ;NO PDL AVAILABLE ON THE PDP6
JRST UUOSY1 ;WE GOT A PDL.
UUOSYS:
NOKL10,<
XCTR XW,[MOVEM 16,16] ;STORE AC16 IN USER 16
MOVEI 16,0 ;SOURCE = AC0, DEST = USER RELATIVE 0.
XCTR XBLTW,[BLT 16,15] ;STORE IN USER RELATIVE 0-15
MOVE TAC,USRSAV+P1PID ;MOVE USER 17 TO USER'S AREA
XCTR XW,[MOVEM TAC,17]
>;NOKL10
MOVEI PID,P1PID
UUOSY2: MOVE J,JOB(PID) ;PICK UP JOB NUMBER
MOVE DAT,UUO0(PID) ;SAVE RETURN IN ACS
MOVE UUO,@UUOLOC(PID) ;AND SAVE UUO ALSO
SKIPE INTACT(PID)
SKIPA P,INTSP(PID) ;USE INTERRUPT LEVEL PDL
SKIPE P,JBTPDL(J) ;GET US A PDL
JRST UUOSY1 ;WE GOT A PDL.
LOSPDL: MOVE P,ERRPD(PID) ;(HERE FROM MONSTR IF JBTPDL=0)
PUSHACS
PUSHJ P,DISJOB
PUSHJ P,DISMES
ASCIZ / AT GETPDL WITHOUT A PDL. RETURNS VIA UUOERR
/
PUSHJ P,DISFLU
POPACS
PUSHJ P,WDDTCAL
MOVEI P,0
JRST UUOERR
↑UUOSY1:EXCH DAT,UUOPC(J) ;(ENTER HERE FROM SPWSER) SAVE RETURN.
MOVEM DAT,UUOOPC(J) ;SAVE OLD RETURN.
SKIPE DAT,UUOPTR(J) ;IS USER TRYING TO SIMULATE UUOS?
JRST UUOSY4 ;PERHAPS. GO CHECK FOR SIMULATION.
UUOSY3: TLNN UUO,740000 ;SYSTEM UUO?
JRST UUOERR ;NO, 0-37 ARE ILLEGAL,PRINT ERROR
LDB UCHN,PUUOAC ;SETUP USER DEVICE CHANNEL NUMBER
LDB TAC1,[POINT 9,UUO,8] ;PICK UP UUO OP CODE
XORI TAC1,700 ;IS THIS AN IOT UUO?
TRCN TAC1,700
JRST UUOIOT ;YES, SEPARATE DISPATCH TABLE
CAIL TAC1,100 ;ILLEGAL INSTRUCTION?
JRST ILLINS ;YES, STOP JOB AND PRINT ERROR
PUSHJ P,CHNSET ;CHECK CHANNEL NUMBER AND LOAD IOS AND DSER
JRST USRXIT ;NO CHANNEL, BUT UUO LEGAL ANYWAY
JRST USRXT1 ;THIS IS LONG UUO ON SHORT DISPATCH DEVICE.
ROT TAC1,-1 ;DIVIDE UUO OPCODE BY 2, SAVE REMAINDER
MOVE DAT,UUOTAB-20(TAC1) ;GET DISPATCH TABLE ENTRY
DISP4: TLNN TAC1,400000 ;WAS UUO ODD?
MOVS DAT,DAT ;NO, USE LH OF DISPATCH ENTRY
AOS NUUOS
PUSHJ P,(DAT) ;DISPATCH TO UUO ROUTINE. RETURN BY POPJ
;BEGINNING HERE WE WON'T TAKE USER INTERRUPTS
USRXT0: JRST USRXIT ;NO SKIP RETURN REQUIRED
JRST USRXT1 ;(SINGLE) SKIP REQUIRED.
MOVE J,JOB(PID)
AOSA UUOPC(J) ;DOUBLE SKIP.
USRXT1: MOVE J,JOB(PID)
AOS UUOPC(J) ; SKIP RETURN TO USER
;USRXIT - RETURN FROM UUO ROUTINE.
;CHECK TO SEE IF SCHEDULER WANTS TO RESCHEDULE THIS JOB.
↑USRXIT:MOVE J,JOB(PID)
IFN FTSCNBUG <
JUMPN PID,.+2 ;DON'T LET PDP-6 USE BUG TRAP
JSR CH7CHK ;BUG TRAP FOR STATE OF SCANNER CHANNEL
>;FTSCNBUG
SKIPN SPWUUF(PID) ;ARE WE AT SPACEWAR LEVEL ?
JRST USRXT6 ;NO.
MOVE TAC,UUOPC(J)
POP P,UUOPC(J) ;RESTORE OLD PC WORD
MOVEM TAC,UUO0(PID)
JUMPE PID,USRXT7
MOVSI 17,SP2SAC
BLT 17,17
XCT SPWXCT+P2PID ;USUALLY JRST 2,@UUO0+P2PID
USRXT7:
NOKL10,< MOVSI 17,SPWSAC ;RESTORE SPW ACS
BLT 17,17 >;NOKL10
IFKL10,< DATAO KLPAG,[401000,,0] ;AC BLK = 1, PREV = 0 >;IFKL10
XCT SPWXCT+P1PID ;USUALLY JRST 2,@UUO0 ;RETURN TO SPW JOB
USRXT6: SKIPE INTACT(PID) ;USER INTERRUPT LEVEL?
JRST USRXT4 ;YES, SKIP SCHEDULING CHECK
SKIPL TAC,JBTSTS(J) ;STILL RUNNABLE?
JRST USRXT9 ;NO - RUN BIT OFF - PUT HIM IN STOPQ
TLNE TAC,STOPIO ;YES?
USRXT2: PUSHJ P,USRXTS ;NO, CAUSE CLK INT ON EXIT
MOVSI UCHN,INTWAIT ;ARE WE ENABLED FOR INTERRUPT WAIT INTERRUPT?
TDNN UCHN,JBTIEN(J)
JRST USRXT4 ;NOT ENABLED FOR INT-WAIT INTERRUPT
SETOM INTHLD(PID) ;MAKE SURE WE DON'T GET TO INTNOW FROM HERE
IORM UCHN,JBTIRQ(J)
SETZM INTHLD(PID) ;INTNOW WILL WIN NOW
SETOM INTREQ(PID)
USRX4A: PUSHJ P,USRXTS ;INT ON WAY BACK TO LOSER
USRXT4: MOVEI DAT,USRXT5
EXCH DAT,UUOPC(J)
TLNN DAT,USRMOD
JUMPN DAT,@DAT ;RETURN IF UUO FROM EXEC, EXCEPT EXIT UUO.
REPEAT 0,<
MOVSI AC1,RUN2
SKIPN PID
MOVSI AC1,RUN1
TDNN AC1,JB2STS(J)
PUSHJ P,PSWITCH
>
;RESTORE ACS AND DISMISS UUO
MOVEM DAT,UUO0(PID)
JUMPE PID,USRXT8
MOVE TAC,JBTPAG(J) ;MAKE SURE USER'S RELOCATION IS SET UP
LSH TAC,=9
MOVSI 17,JOBAC(TAC) ;RESTORE ALL USER ACS
BLT 17,17
XCT UUOXIT+P2PID ;JEN @UUO0+P2PID OR CONO PI,PIOFF
SETOM CLKFLG+P2PID ;CAUSES TRAP TO CLKIN0 INSTEAD OF CLKINT
SETOM SCHEDF+P2PID
CONO PI,PION!4000!<200⊗-CLKCHN>
CONSO PI,77000
JRST CL2IN0
JRST 10,.-2
USRXT8: SKIPN JBTPAG(J) ;IF PRESENT JOB GOES TO CORE 0 (I.E., KILLS)
SETZB J,JOB(PID) ;THEN WE'LL WIND UP IN CHANNEL 7 WITH JOB=0
JUMPE J,USRX8A
NOKL10,<
MOVEI 17,0 ;SOURCE=RELATIVE 0, DEST=AC0
XCTR XBLTR,[BLT 17,17] ;MOVE USER RELATIVE 0-17 INTO ACS
>;NOKL10
IFKL10,<
DATAO KLPAG,[401000,,0] ;SET CURRENT AC BLK = 1, PREVIOUS = 0
>;IFKL10
;UUOXIT normally contains JEN @UUO0 which will restore flags and
;return to the user. If the clock ticks while a UUO is in progress,
;the code at CLKINT clobbers UUOXIT to CONO PI,PIOFF; then XCT UUOXIT
;will fail to jump, and an interrupt on CH7 will be initiated to
;continue the clock interrupt that had been delayed.
USRX8A: SETOM NULBAD ;IN CASE OF KILLING OLD JOB, RESTART NULL JOB
XCT UUOXIT ;JEN @UUO0 OR CONO PI,PIOFF
SETOM CLKFLG ;HERE WITH INTS OFF IF CLOCK HAS TICKED (SEE CLKINT)
SETOM SCHEDF ;IN CASE OF 0 PC FROM EXIT
CONO PI,PION!4000!<200⊗-CLKCHN> ;NOW (GOES TO CLKIN0 SINCE CLKFLG<0)
CONO PI,PION ;FOR THE KL10, SOAK UP ANOTHER EBUS CYCLE
CONSO PI,77000 ;GET HERE ON TRPJEN (ALREADY IN PROGRESS)
JRST CLKIN0 ;CH7, JUST GO
JRST 10,.-2 ;HIGHER CHN, DISMISS (SHOULDN'T RETURN)
;ROUTINE TO FORCE CLOCK BREAK UPON RETURN TO USER
;ONLY CALL WHEN NEARLY READY TO EXIT FOR INTNOW TO WORK.
USRXTS: MOVE TAC,[CONO PI,PIOFF]
MOVEM TAC,UUOXIT(PID)
POPJ P,
;GET HERE IF RUN BIT WAS OFF
USRXT9: MOVNI TAC,STOPQ
MOVEM TAC,JOBQUE(J)
JRST USRXT2 ;GO FORCE SCHEDULE
USRXT5: ;BEYOND HERE USER INTS OK
CONO PI,PIOFF
PUSHJ P,DISMES
ASCIZ /EXITING UUOCON WITHOUT HAVING ENTERED UUOCON
/
PUSHJ P,DISFLUSH
PUSHJ P,WDDTCALL
HALT AUTOLOAD
;UUOSIM - UUO SIMULATION. UUOSY4
;GET HERE WHEN UUOPTR≠0 TO THINK ABOUT LETTING LOSER SIMULATE UUO
;UUOPTR POINTS TO TABLE (IN LOSER'S CORE) OF 3 3-WORD BLOCKS
;EACH BLOCK LOOKS LIKE THIS:
;WD0: PLACE TO SAVE PC
;WD1: PLACE TO SAVE UUO ITSELF
;WD2: PC TO TRANSFER TO
;THE FIRST BLOCK IS USED FOR PDP-10 MAIN PROGRAM UUOS, THE SECOND FOR PDP-10
;INTERRUPT LEVEL UUOS, AND THE THIRD FOR PDP-10 SPACEWAR UUOS. NO PDP-6 UUOS
;CAN BE SIMULATED. IF EITHER WD1≠0 OR WD2=0 IN A GIVEN BLOCK, THOSE
;UUOS ARE NOT GIVEN TO THE USER'S HANDLER. THE WD1≠0 CONDITION HAS THE
;EFFECT OF AUTOMATICALLY DISABLING SIMULATION WHILE IN THE SIMULATOR.
UUOSY4: SKIPE INTACT(PID) ;FIRST MAKE PNTR TO APPROP BLK
ADDI DAT,3
SKIPE SPWUUF(PID)
ADDI DAT,6
XCTR XR,[SKIPN 1(DAT)] ;NOW SEE IF HE REALLY WANTS TO SIMULATE THIS
XCTR XR,[SKIPN TAC,2(DAT)]
JRST UUOSY3 ;NOPE, WE'LL DO OUR THING AS USUAL
XCTR XW,[MOVEM UUO,1(DAT)]
TLO TAC,USRMOD
EXCH TAC,UUOPC(J) ;SWAP PC'S AROUND
XCTR XW,[MOVEM TAC,(DAT)]
JRST USRXIT ;AND "RETURN" TO HIS SIMULATOR
↑SPWBLK←←6 ;TELL SPWSER WHERE TO LOOK
;UUO TO SET UUOPTR TO ENABLE/DISABLE SIMULATOR
;CALL: MOVE AC,<ADDRESS OF 9-WORD SIMULATOR BLOCK>
; UUOSIM AC,
;STORES USER'S ARGUMENT IN UUOPTR(J)
UUOSIM: MOVEM TAC,UUOPTR(J)
POPJ P,
;CHNSET ROUTINE TO ASSIGN A CHANNEL NUMBER
CHNSET: POP P,DAT ;POP UP RETURN ADDRESS
SKIPE DDB,USRJDA(UCHN) ;GET ADRESS OF DEVICE DATA BLOCK
CAMLE UCHN,USRHCU(PID) ;IS IT LESS THAN OR EQUAL TO HIGHEST
;USER IO CHANNEL IN USE FOR CURRENT JOB?
JRST NOCHAN ;CHANNEL NOT ASSIGNED
CHNSE1: MOVE IOS,DEVIOS(DDB) ;GET DATA BLOCK STATUS WORD
MOVE DSER,DEVSER(DDB) ;SETUP IO SERVICE DISPATCH TABLE ADDRESS
CAIL TAC1,LNGUUO ;LONG DISPATCH TABLE UUO?
JRST CHNSE3 ;YES
JRST 2(DAT)
NOCHAN: MOVE TAC,UUOPC(J) ;IS UUO FROM USER MODE?
CAIGE TAC1,IOUUO ;IO UUO?
JRST CHNSE2 ;NO.
REPEAT 0,<
PUSHJ P,GOTOP1 ;ALL IO DONE FROM P1
>
TLNN TAC,USRMOD
JRST CHNSE1 ;EXEC MODE
CAIE TAC1,70 ;YES,IS IT CLOSE OR RELEASE?
CAIN TAC1,71 ;CLOSE AND RELEASE ALWAYS LEGAL
JRST (DAT)
JRST IOIERR ;NO, PRINT IO TO UNASSIGNED CHANNEL AND STOP JOB
CHNSE2: MOVEI DDB,0 ;SET DDB 0 TO FLAG NON-IO UUO
JRST 2(DAT) ;GO DISPATCH
CHNSE3: MOVE TAC,DEVMOD(DDB) ;LONG DISPATCH TABLE UUO
TLNE TAC,DVLNG ;DOES THIS DEVICE HAVE A LONG DISPATCH TABLE?
JRST 2(DAT) ;YES, DISPATCH
CAIGE TAC1,76 ;NO, IS UUO LOOKUP OR ENTER?
JRST (DAT) ;NO, RETURN TO USER
JRST 1(DAT) ;YES, SKIP RETURN TO USER
;TABLE OF UUO DISPATCH ADDRESSES
;IN FORMAT:
; XWD 40,41
; XWD 42,43
; .
; XWD 76,77
;THERE'D BETTER BE EXACTLY 40 ENTRIES HERE
DEFINE UUOS{FOR X IN(CALL,INIT,,SPCWAR,,,,<CALLI> ;40-47
,OPEN,<TTYUUO,TTYUUO>,,,,RENAME,<IN,TIN>,<OUT,TOUT> ;50-57
,<SETSTS,SETIOS>,STATO,<GETSTS,USTATS>,<STATZ> ;60-63
,<INBUF,UINBF>,<OUTBUF,UOUTBF>,<INPUT,IN>,<OUTPUT,UOUT> ;64-67
,<CLOSE,CLOSE1>,<RELEAS,RELEA1>,MTAPE,<UGETF,UDGF> ;70-73
,<USETI,UDSI>,<USETO,UDSO>,<LOOKUP,UDLK>,<ENTER,UDEN>)} ;74-77
DEFINE UUOADR(C,A,B)
{IFE UUOPHZ,<DEFINE UUOAD1<0,A,B>;>XWD UUOAD2(C,\UUOAD1),UUOAD2(C,,A,B)
UUOPHZ←←1-UUOPHZ}
DEFINE UUOAD2!(C,X,A,B)
{IFIDN <A!B><><UUOERR+>IFDIF <B><><B+>IFDIF <A><><IFIDN <B><><C!A+>>0}
UUOPHZ←←0
UUOTAB: UUOS
{ UUOADR U,X
}
XP IOUUO,55 ;LOWEST IO UUO(RENAME)
XP LNGUUO,72 ;LOWEST LONG DISPATCH TABLE UUO
;IOT UUO DISPATCH TABLE
UUOIOT: SUBI TAC1,700 ; MAKE 700-777 INTO 0-77
CAIL TAC1,2*IUUMAX ; DOES THIS ONE EXIST?
JRST ILLINS ; NO, ILLEGAL INSTRUCTION
AOS NIOTS ; BUMP NUMBER OF IOT UUOS USED
ROT TAC1,-1
MOVE DAT,IUUTAB(TAC1) ; PICK UP DISPATCH ADDRESS
MOVEI DDB,[SIXBIT /GARPLY/] ;INIT. FOR ERROR PRINTOUTS.
AOS NNUUOS ; BUMP COUNT OF DISPATCHES
JRST DISP4
DEFINE IUUOS{FOR X IN(<,CPOPJ>,DPYCLR,PPIOT,<UPGIOT> ;700-703
,<UINBF,MINBF>,<UOUTBF,MOUTBF>,<FBREAD,UUOERR>,<FBWRT,UUOERR> ;704-707
,<MAIL,UMAIL>,PTYUUO,POINTS,<UPGMVE,UPGMOV> ;710-713
,UPGMVM,PGIOT,CHNSTS,<CLKINT,CLKUUO> ;714-717
,INTMSK,IMSKST,IMSKCL,INTUUO,IOPUSH,IOPOP,IOPDL)} ;720-726
UUOPHZ←←0
IUUTAB: IUUOS
{ UUOADR ,X
}
IFN UUOPHZ,<UUOADR>
IUUMAX←←.-IUUTAB
;UUO NAME TABLE, FOR FAIL, ETC.
PSHSYS
LOSYS
IFE UUOPHZ,<IUUMAX*2,,UUOFLK;>IUUMAX*2-1,,UUOFLK ;LINK TO TABLES FOR TTYUUO, ETC.
↑UUONAM:UUOS
{ <SIXBIT ,X,>
} IUUOS
{ <SIXBIT ,X,>
}
POPSYS
;CALL AND CALLI
; CALLING SEQUENCE
; CALL D,[SIXBIT/NAME/]
; WHERE NAME IS THE NAME OF A SYSTEM ROUTINE.
; IF NO SYSTEM ROUTINE WITH THE SPECIFIED NAME IF FOUND, THIS ROUTINE
; EXITS TO UUOERR.
;CONTENTS OF USER AC PLACED IN AC TAC, UUO SET TO POINT TO USER AC
;J SET TO JOB NUMBER
UCALL: XCTR XR,[MOVE DAT,(UUO)] ;PICK UP NAME OF SYSTEM ROUTINE
MOVSI TAC1,-UCLLEN
CAME DAT,UCLTAB(TAC1) ;SEARCH SYSTEM ROUTINE NAME TABLE
AOBJN TAC1,.-1
TLZN TAC1,-1 ;CLEAR LH. WAS IT ZERO?
JRST UUOERR ;YES. RAN OUT OF TABLE
JRST UCALL1 ;NO. DISPATCH.
;CALLI UUO - CALL IMMEDIATE
;CALLI D,E
;WHERE E IS RELATIVE INDEX IN CALL TABLE
↑UCALLI:
HRRZ TAC1,UUO
CAIL TAC1,UCLDLN ;EXCEED ?
JRST UCALL2 ;YES. ERROR
UCALL1: POP P,TAC ;REMOVE RETURN
HRR UUO,UCHN ;UUO AC FIELD
XCTR XR,[MOVE TAC,(UUO)] ;PICK UP CONTENTS OF USER AC
ROT TAC1,-1 ;DIVIDE BY 2 AND SAVE REMAINDER
MOVE DAT,UCLJMP(TAC1) ;GET DISPATCH TABLE ENTRY
MOVE J,JOB(PID)
JRST DISP4 ;AND GO DISPATCH
UCALL2: TRZN UUO,400000 ;IS HE ASKING FOR A STANFORD CALLI?
JRST UUOERR ;NO, SHOOT HIM!! BANG!
MOVEI TAC1,UCLDLN(UUO)
CAIL TAC1,UCLDLN ;IF NOT BIGGER THAN THIS, FLUSH IT!
CAIL TAC1,UCLLEN ;STILL TOO LARGE?
JRST UUOERR ;YES, FLUSH
AOS NSCALL ;BUMP NUMBER OF STANFORD CALLIS USED
JRST UCALL1
;CALL UUO DISPATCH TABLE
;NEW UUOS MUST BE ADDED AT END SINCE CALLI DEPENDS ON
;POSITION IN TABLE
;ALSO NUMBER OF DEC CALLIS MUST BE EVEN
DEFINE NAMES!,<
X RESET,RESETUUO ;RESET IO
X DDTIN,DDTIN ;EXT-GET DDT CHAR.
X SETDDT,SETDDT ;SETDDT LOC IN PROTECTED JOB DATA
X DDTOUT,DDTOUT ;EXT:SEND DDT CHAR.
X DEVCHR,DVCHR ;DEVICE CHARACTISTICS
X DDTGT,CPOPJ ;GET DDT MODE
X GETCHR,DVCHR ;DEVICE CHAR.(DIFF. NAME)
X DDTRL,CPOPJ ;RELEASE DDT MODE
X WAIT,WAIT ;WAIT TILL DEVICE INACTIVE
X CORE,CORUUO ;CORE UUO
X EXIT,EXIT ;EXIT
X UTPCLR,UTPCLR ;CLEAR DEC TAPE DIRECTORY
X DATE,DATE ;GET DATE
X LOGIN,LOGIN ;LOGIN
X APRENB,APRENB ;ENABLE APR FOR TRAPPING
X LOGOUT,LOGOUT ;LOGOUT
X SWITCH,SWITCH ;RETURN DATA SWITCHES
X REASSIGN,REASSIGN ;REASSIGN DEVICE TO ANOTHER JOB
X TIMER,TIMER ;RETURN JIFFY CLOCK TIME
X MSTIME,MSTIME ;RETURN TIME OF DAY IN MS
X GETPPN,GETPPN ;RETURN PROJECT-PROGRAMMER NUMBER
X <>,UUOERR ;TRPSET ILLEGAL
X <>,UUOERR ;TRPJEN ILLEGAL
X RUNTIM,JOBTIM ;RETURN TOTAL JOB RUNNING TIME
X PJOB,JOBNO ;RETURN JOB NUMBER
X SLEEP,SLEEP ;SLEEP FOR N SECONDS, THEN RETURN TO USER
X SETPOV,SETPOV ;SET PUSH DOWN OVERFLOW TRAP (FOR COMPAT ONLY)
X PEEK,PEEK ;PEEK INTO SYSTEM CORE. ;JS
X GETLN,GETLN ;GET NAME OF TTY
X RUN,RUNUUO ;DEC'S SWAP UUO
X SETUWP,SETUWP ;SET USER WRITE PROTECT
X REMAP,REMAP ;REDO CORE MAP
X GETSEG,CPOPJ ;GET SEGMENT
X GETTAB,CPOPJ ;GETTAB ILLEGAL (ERROR RETURN) HERE.
X <>,UUOERR ;SPY ALSO ILLEGAL
X SETNAM,SETNAM ;SET JOB NAME
X TMPCOR,TMPCOR ;TEMPORARY FILES FOR RPG, ETC.
X <>,UUOERR ;FILL OUT THE TABLE
>
;STANFORD CALLIS
DEFINE STANFORD <
X SPWBUT,SPCWAR ;READ SWITCH REGISTER
X CTLV,CTLV1 ;PUT TTY IN NON-DUPLEX MODE.
X <>,SETNAM ;SET JOB NAME FOR SYSTAT (OBSOLETE)
X SPCWGO,SPCWGO ;ANOTHER SPACEWAR UUO
X SWAP,SYSRJB ;RUN A JOB
X EIOTM,EIOTM ;ENTER IOT USER MODE
X LIOTM,LIOTM ;LEAVE IOT USER MODE
X PNAME,PNAME ;GET A DEVICE'S PHYSICAL NAME
;; X UFBGET,UFBGET ;GET A FAST BAND - 400010
;; X UFBGIV,UFBGIV ;RELEASE A FAST BAND
;; X UFBCLR,FBFLUSH ;RELEASE ALL FAST BANDS
X <>,UUOERR
X <>,UUOERR
X <>,UUOERR
X JBTSTS,USTAT ;GET JOB STATUS WORD OF A JOB
X TTYIOS,TTYIOS ;GET A JOB'S TELETYPES STATUS WORD
X CORE2,CORE2 ;FUNNY CORE UUO FOR HIGH SEGMENTS
X ATTSEG,ATTSEG ;ATTACH HIGH SEGMENT
X DETSEG,DETSEG ;DETACH HIGH SEGMENT
X SETPRO,SETPRO ;CHANGE PROTECTION OF HIGH SEGMENT - 400020
X SEGNUM,SEGNUM ;GET NUMBER OF HIGH SEGMENT
X SEGSIZ,SEGSIZ
X LINKUP,LINKUP
X DISMIS,DISMIS
X INTENB,INTENB ; ENABLE INTERRUPTS
X INTORM,INTORM
X INTACM,INTACM
X INTENS,INTENS ; 400030
X INTIIP,INTIIP
X INTIRQ,INTIRQ
X INTGEN,INTGEN ; GENERATE AN INTERRUPT
X UWAIT,UWAIT
X DEBREAK,DEBREAK
X SETNM2,SETNM2 ; SET NAME OF UPPER, IF ANY
X SEGNAM,SEGNAM ; GET NAME OF UPPER, IF ANY
X IWAIT,IWAIT ; GO INTO A WAIT STATE, WAKE UP ON ANY INTERRUPT. - 400040
X USKIP,USKIP ; SKIP IF A UWAIT REALLY HAS TO WAIT.
X BUFLEN,BUFLEN ; RETURN BUFFER LENGTH FOR A DEVICE
X NAMEIN,NAMEIN ; SEE IF THIS JOB NAME EXISTS
X SLEVEL,SETLVL ; SET OR GET SERVICE LEVEL.
X IENBW,IENBW ; ENABLE INTERRUPTS AND IMMEDIATELY GO INTO WAIT STATE
X RUNMSK,RUNMSK ; SETS PROCESSOR RUN MASK
X TTYMES,TTYMES ; SEND A STRING TO A TTY
X JOBRD,JOBRD ; READ A BLOCK FROM A GUY'S CORE IMAGE - 400050
X DEVUSE,DEVUSE ; TO TELL HOW MANY PEOPLE ARE WAITING FOR A DEVICE
X SETPR2,SETPR2 ; SET SECOND PROTECT-RELOCATE REGISTER!
X GETPR2,PR2GET ; GET LAST SETPR2 VALUE
X RLEVEL,RLEVEL ; GET CURRENT SERVICE LEVEL RESERVATION
;; X UFBPHY,FBPHY ; GET PHYSICAL BAND NUMBER
;; X UFBSKP,FBSKP ; SKIP IF NO TRANSFER IN PROGRESS
;; X FBWAIT,FBWT ; WAIT FOR TRANSFER TO FINISH
;; X UFBERR,FBERR ; SKIP IF NO ERRORS IN LAST TRANSFER. 400060
X <>,UUOERR
X <>,UUOERR
X <>,UUOERR
X <>,UUOERR
X WAKEME,WAKEME ; SET ALFRED. TIME TO INITIALIZE A JOB.
X GETNAM,GETNAM ;RETURN JOBNAME IN AC
X SNEAKW,SNEAKW ; PEEK AT NEXT TTY CHAR. AND WAIT FOR IT
X SNEAKS,SNEAKS ; PEEK AT NEXT TTY CHAR. AND SKIP IF ONE THERE
X GDPTIM,GDPTIM ; GET TIME CELLS
X SETPRV,SETPRV ; RESET JOBTPRV
X DDCHAN,DDCHAN ;GET/RELEASE DD CHANS ETC.
X VDSMAP,VDSMAP ;CHANGE VIDEO SWITCH MAPPING - 400070
X DSKPPN,UDSKPPN ;GET OR SET DISK ALIAS PPN
IFN FTXCOR,< X GETHI,GETHI ;GET EXTRA CORE AS UPPER SEGMENT >;FTXCOR
IFE FTXCOR,< X <>,UUOERR >;NOT FTXCOR
X SETCRD,SETCRD ;SET JOB CREATION DATE & TIME
X CALLIT,CALLIT ;TRANSLATE CALL TO CALLI OR VICE VERSA
X XGPUUO,XGPUUO ;FONT COMPILER & XGPSER COMMUNICATION.
X LOCK,LOCK ;LOCK A JOB IN CORE.
X UNLOCK,UNLOCK ;UNLOCK A JOB
X DAYCNT,DAYCT ;SYSTEM DATE TO DAY COUNT. - 400100
X ACCTIM,ACCTIM ;RETURN <DATE>,,<TIME IN SECS>
X UNPURE,UNPURE ;UNPURIFY UPPER SEGMENT
X TMPCRD,TMPCRD ;READ OTHER JOB'S TMPCOR
X DEVNUM,DEVNUM ;CONVERT LOGICAL DEV NAME OR CHANNEL # TO UNIT #
X ACTCHR,ACTCHR ;WAIT FOR ACTIVATION AND RETURN CHAR WHICH DUN IT
X UUOSIM,UUOSIM ;SET UP UUO SIMULATOR
X PPSPY,PPSPY ;LIKE PPINFO FOR ANOTHER JOB
X ADSMAP,ADSMAP ;SET/READ AUDIO SWITCH SELECTIONS -400110
X BEEP,BEEP ;BEEP A TTY'S CHANNEL
X WHO,WHOUUO ;READ SYSTEM OR USER WHO LINE
X TTYJOB,TTYJNO ;GET JOB # ON THIS TTY
X NULMES,NULMES ;LIKE TTYMES BUT ALLOWS NULLS WITHIN TEXT
X GETPRV,GETPRV ;GET PRIVILEGES BY JOB #
X TTYSKP,TTYSKP ;SKIP IF TTY INPUT UUO WON'T HANG
X DIAL,DIAL ;DIAL UUO
X LTHUUO,LTHUUO ;LOW TO HIGH MOVE UUO
X TTYSET,TTYDDL ;EXECUTE TABLE OF OPERATIONS FOR TTY
>
;NOTE, USE UP THE UUOERR ENTRIES BEFORE MAKING NEW ONES
IFE FTHPSG,< LTHUUO: POPJ P, > ;IFE FTHPSG - NO OP.
;MACROS TO DEFINE CALLI TABLES
DEFINE X! (A,B)
<
<SIXBIT /A/>
>
PSHSYS
LOSYS
↑UCLTAB: ;POINTER TO HERE IN OUTER
XLIST
NAMES
XP UCLDLN,.-UCLTAB
STANFORD
LIST
XP UCLLEN,.-UCLTAB
UUONAM ;POINTER TO FIND REST OF UUO NAMES
POPSYS
DEFINE X!(A,B)
<IFE ZZ/2*2-ZZ,<DEFINE ZZZ<B>>
IFN ZZ/2*2-ZZ,<XWD ZZZ,B>
ZZ←←ZZ+1
>
ZZ←←0
UCLJMP:
XLIST
NAMES
STANFORD
LIST
IFN ZZ/2*2-ZZ,<XWD ZZZ,0>
;EXIT UUO ROUTINE
HISYS
;REG (1-14-72) EXIT UUO WITH AC FIELD ≠ 0 WILL STOP JOB,
;TYPE CRLF DOT AND ALLOW USER TO TYPE CONTINUE
EXIT: MOVE TAC,JBTSTS(J)
HRRE TAC1,JBTLIN(J)
JUMPL TAC1,EXIT1 ;KILL DETACHED JOB THAT EXIT!
TLNN TAC,JLOG ;LOGGED IN?
JRST EXIT1 ;FLUSH DETATCHED OR UNLOGGED IN JOBS
JUMPN UCHN,EXIT2 ;JUMP IF AC FIELD OF EXIT UUO WAS NOT ZERO
PUSHJ P,KILSPW
PUSHJ P,INTKIL
PUSHJ P,IORELS ;FLUSH USER'S IO (GENTLY - CLOSES FILES)
PUSHJ P,RESETB ;RESET EVERYTHING ELSE
PUSHJ P,TTYFUW ;FIND TTY FOR CURRENT JOB. SETUP J,DDB,DAT
XCTR XW,[SETZM JOBOPC] ;NO MORE OPC
SETZM UUOPC(J) ;NOR USER PC (ESTOP NOW GOES TO USRXIT)
SETZM UUOOPC(J) ;NOR BACKUP USER PC
;ALL THIS MEANS THAT THE NEXT START, ETC.
;PUTS A 0 IN JOBOPC - FOR RAID
JSP TAC,PHOLD ;APPEND "EXIT". STOP JOB. START TTY.
ASCIZ /
Exit/
EXIT1: PUSHJ P,KILSPW ;ZERO SPACEWAR CELLS
PUSHJ P,INTKIL
PUSHJ P,IORELS ;HERE TO KILL JOB. FLUSH USER IO (GENTLY?)
JRST JOBKL ;AND THROW THE USER OFF. (CALLS RESET)
EXIT2: PUSHJ P,KILSPW ; ZERO SPACEWAR CELLS
PUSHJ P,TTYFUW ;GET THE USER'S CONSOLE
PUSHJ P,PRCRCC ;TYPE CRLF ↑C CRLF .
PUSHJ P,TTYSTC ;START THE TTY
JRST STOP1 ;SET JOB NOT RUNNABLE. UUOXIT WILL STOP IT.
;RESET UUO ROUTINE
INTTST: SKIPE SPWUUF(PID) ;SPACEWAR ACTIVE?
JRST SPWERR ;YES. THIS IS AN ERROR.
SKIPN INTACT(PID) ;USER INTERRUPT-LEVEL?
POPJ P, ;NO. WE'RE OK.
JSP TAC,UUOMES ;HERE FOR A UUO ILLEGAL AT INT LEVEL
ASCIZ /Illegal I-level call, UUO/
↑RESET: SKIPA TAC,[PUSHJ P,RESETSEG]
RESETU: MOVSI TAC,(<JFCL>) ;INSTR TO XCT AFTER STOPPING IO, ETC.
PUSHJ P,INTTST
PUSH P,TAC ;SAVE INSTR. TO XCT.
PUSHJ P,KILSPW
PUSHJ P,INTKILL
PUSHJ P,IOKILL ;KILL IO ON ALL DDBS. (RELEA5)
POP P,TAC
XCT TAC ;PUSHJ P,RESETSEG OR JFCL
RESETB: PUSHJ P,UNLOCK ;UNLOCK HIM IN CORE.
SKIPE TAC,JBTPR2(J) ;IS HE DOING PEEK-POKE?
TRNE TAC,2 ;YES, BUT DON'T CLEAR PSEUDO-UPPER
JRST NOPR2 ;NO PEEK-POKE, OR PSEUDO-UPPER.
IFE FTPAGER,< SETZM JBTPR2(J) ;CLEAR IT
PUSHJ P,GETPR
DATAO APR,TAC ;SETUP APR AS APPROPRIATE. >;NOT FTPAGER
IFN FTPAGER,< PUSHJ P,ZERPR2 ;CLEAR JBTPR2 AND PAGE MAP ENTRIES
JFCL
NOKL10,< CONO PAG,3 >;NOKL10
IFKL10,< CONO KLPAG,@KLPCON >;IFKL10
>;FTPAGER
NOPR2: MOVE J,JOB(PID)
SKIPE AC1,JBTFS(J) ;ANY FREE STORAGE?
PUSHJ P,FSGIVE ;YES, RETURN IT
SETZM JBTFS(J)
;;; PUSHJ P,FBFLUSH ;RELEASE USER FAST BANDS
MOVEI TAC,0
PUSHJ P,APRENB ;KILL HIS APR INTERRUPTS
HRRZ AC1,JBTMAIL(J) ;ANYTHING IN HIS MAILBOX ?
JUMPE AC1,.+2 ;NO.
PUSHJ P,FSGIVE ;YES. RETURN THE FREE STORAGE.
SETZM JBTMAIL(J) ;EMPTY THE MAILBOX.
PUSHJ P,PTYCLR ;FLUSH HIS PSEUDO TTY'S, IF ANY.
MOVSI TAC,(J)
PUSHJ P,DDAREL ;FLUSH HIS DATA DISC CHANNELS
PUSHJ P,ADSRES ;RESET AUDIO SWITCH MAP
IFKL10,<PUSHJ P,CSHRES ;CLEAR CACHE DISABLE REASONS >;IFKL10
MOVE AC1,JBTLIN(J) ;PICK UP LINE CHARACTERISTICS
CAME AC1,[-1] ;DETACHED?
TLNN AC1,DISLIN!DDDLIN!DMDLIN ;IF III OR DD OR DM, GO RESET THE DISPLAY
POPJ P, ;NO, NO RESET OF SCREEN
JRST DPYRST ;RESET HIS DPY, IF HE HAS ONE.
;RESETSEG - ROUTINE TO RESET ONE'S UPPER SEGMENT
RESETSEG:
PUSH P,TAC
PUSH P,AC1
PUSH P,TAC1
PUSH P,DDB
PUSHJ P,FLUSHSEG ;FLUSH HIS UPPER, IF ANY
CAME J,JOB(PID) ;IS THIS THE CURRENT JOB?
JRST RESTG1 ;NO, DON'T BOTHER TO RESET PR
IFE FTPAGER,< PUSHJ P,GETPR ;RESET HIS PROT-RELOC
DATAO APR,TAC ;RESET APR MAP >;IFE FTPAGER
IFN FTPAGER,<
NOKL10,< CONO PAG,3 >;NOKL10
IFKL10,< CONO KLPAG,@KLPCON >;IFKL10
>;IFN FTPAGER
RESTG1: POP P,DDB
POP P,TAC1
POP P,AC1
POP P,TAC
POPJ P,
;APRDKL ROUTINE TO KILL ANY CLOCK INTERRUPT REQUESTS FOR JOB J
APRDKL: JUMPN PID,CPOPJ
PUSH P,TAC1 ;SAVE THIS IN CASE SOMEONE DEPENDS ON IT
CONI PI,TAC1 ;GET STATE OF PI SYSTEM
ANDI TAC1,APROFF-1000 ;MASK FOR ONLY STATE OF APR CHANNEL
CONO PI,APROFF ;MAKE SURE CHANNEL IS OFF
SKIPE TAC,APRLST
APRDK3: SKIPN AC1,(TAC)
JRST APRDK1 ;APRLST EMPTY OR END OF LIST
CAIN J,(AC1)
JRST APRDK2 ;THIS IS OUR REQUEST
ADDI TAC,2
JRST APRDK3
APRDK2: PUSHJ P,APRDEL ;DELETE REQUEST POINTED TO BY TAC
JFCL
APRDK1: CONO PI,2000(TAC1) ;TURN CHANNEL ON ONLY IF WE TURNED IT OFF.
POP P,TAC1
POPJ P,
;APRENB, SETPOV - ROUTINE TO SET UP APR FOR USER TRAPPING, PDLOV TRAP
;CALL: MOVE AC,<APR CONI BITS TO BE ENABLED (SEE BELOW)>
; CALL AC,[SIXBIT /APRENB/]
;SET THE FOLLOWING BITS IN THE AC PRIOR TO CALLING APRENB
;1B18 ;CONS TRAP ;JS
;1B19 ;PUSHDOWN OVERFLOW
;1B22 ;ILLEGAL MEMORY
;1B23 ;NON-EXISTENT MEMORY (USERS ARE NOT ALLOWED TO GET NXM TRAPS)
;1B26 ;CLOCK
;1B29 ;AR FOV (OR PC CHANGE FLAG ON 166)
;1B32 ;AROV
;SETPOV - SET PUSH DOWN OVERFLOW TRAP
;CALL: MOVE AC,<ADRESS OF TRAP ON PD OVF>
; CALL AC,[SIXBIT /SETPOV/]
SETPOV: XCTR XW,[MOVEM TAC,JOBAPR] ;STORE USER'S TRAP ADDRESS
MOVEI TAC,1B19 ;SELECT ENABLE BITS FOR ARPENB
APRENB: ANDI TAC,CPUMSK!1000 ;MASK OUT ILLEGAL BITS ;JS
XCTR XW,[MOVEM TAC,JOBENB] ;SET RH TO CONSO BITS
TDNE TAC,APRIN2(PID)
JRST INTLOS ;CONFLICTING INTERRUPT ENABLINGS
IOR TAC,APRIN2(PID) ;INCLUDE NEW MOORER INTERRUPT SYSTEM
JRST APREN2
LOSYS
;THE PDP-6 CAN GET HERE FROM CLKSER
;(CALL APREN2 TO START A PROCESS (CIP8 OR SPACEWAR))
↑APREN2:HRRM TAC,APRIN1(PID) ;STORE USER'S ENABLINGS FOR ARPINT CONSO
XORI TAC,110 ;COMPLEMENT FOV AND AROV
ADDI TAC,330 ;DISABLE THE ENABLED ONES
ANDI TAC,660
NOKL10,<CONO APR,APRCHN(TAC) ;ENABLE OR DISABLE FOV AND/OR AROV >;NOKL10
IFKL10,<TRNN TAC,220 ;SKIP IF ANYTHING IS ENABLED
TLOA TAC,(<JFCL>) ;NO
MOVSI TAC,(<.TRAP 1,>)
MOVEM TAC,KLUPT+421 ;>IFKL10
POPJ P,
HISYS
;PEEK, SWITCH, PJOB, DATE, DAYCNT, ACCTIM, TIMER, JOBTIM, MSTIME UUO'S. STOTAC
;PEEK - READ A WORD FROM A GIVEN MONITOR SPACE ADDRESS.
PEEK: ANDI TAC,-1 ;ZERO LH OF TAC
CAML TAC,RMEMSIZ ;OVER END OF CORE?
JRST RTZERO ;YES. DONT LET HIM GET NON-EX MEM.
IFE FTEXPG,< MOVE TAC,(TAC)
JRST STOTAC >;IFE FTEXPG
IFN FTEXPG,<
PUSH P,TAC
LSH TAC,-=9 ;MAKE PHYSICAL PAGE
MOVEI TAC1,PEKEXP
DPB TAC1,[POINT 9,(P),26] ;CLOBBER VIR. PAGE TO EXEC PAGE NUMBER
PUSHJ P,ADDEMP
POP P,TAC
MOVE TAC,(TAC)
PUSHJ P,DELEMP
JRST STOTAC
>;IFN FTEXPG
SWITCH:
NOKL10,<DATAI TAC ;RETURN APR DATA SWITCHES >;NOKL10
IFKL10,<PUSHJ P,RSWITCH ;GET PDP-11'S VERSION OF SWITCHES >;IFKL10
JRST STOTAC
;STOTAC STORES TAC IN THE USER'S ADDRESS POINTED TO BY RH OF UUO.
;FOR CALL/CALLI UUOS, UUO POINTS TO THE USER'S ACCUMULATOR.
JOBNO: SKIPA TAC,J ;RETURN JOB NUMBER OF THIS JOB
DATE: MOVE TAC,THSDAT ;RETURN DATE TO USER
↑STOTAC:XCTR XW,[MOVEM TAC,(UUO)] ;STORE TAC INTO USER'S AC
POPJ P,
;CONVERT SYSTEM FORMAT DATE TO NUMBER OF DAYS SINCE 1-JAN-64
DAYCT: JUMPG TAC,.+2 ;ARGUMENT IN SYSTEM FORMAT TO DAY COUNT.
MOVE TAC,THSDAT ;ZERO OR NEGATIVE DATE GIVEN GETS TODAY'S DATE
PUSHJ P,DAYCNT ;THIS ROUTINE IS IN COMMAND DECODER (CLKSER)
JRST STOTAC
ACCTIM: SKIPA TAC,TIMDAT ;GET <DATE>,,<TIME IN SECS>
TIMER: MOVE TAC,TIME ;RETURN TIME OF DAY IN JIFFIES
JRST STOTAC
;RETURN JOB RUNNING TIME IN MILLISECONDS
JOBTIM: JUMPL TAC,RTZERO ;ILLEGAL JOB NUMBER
CAIL TAC,JOBN
JRST RTZERO ;ILLEGAL JOB NUMBER
JUMPG TAC,.+2
MOVEI TAC,(J) ;ASSUME CURRENT JOB FOR ZERO ARGUMENT
SKIPA TAC,TTIME(TAC) ;TOTAL JOB RUNNING TIME IN TICKS.
MSTIME: MOVE TAC,TIME ;RETURN TIME OF DAY IN MILLISECONDS
IMULI TAC,=1000 ;CONVERT TIME FROM JIFFIES TO MILLISECONDS
IDIVI TAC,JIFSEC ;DIVIDE BY NO. OF JIFFIES PER SECOND
JRST STOTAC
;SLEEP PUT JOB TO SLEEP FOR NSECONDS
;CALL CALL AC,[SIXBIT /SLEEP/]
↑SLEEP: IMULI TAC,JIFSEC ;MULTIPLY BY NO. OF JIFFIES PER SECOND
↑SLEEPT:MOVSI TAC1,CLKR
TDNE TAC1,JBTSTS(J) ;IS THERE A CLOCK REQUEST FOR THIS JOB ALREADY?
JRST SETSLP ;YES, DO NOT PUT ANOTHER ONE IN.
TRNN TAC,7777 ;0 TIME? JS
SLEEP1: MOVEI TAC,1 ;YES. SLEEP 1 JIFFY
DPB J,[POINT 6,TAC,23]
HRLI TAC,WAKE ;ADDRESS TO MAKE JOB WAKEUP (RUNCSS)
CONO PI,PIOFF
IDPB TAC,CLOCK
CONO PI,PION
JRST SETSLP ;SET JOB STATUS WORD SO JOB WILL NOT RUN
;DVCHR, DEVNUM
DVCHR: PUSHJ P,FNDDDB ;SEARCH FOR DEVICE (OR CHANNEL)
TDZA TAC,TAC ;NOT A DEVICE, RETURN ZERO
SKIPA TAC,DEVMOD(DDB) ;DEVICE FOUND,RETURN DEVMOD
JRST STOTAC ;RETURN ZERO, DEVICE NOT FOUND
TLNN TAC,DVUDP
JRST DVCHR2 ;EASY OUT UNLESS UDP
LDB AC2,PUNIT ;UDP, SCAN ENTIRE DDB LIST OF THIS UDP
MOVE TAC1,DKDBML(AC2)
MOVE AC1,DEVNAM(DDB)
DVCHR0: HLRZ TAC1,DEVSER(TAC1)
CAME AC1,DEVNAM(TAC1)
JRST DVCHR1 ;END OF DDBS FOR THIS DEVICE
IOR TAC,DEVMOD(DDB) ;RETURN UNION OF ALL ASSCON AND ASSPRG BITS
JRST DVCHR0
DVCHR1: SKIPL TAC1,UDPOWN-1(AC2)
CAMN TAC1,JOB(PID)
TLO TAC,DVAVAL ;AVAILABLE IF HIS OR PUBLIC
JRST STOTAC
DVCHR2: LDB TAC1,PJOBN ;GET JOB NO. USING DEVICE
CAME TAC1,JOB(PID) ;DOES CURRENT USER ALREADY HAVE IT?
TDNN TAC,[XWD TTYATC,ASSCON+ASSPRG] ;NO, IS IT ASSIGNED?
TLO TAC,DVAVAL ;NO, BUT HE CAN GET IT.
JRST STOTAC
DEVNUM: PUSHJ P,FNDDDB
POPJ P, ;NONE
LDB TAC,PUNIT ;GET UNIT NUMBER
AOS (P)
JRST STOTAC
;GETPPN -- DSKPPN
;DSKPPN
;CALLING:
; CALL AC,[SIXBIT/DSKPPN/]
;
;AC MEANING
;0 RETURN CURRENT JOB'S DSKPPN
;1 TO JOBN-1 RETURN DSKPPN OF JOB IN AC
;-1 RESET DSKPPN OF CURRENT JOB
;ANYTHING ELSE WILL TRY TO BE PPN TO SET DSKPPN TO
; MUST HAVE NON-ZERO LEFT AND RIGHT HALVES
UDSKPPN:
CAMN TAC,[-1] ;REQUESTING A RESET?
AOJA TAC,RSTPPN ;YES, SET TAC TO 0 AND STORE IT
TLNN TAC,-1 ;IS IT PPN?
JRST RTDSKPPN ;NO, MAYBE JUST GETTING SOMEONES DSKPPN
TRNN TAC,-1
HRR TAC,PRJPRG(J) ;COPY PRG FROM PRJPRG
RSTPPN: CAMN TAC,PRJPRG(J)
MOVEI TAC,0 ;THIS IS REALLY A RESET
CAMN TAC,MFDENT ;SAME AS 1,1?
POPJ P, ;DISALLOW SOME FORMS OF LOSSAGE.
CAME TAC,DSKPPN(J)
SETZM JBTUFD(J) ;CLEAR LOC OF UFD IF DEFAULT UFD IS CHANGING
MOVEM TAC,DSKPPN(J) ;SET NEW DISK ALIAS PPN
POPJ P,
RTDSKPPN:
JUMPN TAC,.+2
MOVE TAC,J ;WANTS HIS OWN
MOVSI TAC1,JNA
CAIGE TAC,JOBN ;LEGAL?
TDNN TAC1,JBTSTS(TAC) ;AND A REAL JOB?
JRST RTZERO ;NO
SKIPN TAC1,DSKPPN(TAC) ;IF THIS IS 0
MOVE TAC1,PRJPRG(TAC) ;THEN THIS IS IT
XCTR XW,[MOVEM TAC1,(UUO)] ;RETURN IT
POPJ P,
↑RTZERO:MOVEI TAC,0
JRST STOTAC
;RETURN PROJECT-PROGRAMMER NUMBER IN AC
GETPPN: MOVSI TAC,JACCT ;ACCOUNTING PROGRAM?
TDNE TAC,JBTSTS(J)
JRST GETPPL ;YES. GETPPN DOES DIFFERENT THING
MOVE TAC,PRJPRG(J)
JRST STOTAC
GETPPL: SETZM JBTUFD(J) ;ACCOUNTING: ANY OTHER USERS UNDER SAME PPN?
SETZM DSKPPN(J) ;RESET DISK ALIAS PPN
MOVE TAC,DUMPPN ;GET ALL POWERFULL PPN
EXCH TAC,PRJPRG(J) ;SET THIS JOB TO THAT PPN
MOVEI TAC1,JOBN-1 ;LOOK THRU ALL THE WORLD
CAMN TAC,PRJPRG(TAC1);SKIP IF NOT MATCHED
CAMN J,TAC1 ;MATCH. SKIP IF MATCH DIFFERENT FROM JOB NUMBER
SOJG TAC1,.-2 ;NO MATCH OR MATCHED SELF. LOOP
JUMPLE TAC1,STOTAC ;IF TAC1 = 0 THEN NO MATCH
AOS (P) ;MAKE IT SKIP RETURN
JRST STOTAC ;GO RETURN
;SETNAM, SETCRD, SETDDT, GETNAM
SETNAM: MOVEM TAC,JOBNAM(J) ;SET JOB NAME FOR SYSTAT
IFN FTSTAT,< PUSHJ P,NAMSTT>
POPJ P,
;SET CREATION DATE & PROT
SETCRD: TLZE TAC,400000 ;CLEAR & CHECK UNUSED BIT
JRST SETCD2 ;ANY OF THESE MEANS DO IT TO THE UPPER
SETCD1: MOVEM TAC,JOBCRD(J)
TDNE TAC,[37,,-1]
POPJ P,
PUSHJ P,DSKTM1
IORM TAC1,JOBCRD(J)
POPJ P,
SETCD2: PUSH P,J ;SAVE FOR ACCESS
LDB J,PSEGN
JUMPE J,TPOPJ ;EASY IF NO UPPER
MOVE AC1,TAC ;ELSE SAVE ARG
PUSHJ P,ACCESS ;AND MAKE SURE THIS IS LEGAL
JRST TPOPJ
JRST TPOPJ
SUB P,[1,,1] ;DON'T NEED THAT JOB # ANY MORE
MOVE TAC,AC1
JRST SETCD1
SETDDT: MOVEM TAC,USRDDT(PID) ;ROUTINE TO SET ONE'S DDT STARTING ADDRESS
POPJ P, ;RETURN TO USER
GETNAM: JUMPLE TAC,GETNA1 ;GET JOBNAME GIVEN JOB NUMBER
CAIL TAC,JOBN
GETNA1: MOVE TAC,J
MOVE TAC,JOBNAM(TAC)
JRST STOTAC
;WAIT, GETLN, SPCWAR (SPWBUT), EIOTM, LIOTM
;WAIT FOR IO TO BECOME INACTIVE ON CHANNEL SPECIFIED BY AC FIELD OF UUO
WAIT: JUMPE DDB,IOIERR ;JUMP IF NO CHANNEL IS ASSIGNED HERE.
JRST WAIT1 ;WAIT TILL INACTIVE BEFORE RETURNING TO USER.
GETLN: PUSHJ P,TTYFND ;GET NAME OF TTY
MOVE TAC,DEVNAM(DDB)
JRST STOTAC
;READ SPACEWAR BUTTONS
SPCWAR: CONI TV,TAC ;READ SWITCH REGISTER
JRST STOTAC
;EIOTM - ENTER IOT-USER MODE
;LIOTM - LEAVE IOT-USER MODE
EIOTM: MOVE TAC,JBTPRV(J)
TLNN TAC,LUPPRV
JRST UUOERR
MOVSI TAC,4000
ORM TAC,UUOPC(J)
POPJ P,
LIOTM: MOVSI TAC,4000
ANDCAM TAC,UUOPC(J)
POPJ P,
;CRKSER -- READ THE PETIT CLOCK. DATIME, DAT2, VENTIM
; J. SAUTER, REST OF PAGE.
;FOR A DESCRIPTION OF THE ON-LINE CALENDAR CLOCK SEE SAILON 9
;DATIME SKIP RETURNS IF CLOCK IS OK. RETURNS IN DAT THE SYSTEM
;FORMAT DATE, RETURNS IN ITEM THE COUNT OF TICKS SINCE MIDNIGHT
LOSYS
↑DATIME: ;CALLED FROM ONCE
MOVEI TAC1,1000 ;TRY ONLY 1000 TIMES
DAT2: CONI PCLK,TEM ;READ FAST PART.
DATAI PCLK,TAC ;READ SLOW PART.
JUMPG TAC,DAT1 ;CLOCK IS VALID.
DAT2A: SOJG TAC1,DAT2 ;INVALID, RETRY.
POPJ P, ;TOO MANY RETRIES, CONSIDER IT SICK.
DAT1: SUBI TAC,5004 ;NORMALIZE CROCK DATA.
SUB TEM,[2020136700] ;AND FAST PART.
LDB ITEM,[POINT 4,TEM,9]
LDB DAT,[POINT 4,TAC,35]
CAME DAT,ITEM ;DID READINGS GIVE THE SAME MINUTE?
JRST DAT2A ;NO. GO RETRY.
TLNE TAC,200000 ;YEAR INVALID?
POPJ P, ;YES. CROCK SICK.
LDB ITEM,[POINT 4,TAC,19] ;MONTH.
SUBI ITEM,4
CAIL ITEM,=12
POPJ P,
IMULI ITEM,=31
MOVEM ITEM,DAT
LDB ITEM,[POINT 5,TAC,24]
ADDM ITEM,DAT ;ADD IN DAY.
LDB TAC1,[POINT 4,TAC,11]
CAILE TAC1,=7 ;> 1979?
POPJ P, ;YES. LOOK GUYS: HERE'S ANOTHER BUG!
IMULI TAC1,=10
LDB ITEM,[POINT 4,TAC,15]
CAILE ITEM,=9
POPJ P, ;19WHAT?
ADD ITEM,TAC1
CAIGE ITEM,=76 ;ITS AFTER 1-JAN-76.
POPJ P,
SUBI ITEM,=64 ;NORMALIZE TO 1964.
IMULI ITEM,=12*=31
ADDM ITEM,DAT ;DAT IS NOW SET UP.
LDB TAC1,[POINT 5,TAC,29] ;HOUR.
CAIL TAC1,=24
POPJ P,
MOVE ITEM,TAC1
IMULI ITEM,=60*=60*=60
ANDI TAC,77 ;MINUTES
CAIL TAC,=60
POPJ P,
IMULI TAC,=60*=60
ADD ITEM,TAC
LDB TAC,[POINT 6,TEM,15] ;SECONDS.
CAIL TAC,=60
POPJ P,
IMULI TAC,=60
ADD ITEM,TAC ;ADD INTO RESULT.
LDB TAC,[POINT 20,TEM,35]
CAML TAC,[=1000000] ;CHECK MILLISECONDS.
POPJ P,
IDIVI TAC,<=1000000/JIFSEC>
ADD ITEM,TAC
DAT3: CAMGE DAT,THSDAT ;DON'T GO BACKWARDS
POPJ P,
CAME DAT,THSDAT ;USUALLY THE SAME DAY...
JRST DAT4 ;THIS IS DIFFERENT
CAMGE ITEM,TIME ;DON'T GO BACKWARDS
POPJ P, ;LOSER.
DAT4: CAML ITEM,MIDNIT ;LESS THAN AN ENTIRE DAY'S WORTH OF TICKS?
POPJ P, ;NO. LOSE!
JRST CPOPJ1 ;RETURN + 1.
IFKL10,<
↑VENTIM:PUSHJ P,RTIMBS ;READ PDP-11'S TIMEBASE
SKIPN KLTIME
SKIPE KLTIME+1
JRST .+2
POPJ P, ;NOBODY HOME
DMOVE TAC,KLTIME ;TAC,TAC1 ← TIMEBASE
DIV TAC,[=24*=3600*JIFSEC] ;DIVIDE BY JIFFIES PER DAY
PUSH P,TAC1 ;TIME IN JIFFIES
PUSHJ P,DCTOSD ;DAYCOUNT IN TAC1 TO SYSTEM DATE
MOVE DAT,TAC ;DAT ← DATE
POP P,ITEM ;POP TIME INTO ITEM
JRST DAT3
>;IFKL10
HISYS
;LOGIN UUO. FOR LOGIN CUSP ONLY.
; CALL AC,['LOGIN ']
; AC = -N,,LOC
; LOC = LOCATION OF TABLE OF LENGTH N. TABLE HAS LOGIN GOODIES.
;(1-14-72 REWRITTEN BY REG)
LOGIN: MOVSI TAC1,JLOG ;LOAD ONE BIT.
TDNE TAC1,JBTSTS(J) ;SKIP IF JOB NOT LOGGED IN
JRST UUOERR ;LOGGED IN ALREADY.
HLRO AC1,TAC ;GET -WORD COUNT
HRR UUO,TAC ;BASE OF DATA TABLE
MOVE AC2,[XWD -LOGTOP,LOGTAB] ;SET A DEPOSIT/CONTROL WORD
LOGIN1: AOJG AC1,LOGIN2 ;INCREMENT USER'S COUNT. SKIP IF EXHAUSTED
XCTR XR,[SKIPA AC3,(UUO)] ;GET DATA FROM USER AND SKIP
LOGIN2: MOVEI AC3,0 ;NO DATA FROM USER. USE ZERO
MOVEM AC3,@(AC2) ;STORE DATA IN JOB TABLE
ADDI UUO,1 ;PUSH USERS POINTER
AOBJN AC2,LOGIN1 ;LOOP UNTIL WE FILL MONITOR TABLES
IORM TAC1,JBTSTS(J) ;SET JLOG BIT IN JBTSTS
MOVSI TAC1,JACCT ;
ANDCAM TAC1,JBTSTS(J) ;CLEAR ACCOUNTING BIT
MOVE TAC1,JB2PRV(J) ;INITIALIZE PRIVS TO PASSIVE PRIVS
MOVEM TAC1,JBTPRV(J)
SETZM JBTUFD(J) ;ZERO UFD POINTER FOR NEW PPN
SETZM DSKPPN(J) ;INITIALIZE DISK ALIAS PPN
↑SETLOG: ;SET-UP USER TABLES FOR LOGIN AND OTHERS!
SKIPN JBTJL(J)
PUSHJ P,PRIBUF
;SPREAD SERVICE LEVEL TO THIS NEW JOB
HRRZ AC1,PRJPRG(J) ;GET PROGRAMMER NAME
MOVN TAC,SLNRES ;LOAD -NUMBER OF RESERVATIONS
JUMPE TAC,CPOPJ ;NO RESERVATIONS.
HRLZ TAC,TAC ;-SLNRES,,0 IN TAC
LOGIN4: HRRZ TAC1,SLRES(TAC) ;PROG NAME WHO HAS A RESERVATION
CAME TAC1,AC1 ;MATCH?
AOBJN TAC,LOGIN4 ;NO MATCH: LOOP
JUMPGE TAC,CPOPJ ;NO MATCH ANYWHERE.
HLRZ TAC,SLRES(TAC) ;GET HIS RESERVATION AS A RH FRACTION
MOVEM TAC,JBTGSL(J) ;SET GUARANTEED SERVICE LEVEL
POPJ P, ;STOW IT.
;TABLE OF TABLES SET BY LOGIN UUO. INCLUDE J AS INDEX REGISTER
;AND STORE @ THRU THIS TABLE.
LOGTAB: XWD J,PRJPRG ;USER NAME
XWD J,JB2PRV ;JOB PASSIVE PRIVLEGE BITS
LOGTOP←←.-LOGTAB ;NO. OF TABLES TO BE SET
; ROUTINE TO SET UP SCHEDULER DATA STRUCTURE FOR A JOB
↑PRIBUF:MOVEI AC3,JLLENGTH
PUSHJ P,FSGET
POPJ P, ;IF YOU LOSE, YOU LOSE
MOVEM AC1,JBTJL(J)
SETZM JBTJLH(J)
SETZM JBTGSL(J)
HRL AC2,AC1
HRRI AC2,1(AC1)
SETZM (AC1)
BLT AC2,JLLENGTH-1(AC1)
POPJ P,
;SETPRV, GETPRV
; SETPRV SET JBTPRV JOB PRIVILEGE BITS
; CALL AC,['SETPRV']
; JBTPRV WILL BE SET TO CONTENTS OF AC IF
; EITHER PRIPRV IS SET IN CURRENT JBTPRV OR JBTSTS INDICATES JACCT SET
; RETURN CONTENTS OF JBTPRV IN AC.
; IF AC REQUESTS FEWER PRIVILEGES THAN ARE NOW ALLOWED, THEN
; THE REQUEST WILL BE SUCESSFUL
; IF C(AC) = -1 THEN ONLY RETURN CURRENT CONTENTS OF JBTPRV
SETPRV: CAMN TAC,[-1] ;SKIP UNLESS SPECIAL CODE
JRST STPRV1 ;JUST GIVE HIM THE CURRENT CONTENTS
MOVSI TAC1,PRIPRV ;THE PRIVILEGE PRIVILEGE BIT
MOVSI AC1,JACCT ;ACCOUNTING PROG, BIT
TDNN AC1,JBTSTS(J) ;SKIP IF JACCT SET
TDNE TAC1,JB2PRV(J) ;SKIP UNLESS PRIPRV SET
MOVEM TAC,JBTPRV(J) ;STORE NEW PRIV BITS IF JACCT ∨ PRIPRV
CAMN TAC,JBTPRV(J) ;ARE THESE THE SAME NOW?
POPJ P, ;YES RETURN QUICK
ANDM TAC,JBTPRV(J) ;TURN OFF THE ONES HE IS NOT REQUESTING
MOVE TAC1,JB2PRV(J) ;11/19/74 ME+BH
IOR TAC1,JBTTPV(J) ; TO ALLOW TURN ON OF TEMP PRIVS
AND TAC,TAC1 ;LEAVE ON THE ONES HE CAN SET
IORM TAC,JBTPRV(J) ;AND SET THEM
STPRV1: MOVSI TAC,PRIPRV ;RETURN PRIPRV FROM JB2PRV
AND TAC,JB2PRV(J)
IOR TAC,JBTPRV(J) ;GET THE REST FROM JBTPRV
JRST STOTAC ;GIVE THEM BACK TO THE USER
;GET PRIVILEGES FOR JOB
;CALLING SEQUENCE:
; MOVE AC,[FUNC CODE,,JOB #]
; GETPRV AC,
; <ALWAYS RETURN HERE>
;CODE 0 ACTIVE PRIVILEGES
;CODE 1 PASSIVE PRIVILEGES
;CODE 2 TEMPORARY PRIVILEGES
GETPRV: HLRZ AC1,TAC ;GET FUNCTION CODE
CAIL AC1,MAXFNC ;LEGAL FUNCTION CODE
JRST UUOERR ;NO, FLUSH
HRRZ TAC,TAC ;GET JUST JOB #
CAIGE TAC,JOBN ;JOB # TO LARGE?
JUMPN TAC,.+2 ;OR 0?
MOVE TAC,J ;YES, USE CURRENT JOB
XCT FNCTAB(AC1) ;DO FUNCTION
JRST STOTAC ;RETURN ANSWER
FNCTAB: MOVE TAC,JBTPRV(TAC) ;ACTIVE PRIVILEGES
MOVE TAC,JB2PRV(TAC) ;PASSIVE PRIVILEGES
MOVE TAC,JBTTPV(TAC) ;TEMPORARY PRIVILEGES
MAXFNC←←.-FNCTAB
>
;RLEVEL, SLEVEL, SETRES - SERVICE LEVEL UUOS
;GET A PPN'S SERVICE LEVEL RESERVATION.
;CALLING
; MOVE AC,[SIXBIT /PPN/] ;ONLY THE PROG NAME IS USED
; CALL AC,[SIXBIT /RLEVEL/]
; RETURN HERE ALWAYS, AC = <SL RESERVATION IN %>,,PRG NAME,
; IF RESERVATION ≠ 0, OTHERWISE AC = 0,,0.
RLEVEL: HRRZ AC1,TAC ;GET PROGRAMMER NAME
MOVN TAC,SLNRES ;LOAD -NUMBER OF RESERVATIONS
JUMPE TAC,RTZERO ;NO RESERVATIONS: RETURN ZERO
HRLZ TAC,TAC ;-SLNRES,,0 IN TAC
RLEV1: HRRZ AC2,SLRES(TAC) ;PROG NAME WHO HAS A RESERVATION
CAME AC2,AC1 ;MATCH?
AOBJN TAC,RLEV1 ;NO MATCH: LOOP
JUMPGE TAC,RTZERO ;JUMP IF NO MATCH.
RLEV2: HLRZ TAC,SLRES(TAC) ;GET HIS RESERVATION AS A RH FRACTION
GETLV1: IMULI TAC,=100 ;MAKE IT LEFT HALF PERCENT
ADDI TAC,400000 ;ROUND IT. (LIKE YOU DID IN CLKSER)
HRR TAC,AC1 ;JOB NUMBER (OR PRG NAME) TO TAC
JRST STOTAC ;STOW IT.
;REG 12-5-72
SPRSSL: SETZM JBTGSL+1 ;SPREAD SERVICE LEVEL TO USERS WITH RESERVATIONS.
MOVE TAC,[JBTGSL+1,,JBTGSL+2]
BLT TAC,JBTGSL+JOBN-1 ;FIRST ZERO ALL LEVELS.
SKIPLE AC2,SLNRES ;GET THE NUMBER OF RESERVATIONS
CAILE AC2,SLRMAX ;SKIP IF REASONABLE NUMBER.
POPJ P, ;RETURN QUICK IF NONE.
SPRSS0: HRRZ TAC1,SLRES-1(AC2)
MOVE AC1,JOBNM1 ;LOOK THROUGH ALL THE JOBS
SPRSS1: HRRZ TAC,PRJPRG(AC1)
CAIE TAC1,(TAC)
JRST SPRSS2
HLRZ TAC,SLRES-1(AC2)
MOVEM TAC,JBTGSL(AC1)
SPRSS2: SOJG AC1,SPRSS1
SOJG AC2,SPRSS0
POPJ P,
;SET BELOW IS DISABLED!
;GET OR SET A JOBS SERVICE LEVEL.
;CALLING
; MOVE AC,[XWD %SLEVEL,JOB # ]
; CALL AC,[SIXBIT/SLEVEL/]
; RETURN HERE ALWAYS
;IF %SLEVEL<0 RETURN CURRENT %SL,,JOB NUMBER
;OTHERWISE SET SLEVEL OF JOB TO %SLEVEL
; SET IS ALLOWED ONLY IF JOB NUMBER GIVEN IS 0 OR USER'S JOB #
; IF SET COMMAND FAILS, USER'S AC WILL BE SET TO
; - % AVAILABLE
;ALSO SET IT FOR HIS OTHER JOBS.
;IF JOB # = 0 USE THIS JOB
;IF JOB # = -1, AND SERVICE LEVEL MONITOR IS THE USER,
; THEN RESET THE SL RESERVATION TABLE.
SETLVL: HRRZ AC1,TAC ;GET JOB NUMBER
CAIL AC1,JOBN ;LEGAL JOB?
JRST SETRES ;NO. MAYBE SL MONITOR CHANGING RESERVATIONS
JUMPG AC1,.+2 ;SKIP UNLESS ZERO
MOVE AC1,J ;ZERO MEANS THIS JOB.
PUSH P,AC1 ;THESE 5 INSTRUCTIONS: REG 12-5-72
PUSHJ P,SPRSSL ;SPREAD ALL SERVICE LEVELS
POP P,AC1
HRRZ TAC,JBTGSL(AC1)
JRST GETLV1
;;; WE ARRIVE HERE IF A NEGATIVE JOB NUMBER IS SPECIFIED.
;;; THIS IS ALWAYS ILLEGAL UNLESS THE JOB HAS THE SSL PRIVILEGE,
;;; IN WHICH CASE THE CURRENT SLRESERVATION TABLE IS BEING RESET,
;;; AND THE CALLING SEQUENCE WAS:
;;;
;;; MOVE AC,[XWD [ XWD <0,1, OR 2>,N
;;; <1ST TABLE ENTRY>
;;; <2ND TABLE ENTRY>
;;; ...
;;; <NTH TABLE ENTRY>],-1]
;;; CALL AC,[SIXBIT /SLEVEL/]
;;; FAILURE RETURN (N TOO LARGE, TOTAL SL TOO MUCH, ETC.)
;;; SUCCESS RETURN
SETRES: CAIE AC1,-1
JRST RTZERO
MOVE TAC1,JBTPRV(J) ;GET THE USER'S PRIV BITS
TLNN TAC1,SSLPRV ;SKIP IF HE HAS THE PRIVILEGE
JRST RTZERO ;RETURN ZERO.
;;; THIS IS THE CODE THAT READS A NEW SL RESERVATION TABLE FROM
;;; GSLMON AND GIVES THE RESERVED AMOUNTS TO ANYBODY CURRENTLY
;;; LOGGED IN, DECREASING THE SL OF SCROUNGERS IF NECESSARY.
XCTR XR,[HLRZ TAC1,(UUO)] ;TAC1 ← USER REL. ADDR. OF TABLE INFO.
XCTR XR,[HLRZ AC2,(TAC1)] ;AC2 ← CORE COST OF SL = 0,1 OR 2
CAIL AC2,3 ;IS 0 ≤ (TAC) ≤ 2 ?
MOVEI AC2,1 ;NO, MAKE IT 1.
MOVEM AC2,SLCOST ;STORE IN SL DATA AREA
XCTR XR,[HRRZ TAC,(TAC1)] ;TAC ← (# OF RESERVATIONS)
CAILE TAC,SLRMAX ;TOO MANY RESERVATIONS?
JRST SETAL0 ;YES, FAILURE EXIT
MOVSI AC2,(TAC1) ;SOURCE OF BLT (USER-RELATIVE)
HRRI AC2,SLNRES ;DESTINATION OF BLT
XCTR XBLTR,[BLT AC2,SLNRES(TAC)];BLT NEW RES TABLE INTO SYSTEM
HRRZS SLNRES ;ZERO OUT THE 0,1,OR 2 IN LEFT HALF,
MOVEI TAC1,0 ;ADD UP NEW RESERVATIONS...
HLRZ AC1,SLNRES(TAC)
ADD TAC1,AC1
SOJG TAC,.-2
CAIG TAC1,<XWD MAXLEV,0>/=100+SLRMAX ;TOO MUCH RESERVED SL?
SETAL1: AOSA (P) ;NOT TOO MUCH. SET SKIP RETURN
SETAL0: SETZM SLNRES ;TOO MUCH. CLEAR TABLE.
JRST SPRSSL ;SPREAD NEW TABLE
;LOGOUT UUO
LOGOUT: MOVSI TAC,JACCT ;IS HE REALLY THE LOGOUT ROUTINE?
TDNN TAC,JBTSTS(J) ;SEE IF THE ACCOUNTING BIT IS ON
JRST UUOERR ;NOT ON, HE IS A FAKE!
JRST JOBKL ;ALL OK. LOG HIM OUT.
;SWAP UUO, RUN UUO
; FORMAT AS FOLLOWS . . .
; MOVE AC,[E,,F]
; CALL AC,[SIXBIT /SWAP/]
;E: SIXBIT /DEVICE/
; SIXBIT /FILENAME/
; SIXBIT /EXTENSION/ + MODE BITS
; XWD (CORESIZE - IN K),(STARTING ADDRESS)
; SIXBIT /PROJ-PROG NUMBER/
; IF STARTING ADDRESS IS ZERO, C(JOBSA) WILL BE USED
; IF E=0, NO SAVE WILL BE DONE
;F: SIXBIT /DEVICE/
; SIXBIT /FILENAME/
; SIXBIT /EXTENSION/ + MODE BITS
; XWD (CORESIZE - IN K),(STARTING ADDRESS INCREMENT)
; SIXBIT /PROJ-PROG NUMBER/
; IF F=0, NO RUN WILL BE DONE. IF E=F=0, THE UUO IS A NO-OP
; MODE BIT 35 = DO NOT START JOB. JUST GET CORE IMAGE.
; MODE BIT 34 = MAKE STARTING ADDRESS ABSOLUTE, NOT AN INCREMENT
; MODE BIT 33 = LOGIN NEW JOB AND RUN THIS THERE!
; MODE BIT 32 = DON'T SET JLOG
; RUN UUO INCLUDED FOR COMPATABILITY WITH DEC SYSTEMS:
; MOVE AC,[<STARTING INCREMENT>,,G]
; CALL AC,[SIXBIT/RUN/]
;
;G: SIXBIT /DEVICE/
; SIXBIT /FILENAME/
; SIXBIT /EXT/
; 0
; SIXBIT /PROJ-PROG NUMBER/
; 0,,<DESIRED CONTENTS OF JOBREL>
RUNUUO: PUSHJ P,SVUACS
HLRM TAC,SAVSAI(J) ;SET START INCREMENT
XCTR XR,[HRRZ TAC1,5(TAC)]
XCTR XW,[MOVEM TAC1,JOBCOR] ;SET CORE SIZE
HRROI AC1,(TAC) ;COPY PNTR WITH "RUN" FLAG
JRST RUNUU2 ;NOW ENTER SWAP UUO
; SWAP UUO
SYSRJB: PUSHJ P,INTTST ;MAKE SURE NO SPACEWAR, NO INTLEVEL
XCTR XR,[SKIPN AC1,(UCHN)] ;PICK UP ADDRESSES OF TABLES, IF ANY
POPJ P, ;NONE, NO-OP
XCTR XW,[MOVEM AC1,JOBFDV] ;SAVE TABLE ADDRESS OF GET SIDE
MOVE AC1,UUOPC(J) ;SAVE RETURN ADDRESS
XCTR XW,[MOVEM AC1,JOBOPC]
PUSHJ P,SVUACS ;SAVE USER'S ACS
XCTR XR,[HLRZ AC1,JOBFDV] ;PICK UP 'SAVE' TABLE ADDRESS
JUMPE AC1,SYSRJ1 ;IF ZERO OMIT THE SAVE.
PUSHJ P,SYSRS ;GET SAVE-ARGUMENTS FROM USER
JSP TAC1,SG1 ;OPEN DEVICE. DOES SUPERFLUOUS LOOKUP
;SG1 CLOBBERS ACS (P) BECAUSE IT THINKS IT IS BEING RUN AS A "MONITOR JOB"
;DO NOT CLOBBER ANY ACS BETWEEN SG1 AND SAVJBB
JFCL
PUSH P,AC1
HRRZ AC1,SAVSAI(J) ;PICK UP NEW STARTING ADDRESS
JUMPE AC1,SYSSJ1 ;JUMP IF THERE WAS NONE
XCTR XR,[SKIP (AC1)] ;TEST TO BE SURE ADDRESS IS LEGAL
XCTR XRW,[HRRM AC1,JOBSA] ;STUFF NEW STARTING ADDRESS IN CORE
SYSSJ1: XCTR XW,[SETZM NEWCOR] ;ASSUME SAVE, NOT SSAVE.
XCTR XR,[MOVE AC1,INCWRD] ;FETCH SAVE-SIDE MODE BITS
TRNE AC1,1 ;SSAVE?
XCTR XW,[SETOM NEWCOR] ;SET FLAG FOR SSAVE
POP P,AC1
PUSHJ P,SAVJBB ;DO ACTUAL SAVE
PUSHJ P,RSUACX ;RESTORE USER'S ACS IN CASE ARGS ARE THERE
SYSRJ1: XCTR XR,[HRRZ AC1,JOBFDV] ;GET 'RUN' TABLE ADDRESS BACK
JUMPE AC1,SYSRXT ;IF ZERO, EXIT GRACEFULLY
XCTR XR,[MOVE TAC1,2(AC1)] ;GET MODE BITS FIRST!
TRNE TAC1,4 ;TEST FOR PHANTOM STARTUP.
JRST PHANTOM ;YES!
RUNUU2: PUSHJ P,SYSRS ;(HERE FROM RUN UUO) GET RUN-SIDE ARGS
PRUNJB: JSP TAC1,SG1 ;ASSIGN DEVICE, DO LOOKUP, AND RESET PDL
JRST NOFILE ;NO FILE?
PUSHJ P,GETJB ;READ JOB IN
MOVSI AC1,USRMOD ;MAKE SURE HE GETS INTO USER MODE
XCTR XR,[HRR AC1,JOBSA] ;PICK UP STARTING ADDRESS
XCTR XR,[MOVE AC2,INCWRD] ;PICK UP OUR MODE BITS AGAIN
PUSH P,AC1 ;PUT THAT ADDRESS ON THE STACK
MOVE J,JOB(PID) ;PICK UP JOB NUMBER
TRNE AC2,2 ;IF BIT 34 ON, INHIBIT ADDING IN HIS STARTING ADDRESS
SKIPA AC1,SAVSAI(J) ;INSTEAD, PICK UP INCREMENT AND USE IT!
ADD AC1,SAVSAI(J) ;PICK UP STARTING ADDRESS INCREMENT
XCTR XR,[SKIP (AC1)] ;SEE IF ADDRESS IS IN BOUNDS
HRRM AC1,(P) ;UPDATE STARTING ADDRESS
PUSH P,AC2 ;SAVE MODE BITS
PUSHJ P,RSUACS ;RESTORE USER'S ACCUMULATORS
POP P,AC2 ;MODE BITS
POP P,UUOPC(J) ;"UUO RETURN ADDRESS"
TRNN AC2,1 ;IF MODE BIT 35 IS ON, DON'T START JOB
JRST USRXIT ;START USER BY EXITING UUOCON
JRST GETJ1 ;EXIT PRINTING "JOB SETUP" MESSAGE
SYSRXT: PUSHJ P,RSUACS ;RESTORE USER ACS
SYSRX2: XCTR XR,[MOVE TAC,JOBOPC] ;GET UUO RETURN ADDRESS
MOVEM TAC,UUOPC(J) ;AND RETURN TO IT!
JRST USRXIT ;MAKE IT LOOK LIKE A UUO EXIT (WHICH IT IS)
; ROUTINE TO PICK UP BITS OF USER'S GOODIE TABLE
; IF LH OF AC1 IS -1 THEN THIS WE'RE HERE FROM THE RUN UUO.
;THIS CODE'S BEEN REORGANIZED TO PERMIT ARGUMENT BLOCK TO BE ANYWHERE IN ACS.
SYSRS: XCTR XR,[MOVE TAC1,4(AC1)] ;START WITH PPN
MOVEM TAC1,JOBPPN(J)
XCTR XR,[PUSH P,(AC1)] ;SAVE DEVICE NAME
XCTR XR,[PUSH P,1(AC1)] ;SAVE FILE NAME
XCTR XR,[PUSH P,2(AC1)] ;SAVE EXTENSION,,MODE BITS
JUMPL AC1,SYSRS1 ;JUMP IF RUN UUO
XCTR XR,[MOVE TAC1,3(AC1)] ;PICK UP CORE SIZE,,STARTING INCREMENT
HRRM TAC1,SAVSAI(J) ;STORE STARTING INCREMENT
HLRZ TAC1,TAC1 ;GET CORE SIZE IN K
LSH TAC1,12 ;CONVERT TO WORD COUNT
JUMPE TAC1,.+2 ;UNLESS, OF COURSE, HE ASKED FOR NONE
SUBI TAC1,1
XCTR XW,[MOVEM TAC1,JOBCOR]
SYSRS1: POP P,TAC1 ;GET EXTENSION AND MODE BITS
TLNN TAC1,-1 ;SKIP IF EXTENSION SPECIFIED.
HRLI TAC1,'DMP' ;HE REALLY WANTS .DMP
XCTR XW,[HLLZM TAC1,FILEXT] ;STORE FILE EXTENSION
XCTR XW,[HRRZM TAC1,INCWRD] ;AND SAVE MODE BITS
POP P,TAC1 ;FILE NAME
XCTR XW,[MOVEM TAC1,FILNAM] ;FOR LOOKUP/ENTER IN SAVGET
MOVEM TAC1,JOBNAM(J) ;THIS IS NEW JOB NAME TOO
IFN FTSTAT,<PUSHJ P,NAMSTT>
XCTR XW,[POP P,DEVWRD] ;DEVICE NAME FOR SAVJOB
POPJ P,
; ROUTINE TO SAVE ACCUMULATORS OVER RUNJOB UUO
SVUACS: HLRZ AC1,SAVSAI(J) ; ANY FREE STORAGE HERE ALREADY?
JUMPE AC1,SVUA2 ; NO, GET SOME
CAML AC1,MEMSIZ ; IS IT IN THE FREE STORAGE AREA?
CAML AC1,RMEMSIZ ; IT IS ABOVE USER CORE. IS IT IN REAL CORE?
JRST .+2 ;THINK ABOUT IT SOME MORE, ANDY.
JRST SVUA1 ;YES, USE IT
PUSHACS
PUSHJ P,DISMES
ASCIZ /GARBAGE IN SAVSAI LEFT HALF!
/
POPACS
SVUA2: MOVEI AC3,20 ;GET A 20-WORD BLOCK OF FREE STORAGE
PUSHJ P,UFSGET ;GET FREE STORAGE AT UUO LEVEL
HRLM AC1,SAVSAI(J) ;SAVE THE POINTER
SVUA1: HRLI AC1,0 ;BLT USER 0-17 INTO THE SYSTEM
HRR AC2,AC1
XCTR XBLTR,[BLT AC1,17(AC2)] ;RELOCATE "FROM OF BLT"
POPJ P,
RSUACS: PUSHJ P,RSUACX ;RESTORE USER ACS THEN FLUSH FS. BLOCK
HLRZ AC1,SAVSAI(J) ;GET ADDRESS OF BLOCK.
SETZM SAVSAI(J) ;ZERO OUT FS POINTER
JUMPN AC1,FSGIVE
POPJ P,
RSUACX: HLLZ AC1,SAVSAI(J) ;PICK UP FREE STORAGE POINTER,,0
JUMPE AC1,CPOPJ ;NOBODY HOME
XCTR XBLTW,[BLT AC1,17] ;STORE IN USER SPACE. (RELOCATE "TO OF BLT")
POPJ P, ;RESTORE ACS WITHOUT FLUSHING FS BLOCK
; SWAP UUO - LOG IN NEW JOB AND RUN THIS ON IT - PHANTOM STARTUP
PHANTO: HLLZ TAC,SAVSAI(J) ;FREE STORAGE ADDRESS,,0
XCTR XBLTW,[BLT TAC,17] ;COPY OLD ACS BACK TO USER SPACE.
XCTR XR,[SKIPN TAC,5(AC1)] ;PRJPRG
MOVE TAC,PRJPRG(J) ;USE CURRENT PPN
CAMN TAC,PRJPRG(J) ;IS HE DOING IT TO HIMSELF?
JRST PHWIN ;YES
CAMN TAC,SYSPPN ;1,1
JRST PHLOS1 ;LOSE.
PHWIN: PUSH P,J ;SAVE PRESENT JOB NUMBER
PUSHJ P,INIJOB ;INITIALIZE A NEW JOB
JRST PHLOSE ;NO JOBS TO BE HAD
JFCL
MOVSI TAC,JNA
IORM TAC,JBTSTS(J)
TLNN TAC1,-1 ;WAS ANY EXTENSION SPECIFIED?
HRLI TAC1,'DMP' ;NO. USE 'DMP'
MOVEM TAC1,JOBLOG(J) ;SAVE MODE BITS AND EXTENSION
MOVSI TAC,JLOG
TRNN TAC1,10 ;THIS BIT SAYS DON'T SET JLOG
IORM TAC,JBTSTS(J)
SETZM JBTUFD(J) ;FLUSH THIS OR ELSE!
SETZM DSKPPN(J) ;INITIALIZE DISK ALIAS PPN
SETZM JBTKCJ(J) ;INITIALIZE KILO CORE SECONDS
XCTR XR,[MOVE TAC1,(AC1)] ;DEVICE
MOVEM TAC1,JOBDEV(J)
XCTR XR,[MOVE TAC1,1(AC1)] ;FILENAME
MOVEM TAC1,JOBNAM(J)
IFN FTSTAT,< PUSHJ P,NAMSTT>
XCTR XR,[MOVE TAC1,4(AC1)] ;LOC OF FILE
MOVEM TAC1,JOBPPN(J)
MOVE TAC,(P) ;GET OUR J TEMPORARILY
XCTR XR,[SKIPN TAC1,5(AC1)] ;PPN
MOVE TAC1,PRJPRG(TAC) ;NONE, USE CURRENT
MOVEM TAC1,PRJPRG(J)
CAME TAC1,PRJPRG(TAC) ;SAME AS CALLER?
TDZA TAC1,TAC1 ;NO. ZERO PRIVILEGES AND SKIP.
MOVE TAC1,JBTPRV(TAC) ;SAME PPN. COPY OUR PRIVILEGES TO NEW GUY.
PUSH P,TAC1 ;SAVE PRIV WORD FOR NEW GUY.
MOVSI TAC1,LUPPRV
TDNE TAC1,JBTPRV(TAC) ;SKIP IF CALLER DOESN'T HAVE LUPPRV
IORM TAC1,(P) ;COPY CALLER'S LUPPRV TO NEW GUY.
POP P,JBTPRV(J) ;NEW GUY'S PRIVS.
MOVE TAC1,PRJPRG(TAC) ;GET OUR PPN
CAME TAC1,PRJPRG(J) ;SAME AS HIS?
TDZA TAC1,TAC1 ;NO, NO PRIVILEGES
MOVE TAC1,JB2PRV(TAC) ;ALSO PASSIVE PRIVILEGES
MOVEM TAC1,JB2PRV(J)
XCTR XR,[MOVS TAC1,3(AC1)] ;GET S.A.,,CORE SIZE
HRRZM TAC1,JOBCRD(J) ;PASS ON CORE SIZE
MOVE TAC,(P) ;CALLERS JOB #
HLR TAC1,SAVSAI(TAC)
MOVSM TAC1,SAVSAI(J) ;GIVE AC BLK AND S.A. TO NEW JOB
SETZM SAVSAI(TAC) ;NO LONGER BELONGS TO CALLER
ADDI TAC1,(UCHN)
MOVEM TAC,(TAC1) ;CALLERS JOB # TO NEW JOB (IN SAME AC)
XCTR XW,[MOVEM J,(UCHN)] ;NEW JOB # TO CALLER
PUSHJ P,DELBTT
POP P,J
JRST SYSRX2 ;DON'T BOTHER LOOKING FOR ACS
PHLOSE: POP P,J
PHLOS1: PUSHJ P,RSUACS ;RESTORE ACS.
SETZM (UCHN) ;FLAG FAILURE BY RETURNING ZERO
JRST SYSRX2
;PNAME, USTAT
; UUO TO GET THE PHYSICAL NAME OF A DEVICE
; PUT THE SIXBIT OF THE DEVICE LOGICAL NAME IN AN AC
; DO A 'CALL AC,[SIXBIT /PNAME/]
; AND THE ROUTINE SKIPS UPON SUCCESS (IE, IF DEVICE NAME EXISTS)
; AND RETURNS PHYSICAL NAME IN THAT AC
PNAME: PUSHJ P,FNDDDB ; SEARCH FOR DEVICE NAME (OR CHANNEL #)
POPJ P, ; FAILURE
MOVE TAC,DEVNAM(DDB) ; PICK UP PHYSICAL NAME
XCTR XW,[MOVEM TAC,(UCHN)]
JRST CPOPJ1
; GET A JOB'S JOB STATUS WORD
; CALLING . . .
; MOVE AC,<JOB NUMBER IN QUESTION>
; CALL AC,[SIXBIT /JBTSTS/]
; RETURNS JOB STATUS WORD IN AC
USTAT: JUMPG TAC,.+2 ; POSITIVE JOB NUMBER?
MOVE TAC,J ; LESS OR EQUAL TO ZERO MEANS OWN JOB
CAIL TAC,JOBN ; MUST BE LESS THAN MAXIMUM TOO
JRST UUOERR ; OR ELSE, ERROR
MOVE TAC,JBTSTS(TAC) ; GET STATUS WORD
JRST STOTAC ; AND GIVE IT TO HIM
;TTYIOS, GET A TELETYPE'S DEVIOS
; CALLING . . .
; MOVE AC,<JOB NUMBER WHOSE TTY IOS YOU WANT>
; CALL AC,[SIXBIT /TTYIOS/]
TTYIOS: JUMPL TAC,TTYIO3 ;TRY NAME IF ILLEGAL NUMBER
CAIL TAC,JOBN
JRST TTYIO3 ;ILLEGAL AS A JOB NUMBER, TRY AS A DEV NAME.
HLRZ DDB,DEVLST
TTYIO1: HLRZ TAC1,DEVNAM(DDB) ;IS THIS A TELETYPE?
CAIE TAC1,'TTY'
JRST TTYIO2 ;NO. KEEP LOOKING.
LDB TAC1,PJOBN ;YES, DOES THE JOB NUMBER MATCH?
CAIE TAC1,(TAC)
JRST TTYIO2 ;NO, SCAN SOME MORE
TTYIO5: MOVE TAC,DEVIOS(DDB) ;YES, PICK UP HIS IOS
JRST STOTAC ;AND GIVE IT TO HIM
TTYIO2: HLRZ DDB,DEVSER(DDB) ;PICK UP NEXT DEVICE DATA BLOCK ADDRESS
JUMPN DDB,TTYIO1 ;AND GO BACK IF NOT END OF LIST
TTYIO4: MOVNI TAC,1 ; IF END OF LIST, GIVE HIM A -1 TO CHEW ON
JRST STOTAC
TTYIO3: PUSHJ P,DEVSRC ;TRY SEARCHING FOR THIS SIXBIT NAME.
JRST TTYIO4 ;LOSE.
JRST TTYIO5 ;WIN.
;WAKEME
COMMENT $
CALL: MOVE AC,<ADDRESS OF 3 WORD BLOCK>
CALL AC,['WAKEME']
<ERROR: JOB NAMED WAS NOT IN BATMAN AND ROBIN, ELSE MAINTMODE SET>
BLOCK CONTAINS
JOBNAME
PPN
DATA
IF JOBNAME AND PPN ARE FOUND IN BATMAN AND ROBIN THEN
SET ALFRED TO DATA. DATA IS INTERPRETED AS FOLLOWS
<0 MEANS NEVER START THIS
=0 MEANS KEEP THIS JOB RUNNING
>0 DATA IS INTERPRETED AS
DATE,,TIME IN MINUTES
WHEN TO START THIS AGAIN.
ALFRED IS ZEROED AT SYSINI, SO ALL JOBS NAMED IN BATMAN WILL
BE STARTED AT RELOADS AND RESTARTS
$
WAKEME:
IFN FTBAT,<
SKIPE MAINTMODE ;SKIP IF NORMAL MODE
POPJ P, ;ERROR RETURN IF MAINTMODE
XCTR XR,[MOVE AC1,(UCHN)] ;GET USER'S POINTER
XCTR XR,[MOVE AC2,(AC1)] ;GET JOBNAME
XCTR XR,[MOVE AC3,1(AC1)] ;GET PPN
MOVSI TAC,-BATLEN ;GET SIZE OF BATMAN
WAKEM1: CAMN AC2,BATMAN(TAC) ;LOOK IN TABLE
CAME AC3,ROBIN(TAC) ;SAME AS TABLE?
JRST WAKEM2 ;NO
XCTR XR,[SKIPGE AC3,2(AC1)] ;GET DATA FOR ALFRED
JRST WAKEM3 ;RUN NEVER.
MOVE AC1,TIME
IDIVI AC1,=60*JIFSEC
HRL AC1,THSDAT
CAMG AC3,AC1 ;SKIP IF RUN IN THE FUTURE
SETZM BATYET ;MAKE CH7 LOOK NEXT TICK
WAKEM3: MOVEM AC3,ALFRED(TAC) ;STUFF IT
JRST CPOPJ1 ;GIVE HIM SUCCESS RETURN
WAKEM2: AOBJN TAC,WAKEM1 ;LOOK THRU TABLE
>
POPJ P, ;LOSE
;TRANSLATE SYSTEM CALL TO/FROM SIXBIT.
;CALL: MOVE AC,[SIXBIT OR NUMERIC UUO]
; CALLIT AC,
; RETURN WITH NUMERIC OR SIXBIT FORM (RESP.), 0 IF ERROR
;IF AC12-16 ≠ 0, ARG IS ASSUMED TO BE SIXBIT (ALL UUO MNEMONICS ARE > 2 CHARS)
; NUMERIC REPRESENTATION WILL BE RETURNED, OR 0 IF THE SPECIFIED UUO DOES
; NOT EXIST. NOTE THAT CALLING THIS WITH 1- OR 2-CHARACTER NAMES MAY HAVE
; STRANGE RESULTS.
;IF AC12-17 = 0, ARG IS ASSUMED TO BE A NUMERIC UUO OF SOME FORM. THE AC AND
; ADDRESS FIELDS MUST BE 0 UNLESS RELEVANT FOR DECODING (I.E. ADR OF CALLI,
; AC OF TTYUUO, ETC.). IF THE ARG IS A LEGAL UUO, ITS SIXBIT MNEMONIC WILL BE
; RETURNED, OTHERWISE 0. IN THE EVENT OF AMBIGUITY, THE MORE SPECIFIC MNEMONIC
; WILL BE RETURNED (E.G. INCHRW RATHER THAN TTYUUO).
;IF AC12-17 = 1, THE MNEMONIC FOR THE SPECIFIED MAJOR OPCODE WILL BE RETURNED.
; THE AC AND ADDRESS FIELDS MUST BE 0. THIS PROVIDES A WAY TO GET AT MNEMONICS
; SUCH AS "TTYUUO".
CALLIT: TLNE TAC,36 ;IF ITS SIXBIT
JRST CALT0 ; THEN GO LOOK IT UP
HLRZ TAC1,TAC
CAIE TAC1,(<CALLI>)
JUMPN TAC1,CALTU
ANDI TAC,-1
CAIGE TAC,UCLDLN ;IF ITS A DEC CALLI
JRST CALT1 ; THEN GET THE SIXBIT
TRZN TAC,400000 ;IF NOT A STANFORD CALLI
JRST RTZERO ; THEN RETURN 0
MOVEI TAC,UCLDLN(TAC) ;GET ACTUAL POINTER
CAIL TAC,UCLLEN ;IF ITS OFF THE END
JRST RTZERO ; THEN RETURN 0
CALT1: MOVE TAC,UCLTAB(TAC) ;ELSE PICK UP SIXBIT
JRST STOTAC ;THEN PUT IT IN AC AND RETURN
CALT0: MOVSI TAC1,-UCLLEN
CAME TAC,UCLTAB(TAC1) ;SEARCH CALLI SIXBIT TABLE
AOBJN TAC1,.-1
JUMPGE TAC1,CALT2 ;IF OFF THE END, TRY FOR OPCODES
MOVEI TAC,(TAC1)
CAIL TAC,UCLDLN ;IF STANFORD CALL
MOVEI TAC,400000-UCLDLN(TAC) ;THEN CONVERT
HRLI TAC,(<CALLI>) ;MAKE IT A CALLI
JRST STOTAC ; AND SHIP IT
CALTU: ANDI TAC1,777000
CAIL TAC1,40000
CAIL TAC1,700000+IUUMAX*2000
JRST CALT0 ;OUTSIDE UUO RANGE - TRY AS SIXBIT
CAIL TAC1,100000
CAIL TAC1,700000
TRNE TAC,-1
JRST CALT0 ;IN BETWEEN RANGES OR RH NOT ZERO
TLZE TAC,1
JRST CALTU2 ;SPECIAL - FORCE MAJOR OPCODE NAME
MOVSI AC1,(TAC1)
MOVSI AC2,1000(TAC1)
MOVEI TAC1,UUONAM ;HEADER FOR SECOND LEVEL TABLES
CALTU1: HRRZ TAC1,-1(TAC1)
JUMPE TAC1,CALTU2 ;NO MORE - MUST BE PLAIN UUO
CAMG AC1,-1(TAC1)
CAMG AC2,-1(TAC1)
JRST CALTU1 ;NOT THIS ONE
HLLZ AC3,-1(TAC1) ;GET OPCODE
CAMLE TAC,AC3
JRST RTZERO ;ILLEGAL AC FIELD
ROT TAC,15
ANDI TAC,17 ;ISOLATE AC FIELD
ADD TAC,TAC1
MOVE TAC,(TAC) ;GET SIXBIT
JRST STOTAC
CALTU2: TLNE TAC,(<17,>)
JRST RTZERO ;AC FIELD MUST BE ZERO
ROT TAC,9 ;GET OPCODE
CAIL TAC,700
SKIPA TAC,UUONAM+40-700(TAC)
MOVE TAC,UUONAM-40(TAC)
JRST STOTAC
CALT2: MOVSI TAC1,-IUUMAX*2-40 ;TOTAL # MAJOR OPCODES
CAME TAC,UUONAM(TAC1)
AOBJN TAC1,.-1
JUMPGE TAC1,CALT3 ;NOT FOUND - TRY SECOND LEVEL TABLES
MOVEI TAC,40(TAC1) ;THIS WILL BE THE OPCODE
CAILE TAC,77
MOVEI TAC,700-40(TAC1) ;UNLESS IT'S ONE OF THESE
ROT TAC,-9 ;PUT IT IN THE RIGHT PLACE
JRST STOTAC
CALT3: MOVE DAT,[,UUONAM(TAC1)];INIT TABLE PNTR TO HDR, (TAC1) FOR @ BELOW
CALT4: HRR DAT,-1(DAT) ;GET NEXT TABLE LOC
TRNN DAT,-1
JRST RTZERO ;IF NO MORE JUST RET 0 FOR FAILURE
LDB TAC1,[270400,,-1(DAT)];GET MAX #
MOVNI TAC1,1(TAC1) ;OFFSET BY 1 FOR COUNT
MOVSI TAC1,(TAC1) ;MAKE AOBJN PNTR
CAME TAC,@DAT
AOBJN TAC1,.-1
JUMPGE TAC1,CALT4 ;TRY NEXT TABLE IF NOT FOUND
HLLZ TAC,-1(DAT) ;FOUND - GET BASE OPCODE
DPB TAC1,[270400,,TAC] ;SET CORRECT AC FIELD
JRST STOTAC
BEGIN SEGUUO ↔ SUBTTL UUO'S FOR HIGH SEGMENTS ;SETPR2, GETHI
; SETPR2 UUO
; MOVE AC,[PROT,,RELOC]
; SETPR2 AC,
; <ERROR RETURN>
; <SUCCESS RETURN>
;
; RELOC IS ABSOLUTE ADDRESS YOU WISH AS YOUR BASE ADDRESS
; IF THE LOW ORDER BIT IS ON THEN RELOC IS A RELATIVE ADDRESS
; IN YOUR CORE IMAGE.
; IF THE LOW ORDER BIT OF PROT IS ON THEN ACCESS IS WRITE PROTECTED
; IF THE ACCESS IS ABSOLUTE AND YOU DON'T HAVE THE ACW PRIV THEN YOU ARE
; AUTOMATICALLY WRITE PROTECTED.
; BOTH PROT. AND RELOC. ARE TRUNCATED TO 1K BOUNDARIES WHEN LOADED
; INTO THE PROT.-RELOC. REGISTER.
; IN RELATIVE MODE PROT. IS ADJUSTED TO BE WITHIN YOUR CORE IMAGE.
↑SETPR2:TRNE TAC,1 ;IS THIS RELATIVE?
JRST PR2REL
MOVEI TAC1,(TAC)
ANDCMI TAC1,1777
CAML TAC1,RMEMSIZ ;IS RELOC GREATER THAN MEMORY?
POPJ P, ;YES, LOSE
MOVE TAC1,RMEMSIZ
CAILE TAC1,-1 ;FULL HOUSE?
JRST SETPRW ;YES. LET HIM WRAP AROUND.
HLRZ TAC1,TAC ;PROTECTION DESIRED
TRO TAC1,1777
HRRZ AC1,TAC ;RELOCATION DESIRED
ANDCMI AC1,1777
ADDI TAC1,(AC1) ;BH 7/30/74 HE REALLY WANTED THE UPPER BOUND!
CAML TAC1,RMEMSIZ ;IS PROTECT GREATER THAN MEMORY?
POPJ P, ;YES
SETPRW: MOVE TAC1,JBTPRV(J) ;GET THIS GUY'S PRIV BITS
TLNN TAC1,ACWPRV ;SKIP IF HE HAS ABS CORE WRITE PRIV
TLO TAC,1 ;NO, WRITE PROTECT AUTOMATICALLY
JRST PR2SET
IFN FTXCOR,<
;CALL: MOVE AC,[# OF PAGES,,STARTING PAGE*40+FLAGS]
; GETHI AC,
; <ERROR RETURN>
; <SUCCESS RETURN>
;FLAGS= 20 FOR WRITE PERMISSION
; 10 FOR PARITY ERROR SUPPRESSION (SEE PARSER)
;NUMBER OF PAGES MUST BE 400 OR FEWER.
;
;SPECIAL PURPOSE UPPER SEGMENT MAP MUNGING UUO.
;ATTACHES CERTAIN PHYSICAL ADDRESSES AS THIS JOB'S UPPER SEGMENT.
;FLUSHES ANY UPPER THAT EXISTED PRIOR TO THIS CALL.
;SUCCEEDS UNLESS LOWER IS BIGGER THAN 128K.
↑GETHI: HLRZ TAC1,JBTPAG(J)
HLRZ AC1,TAC ;NUMBER OF PAGES FROM THE USER'S ARGUMENT
CAIG AC1,400 ;SKIP IF NEW UPPER IS TOO BIG.
CAILE TAC1,400
POPJ P, ;LOWER IS TOO BIG
MOVE TAC1,JBTPRV(J)
TLNN TAC1,ACWPRV ;SKIP IF HE CAN WRITE ANYWHERE
TRNN TAC,20 ;NOT ALLOWED TO WRITE. SKIP IF HE'S TRYING
JRST .+2 ;WRITE PERMITTED, OR NOT WRITING
POPJ P, ;DISALLOW WRITE WITHOUT PERMISSION
IFN FTEXPG,<
LDB TAC1,[POINT 13,TAC,30] ;STARTING PHYSICAL PAGE NUMBER
ADDI TAC1,(AC1) ;TAC1←ENDING PAGE NUMBER+1
LSH TAC1,9 ;COMPUTE ENDING ADDRESS+1
CAMLE TAC1,TMEMSIZE ;WITHIN BOUNDS OF PHYSICAL MEM?
POPJ P, ;NO. LOSE.
>;FTEXPG (TMEMSIZ IS NOT DEFINED IN EARLIER SYSTEMS)
PUSH P,TAC ;SAVE USER'S ARGUMENT
PUSHJ P,KILSEG ;KILL ANY SEGMENT THAT MAY HAVE BEEN THERE.
POP P,TAC
AOS (P)
TRZ TAC,7 ;CLEAR SOME BITS
TRO TAC,4 ;SET GETHI BIT FOR JBTPR2
JRST STPR2 ;STORE JBTPR2. UPMAPL DOES ALL THE WORK!
>;FTXCOR
; HERE WE ADDRESS CHECK HIS PR REQUEST
PR2REL: HLRZ TAC1,JBTPAG(J) ;NUMBER OF PAGES IN LOWER
LSH TAC1,=9 ;LOWER'S WORD COUNT
HRRZ AC1,TAC ;RELOC REQUESTED(RELATIVE TO CORE IMAGE).
ANDCMI AC1,1777
CAIL AC1,(TAC1) ;TOO HIGH?
POPJ P, ;LOSE
HLRZ AC1,TAC ;PROT.
IORI AC1,1777
HRRZ AC2,TAC
ANDCMI AC2,1777
ADDI AC1,(AC2) ;+RELOC
CAIL AC1,(TAC1) ;TOO BIG?
POPJ P, ;YES, LOSE
PR2SET: PUSH P,TAC
PUSHJ P,KILSEG
POP P,TAC
AOS (P)
TRZ TAC,1776 ;MAKE IT PRETTY
TLO TAC,1776
↑STPR2: MOVEM TAC,JBTPR2(J)
IFN FTPAGER,<
STPR2A: PUSHJ P,UPMAPL ;LOOP THROUGH ALL UPPER SEGMENT PAGES
PUSHJ P,STPR2B >;FTPAGER
JRST SEGXIT ;SET UP PR AND JOBRL2
IFN FTPAGER,<
↑↑STPR2B:
TRNN AC1,4 ;SKIP IF GETHI HACK
ANDCMI AC2,1000 ;DON'T ALLOW PAGE NUMBERS BIGGER THAN 777
MOVEM AC2,(TAC1) ; INSTRUCTION FOR UPMAPL TO EXECUTE
POPJ P,
>;FTPAGER
;GETPR2
;CALLING SEQUENCE:
; GETPR2 AC,
; <ALWAYS RETURNS HERE>
;
; AC NOW CONTAINS PROT,,RELOC
; LOW ORDER BIT OF PROT IS ON IF ACCESS IS WRITE PROTECTED.
; LOW ORDER BIT OF RELOC IS ON IF RELATIVE MODE.
; NEXT TO LOW ORDER BIT ON IF PSEUDO-UPPER
; NEXT TO NEXT TO LOW ORDER BIT ON IF GETHI
↑PR2GET:MOVE TAC,JBTPR2(J)
JRST STOTAC ;GIVE HIM CURRENT VALUE
;REMAP UUO, ALSO SEGXIT, SEGXT1 - COMMON SEGMENT UUO EXIT ROUTINE
;CALL: MOVE AC,[FLAG,,<HIGHEST ADDRESS IN LOW PART>]
; REMAP AC,
; <FAILURE>
;IF SIGN BIT IN AC IS ON, SETS SEGMENT AS WRITE-PROTECTED.
;RETURNS IN AC THE JOB NUMBER OF THE SEGMENT.
↑REMAP: PUSH P,TAC ;SAVE ARGUMENT
MOVEI TAC,(TAC) ;RIGHT HALF ONLY
HLRZ TAC1,JBTPAG(J)
LSH TAC1,=9
CAIL TAC,-1(TAC1) ;SKIP IF ADDRESS IS IN BOUNDS (AND UPPER NON-EMPTY)
JRST UADERR
PUSHJ P,LINKSEG ;ATTEMPT A LINKUP. SKIP IF SUCCESSFUL
REMAP0: PUSHJ P,MAKESEG ;LINKUP FAILED. MAKE A NEW UPPER
LDB TAC1,PSEGN
JUMPE TAC1,TPOPJ ;EXIT IF COULDN'T MAKE A NEW SEG.
MOVE TAC,JBTSTS(TAC1) ;IF WE LINKED, WAIT FOR SEG TO BE IN CORE
TLNE TAC,SWP!SHF
PUSHJ P,WSCHED ;WAIT FOR SEGMENT TO GET IN.
SKIPN JBTPAG(TAC1) ;DID WE MAKE A NEW SEGMENT?
JRST REMAP1 ;YES, WE GOT A NEW ONE.
TLNN TAC,JSEG
JRST RMPER1 ;ERROR IF JSEG ISN'T ON IN THE UPPER'S JBTSTS
LDB AC1,[POINT 1,TAC,JWPPOS] ;GET WRITE PROTECT BIT FOR SEG
ROT AC1,-1 ;SHIFT JWP BIT TO SIGN BIT.
XOR AC1,(P) ;COMPARE WITH USER'S ARGUMENT
JUMPL AC1,REMAP0 ;IF WHAT WE GOT ISN'T WHAT WE WANT, MAKE A NEW SEG
POP P,TAC ;GET NEW CORE ASSIGNMENT BACK (AC FROM USER)
HRRZ TAC,TAC ;NEW SIZE FOR LOWER
IORI TAC,1777
PUSHJ P,CORUUO ;SHRINK LOWER.
JRST RMPER2 ;IMPOSSIBLE ERROR.
LDB TAC1,PSEGN
REMAP2: LDB UCHN,PUUOAC ;RESTORE UCHN - CLOBBERED BY CORUUO
XCTR XW,[MOVEM TAC1,(UCHN)] ;STORE SEG # IN USER'S AC
IFN FTHPSG,< MOVEI TAC,0 ;ARGUMENT TO SPECIFY DIRECTION
PUSHJ P,LTHUUO ;MOVE SEGMENT TO HIGH CORE
JFCL ;IGNORE FAILURE
MOVE J,JOB(PID) >;FTHPSG
SEGXT1: AOS (P) ;GIVE SKIP RETURN.
SEGXIT: PUSHJ P,GETPR ;SETUP TAC FOR COMPUTING JOBHRL
IFE FTPAGER,< DATAO APR,TAC >;IFE FTPAGER
IFN FTPAGER,<
NOKL10,< CONO PAG,3 >;NOKL10
IFKL10,< CONO KLPAG,@KLPCON >;IFKL10
>;IFN FTPAGER
LSH TAC,-9 ;SET JOBHRL FROM PR WD SO SETPR2 WILL WIN TOO
TRNN TAC,776000 ;SKIP IF THERE IS AN UPPER
JRST SEGXT4 ;NO UPPER.
TRNN TAC,JWP⊗<=18-9>
TLZA TAC,-1 ;NOT WRITE PROTECTED. LH OF JOBHRL IS ZERO.
HRLI TAC,400000 ;WRITE PROTECTED UPPER. SET SIGN BIT IN JOBHRL
TROA TAC,401777 ;CONVERT UPPER PROTECT ADDRESS TO RELATIVE ADDRESS
SEGXT4: MOVEI TAC,0 ;HERE IF THERE'S NO UPPER. ZERO JOBHRL
XCTR XW,[MOVEM TAC,JOBRL2]
POPJ P,
RMPER2: PUSHACS
PUSHJ P,DISJOB
PUSHJ P,DISMES
ASCIZ / ERROR RETURN FROM CORUUO AT REMAP
/
POPACS
JSP DAT,UERROR
RMPER1: PUSHACS
PUSHJ P,DISJOB
PUSHJ P,DISMES
ASCIZ / REMAP FAILED TO GET AN UPPER.
/
POPACS
JSP DAT,UERROR
;REMAP1 - INTIALIZE THE CONTENTS OF THE NEW SEGMENT.
;WE'VE MADE A NEW SEGMENT. MOVE IMAGE OF UPPER TO 1K BOUNDARY.
;(P) HAS THE USER'S AC, TAC1 HAS THE JOB NUMBER OF THE UPPER
REMAP1: SETCM TAC,(P)
TRNN TAC,1777 ;SKIP UNLESS IMAGE OF UPPER IS ALREADY
JRST REMAP3 ; AT A 1K BOUNDARY. AVOID UPWARD BLT
HLRZ TAC,JBTPAG(J)
LSH TAC,=9
ADDI TAC,1777 ;GET AN EXTRA 1K TO BLT HIM UP INTO
PUSHJ P,CORUUO
JRST REMAP8 ;COULDN'T GET 1K EXTRA CORE. GIVE ERROR RETURN
HRRZ TAC,(P) ;GET LAST ADDRESS IN LOWER
PUSHJ P,BLTUP ;MOVE UP UPPER.
LDB TAC1,PSEGN ;GET BACK SEGMENT NUMBER
REMAP3: ;(NOTE: UCHN IS CLOBBERED BY CORUUO)
IFN FTPAGER,< PUSH P,J
MOVE J,TAC1 ;JOB NUMBER OF UPPER
PUSHJ P,MAKMAP ;GET A PAGE MAP (WE MAY ALREADY HAVE ONE)
POP P,J >;FTPAGER
POP P,TAC ;GET USER'S AC BACK
MOVSI DAT,JWP
SKIPG TAC ;SKIP IF REQUESTING NO WRITE PROTECT
IORM DAT,JBTSTS(TAC1) ;SET WRITE PROTECT IN SEGMENT'S STATUS
HRRZ TAC,TAC
IORI TAC,1777 ;TAC←LAST ADDRESS IN NEW LOWER
MOVE DAT,JBTPAG(J) ;SAVE CURRENT CORE ASSIGNMENT OF LOWER
XCTR XW,[HRRZM TAC,JOBREL]
MOVEI TAC,1(TAC)
LSH TAC,-=9
HRLM TAC,JBTPAG(J)
MOVEI AC3,(DAT)
ADDI AC3,(TAC) ;AC3←PAGE NUMBER OF FIRST PAGE IN UPPER.
HRRZM AC3,JBTPAG(TAC1) ;STORE IT
IFN FTSTAT,< LSH TAC,6 ;MAKE ROOM FOR JOB NUMBER
IORI TAC,CSZSTA(J) ;SEND CORE SIZE OF LOWER
PUSHJ P,STAPTT
MOVEI TAC,CPSSTA(TAC1)
PUSHJ P,STAPTT ;CORE ADDRESS OF UPPER FOLLOWS
MOVE TAC,(AC3)
PUSHJ P,STAPTT >;FTSTAT
HLRZ TAC,DAT ;TAC←PAGE COUNT OF UPPER+LOWER
HLRZ DAT,JBTPAG(J) ;DAT←PAGE COUNT OF LOWER
SUBI TAC,(DAT) ;TAC←PAGE COUNT OF UPPER
HRLM TAC,JBTPAG(TAC1) ;STORE UPPER'S PAGE COUNT.
IFN FTSTAT,< LSH TAC,6
IORI TAC,CSZSTA(TAC1);SEND CORE SIZE OF UPPER.
PUSHJ P,STAPTT >;FTSTAT
PUSH P,TAC1 ;REG. FIX CORTAB AT REMAP TIME. PUSH SEG #
HRRZ DSER,JBTPAG(TAC1) ;FIRST PAGE OF UPPER
HLRZ AC1,JBTPAG(TAC1) ;NUMBER OF PAGES OF UPPER.
IFN FTPAGER,< HLRZ TAC,JBTPAG(J) ;NUMBER OF PAGES IN LOWER
PUSHJ P,ZMAPL ;LOOP THROUGH LOWER'S PAGE MAP STARTING
SETZM (TAC1) ; WHERE UPPER WAS, ZEROING OUT ENTRIES
>;FTPAGER
MOVEI UCHN,0 ;SET TO RELEASE CORE.
PUSHJ P,CORSTG ;RELEASE FROM CORTAB (SO CAN GET THEM BACK)
MOVE UCHN,(P) ;GET THE JOB NUMBER OF UPPER.
HLRZ AC1,JBTPAG(UCHN) ;NUMBER OF PAGES IN THE UPPER, AGAIN
IFN FTPAGER,< LDB DDB,[POINT 1,JBTSTS(UCHN),JWPPOS] ;GET JWP BIT OF UPPER
PUSH P,J
MOVE J,UCHN
PUSHJ P,LMAPL ;LOOP THROUGH PAGES OF NEW UPPER
PUSHJ P,STRMAP ; SETTING PAGE MAP ENTRIES W OR W/O WR PROT
MOVE TAC,(P) ;SET TO JOB NUMBER OF LOWER
PUSHJ P,ASGMAP ;COPY PAGE MAP OF UPPER TO LOWER
POP P,J >;FTPAGER
PUSHJ P,CORSTG ;CLAIM BLOCKS IN CORTAB
POP P,TAC1
JRST REMAP2
REMAP8: POP P,TAC ;HERE IF WE COULDN'T BLT UP
JRST KILSEG ;RETURN SEGMENT'S JOB NUMBER TO SYSTEM
;BLTUP - FAST UPWARDS BLT
;TAKES SOURCE ADDRESS-1 IN TAC (RELATIVE)
;BLTS UP REST OF CORE IMAGE TO NEXT 1K BOUNDARY
;CLOBBERS TAC,TAC1,AC1,AC2,AC3
;THIS CODE IS MORE OR LESS COPIED FROM CORE ROUTINES IN 'E'
;ALTERNATE ENTRY POINT AT FASBLT (NO ONE USES THIS). TAC1=DEST-1, AC2=LAST DEST
;THIS ROUTINE IS MORE GENERAL THAN NECESSARY FOR ITS PRESENT USES
;NOTE THAT THE MAP MUST BE SETUP BEFORE ENTERING THIS!
↑BLTUP: MOVEI TAC1,(TAC) ;TAC1←SOURCE ADDRESS-1
IORI TAC1,1777 ;TAC1←FIRST DESTINATION ADDRESS-1
HLRZ AC2,JBTPAG(J) ;PAGE COUNT OF LOWER
LSH AC2,=9 ;WORD COUNT
SUBI AC2,1 ;AC2←LAST DESTINATION ADDRESS.
FASBLT: SUBI AC2,(TAC1) ;AC2←LENGTH OF TRANSFER
SUBI TAC1,(TAC) ;TAC1←DISTANCE OF TRANSFER
CAILE AC2,(TAC1) ;IF LENGTH LESS THAN DISTANCE, THERE'S NO OVERLAP
JUMPGE TAC1,BLTUP1 ;JUMP IF OVERLAP AND DISTANCE TO MOVE IS POSITIVE.
JUMPLE AC2,CPOPJ ;IF THE LENGTH TO MOVE IS NEGATIVE YOU'RE CONFUSED
MOVEI AC3,(TAC) ;FIRST SOURCE-1
ADD AC3,TAC1 ;+DISTANCE=FIRST DESTINATION. (ABSOLUTE)
HRLI AC3,1(TAC) ;AC3←FIRST SOURCE,,FIRST DESTINATION
ADDI AC2,(AC3) ;AC2←DESTINATION+LENGTH = ENDING ADDRESS+1
BLT AC3,-1(AC2)
POPJ P,
BLTUP1: CAILE TAC1,5 ;THIS IS BELIEVED TO BE THE ROUGH BREAK-EVEN POINT
JRST BLTUP2 ;BETWEEN THE TWO METHODS
JUMPE TAC1,CPOPJ ;IF DISTANCE TO MOVE IS ZERO, WE ARE DONE.
MOVSI AC1,(<POP TAC1,(TAC1)>)
HRRI AC1,(TAC1) ;AC1←POP TAC1,OFFSET(TAC1)
MOVSI TAC1,377777(AC2) ;SET COUNT TO GO POS WHEN DONE.
HRRI TAC1,(TAC) ;TAC1←COUNT,,FIRST SOURCE-1
ADDI TAC1,(AC2) ;TAC1←COUNT,,LAST SOURCE
MOVE AC2,[JUMPL TAC1,AC1]
PUSH P,TAC ;SAVE TAC.
MOVE TAC,AC1 ;MOVE THE POP INSTRUCTION TO TAC
MOVE AC1,[XCTR XWSTKR,TAC] ;EXECUTE RELOCATED FOR THE POP INSTR.
MOVE AC3,[JRST TPOPJ] ;THE RETURN INSTR.
JRST AC1 ;ROAR
;TAC/ POP TAC1,OFFSET(TAC1)
;TAC1/ 377777+WC,,LAST SOURCE ADDRESS
;AC1/ XCTR XWSTKR,TAC
;AC2/ JUMPL TAC1,AC1
;AC3/ JRST TPOPJ
;HERE WE ITERATE ON BLTS, POSSIBLY STARTING WITH A SMALLER ONE
BLTUP2: PUSH P,AC2
IDIVI AC2,(TAC1) ;REMAINDER (AC3) IS SIZE OF FIRST (SHORT) BLT
MOVE AC2,(P) ;AC2← # OF WORDS TO MOVE
ADDI AC2,1(TAC) ;AC2←LAST SOURCE ADDRESS+1
HRLI AC2,(AC2) ;LAST SOURCE+1,,LAST SOURCE+1
ADDI AC2,(TAC1) ;LAST SOURCE+1,,LAST DESTINATION+1
JUMPE AC3,BLTUP3 ;IF REMAINDER IS ZERO, DON'T NEED INITIAL SHORT BLT
MOVSI AC1,(<BLT AC3,(AC2)>)
HRRI AC1,-1(AC3) ;AC1 ← BLT AC3,LENGTH-1(AC2)
HRLI AC3,(AC3) ;AC3 ← LENGTH,,LENGTH (OF SHORT BLT)
SUBB AC2,AC3 ;BACKUP THE BLT POINTER (AC3) AND COPY IT IN AC2.
XCTR XBLTRW,AC1 ;EXECUTE THE BLT, RELOCATING BOTH FETCH AND STORE
BLTUP3: HRLI TAC1,(<BLT AC3,(AC2)>) ;TAC1←BLT AC3,DISTANCE(AC2)
MOVEM TAC1,(P)
SOS (P) ;(P) ← BLT AC3,DISTANCE-1(AC2)
HRLI TAC1,(TAC1) ;TAC1 ← DISTANCE,,DISTANCE
MOVEI AC1,1(TAC) ;AC1←FIRST SOURCE ADDRESS
ADDI AC1,(TAC1) ;AC1←FIRST DESTINATION ADDRESS
;AC2 ← LAST SOURCE+1,,LAST DESTINATION+1
;TAC1 ← DISTANCE,,DISTANCE OF EACH BLT
;AC1 ← FIRST DESTINATION ADDRESS
BLTUP4: SUB AC2,TAC1 ;BACKUP AC2 TO BE READY FOR NEXT BLT.
MOVE AC3,AC2 ;COPY FOR BLT ENDING ADDRESS COMPUATION
XCTR XBLTRW,(P) ;DO BLT, RELOCATING FETCH AND STORE
CAIGE AC1,(AC2) ;HAVE WE REACHED THE FIRST DEST. YET?
JRST BLTUP4 ;NO. DO SOME MORE.
SUB P,[1,,1] ;REMOVE BLT FROM STACK
POPJ P,
;SETUWP UUO TO SET OR CLEAR USER WRITE-PROTECT BIT
; CALLING . . .
; MOVE AC,<0 FOR CLEAR, ≠0 FOR SET>
; SETUWP AC,
; <NO CAN DO>
↑SETUWP:PUSH P,TAC ;ARGUMENT AC
PUSH P,J
LDB J,PSEGN
JUMPN J,SETUW1 ;JUMP IF A REAL SEGMENT EXISTS
POP P,J ;UNWIND STACK
POP P,TAC1 ;ARGUMENT AC
SKIPN TAC,JBTPR2(J)
JRST SEGXIT
TRNE TAC,4 ;SKIP IF NOT GETHI HACK
JRST SEGXIT
MOVEI AC1,0
SKIPE TAC1
MOVEI AC1,1 ;SET UP WRITE PROTECT BIT FOR SETPR2
DPB AC1,[POINT 1,TAC,17] ;SET UP ARGUMENT TO SETPR2
JRST SETPR2
SETUW1: PUSHJ P,ACCESS ;ACCESS NEEDS JOB PUSHED ON STACK!
JFCL ;NO ACCESS
JRST SETUW2 ;READ ACCESS ONLY
IFN FTPAGER,<
EXCH DDB,-1(P)
PUSHJ P,WPMAPL ;SET WRITE PROTECT ACCORDING TO DDB
PUSHJ P,AUPMAP ;CHANGE ALL LOWERS OF OUR UPPER
EXCH DDB,-1(P)
>;FTPAGER
POP P,TAC1 ;MASTER JOB NUMBER
EXCH TAC1,(P) ;GET BACK USER'S AC INTO TAC1, MASTER JOB INTO 0(P)
MOVSI TAC,JWP
JUMPE TAC1,.+2 ;JUMP IF HE WANTS TO BE ABLE TO WRITE
IORB TAC,JBTSTS(J) ;HE WANTS TO WR PROT, SET THE BIT
JUMPN TAC1,.+2 ;JUMP IF HE WANTS TO BE WRITE PROTECTED
ANDCAB TAC,JBTSTS(J) ;HE WANTS TO BE ABLE TO WRITE, CLEAR THE BIT
HLRZ TAC1,JBTPAG(J)
LSH TAC1,=9
SOJA TAC1,CORE2X ;CALL CORE2X WITH TAC=PROTECTION OF UPPER
SETUW2: POP P,J ;FORGET IMMEDIATELY IF READ-ONLY ACCESS
POP P,TAC
JUMPN TAC,CPOPJ1
POPJ P,
;UNPURE, UNPURS
;MAKE A WRITEABLE COPY OF PRESENT UPPER.
;IF THE UPPER IS NOT WRITE-PROTECTED, WE USE IT, OTHERWISE, A COPY IS MADE.
;SKIPS ON SUCCESS (ALREADY WRITEABLE, NO UPPER, RELATIVE SETPR2, OR COPY DONE).
;NO-SKIP MEANS THAT A COPY COULDN'T BE CREATED (JOB SLOTS) OR SETPR2 SEGMENT
;CAN'T BE WRITTEN IN.
↑UNPURE:LDB AC1,PSEGN ;AC1←JOB NUMBER OF PRESENT UPPER.
JUMPE AC1,UNPNON ;JUMP IF NO UPPER. CHECK FOR PR2.
IFN FTHPSG,< MOVEI TAC,1 ;ALWAYS FLUSH UNPURIFIED UPPERS FROM HICORE
PUSHJ P,LTHUUO
MOVE J,JOB(PID) >;FTHPSG
MOVE TAC,JBTSTS(AC1)
TLZN TAC,JWP
JRST CPOPJ1 ;SUCCESS RETURN IF UPPER IS WRITEABLE
MOVE TAC1,NJOBS(AC1)
SOJG TAC1,UNPNC1 ;JUMP UNLESS WE ARE THIS SEG'S ONLY USER
MOVEM TAC,JBTSTS(AC1) ;OURS ALONE - JUST UNPROTECT IT
IFN FTPAGER,< PUSHJ P,UNPMAP > ;UNPURIFY THE SEGMENT AND ITS LOWERS
PUSHJ P,UNPUR2
JRST SEGXT1
UNPUR2: MOVE TAC,JOBNAM(AC1) ;MUNG JOBNAM SO THE OLD ONE IS STILL UNIQUE
LSH TAC,-6 ;CLEVERLY PRESERVING THE INFO FOR HUMANS
MOVEM TAC,JOBNAM(AC1)
IFN FTSTAT,< PUSH P,J
MOVEI J,(AC1)
PUSHJ P,NAMSTT
POP P,J >;IFN FTSTAT
MOVEI TAC,400(J) ;400 BIT WILL FEND OFF ACCESS
DPB TAC,[POINT 9,JOBCRD(AC1),8] ;SET PROTECTION
POPJ P,
;An unpurification resource (bits 30-35 of RTIME) is associated with
;each segment. The resource is claimed by one lower that's trying to
;unpurify an upper. We wait until this resource is free, claim it for
;ourselves, and when the upper is swapped out, the resource will be
;freed, and, hopefully, we'll be given a new, writeable, segment.
UNPNC2: PUSHJ P,WSCHED ;WAIT UNTIL WE HAVE THE UNPURE RESOURCE
UNPNC1: LDB AC1,PSEGN ;AC1←SEGMENT NUMBER
printx here is the UNPURE disable crock
POPJ P,
LDB TAC,[POINT 6,RTIME(AC1),35] ;TAC←OWNER OF UNPURE RESOURCE
CAIE TAC,(J) ;OK IF WE'VE GOT IT.
JUMPN TAC,UNPNC2 ;WAIT IF ASSIGNED TO SOMEONE ELSE.
DPB J,[POINT 6,RTIME(AC1),35] ;CLAIM RESOURCE
UNPNC4: LDB TAC,[POINT 6,RTIME(AC1),35] ;AC1=(OLD) SEGMENT NUMBER
CAME TAC,JOB(PID) ;SKIP IF WE STILL HAVE RESOURCE
JRST UNPNC5 ;NO. GO SEE WHAT'S HAPPENED
MOVE J,AC1 ;J←SEGMENT NUMBER
MOVE TAC1,JBTSTS(J)
SKIPN XJOB(J)
TLNE TAC1,SWP!SHF
JRST UNPNC3 ;CAN'T GRONK SEGMENT NOW.
HLRZ TAC,JBTPAG(J) ;CALL XPAND WITH SAME AMOUNT OF CORE AS NOW
PUSHJ P,XPAND ;FORCE SEGMENT OUT.
UNPNC3: PUSHJ P,WSCHED ;WAIT BEFORE GRONKING SEGMENT
JRST UNPNC4
UNPNC5: MOVE J,JOB(PID)
PUSHJ P,SPWCNT ;CONTINUE SPACEWAR.
LDB TAC1,PSEGN ;TAC1←NEW SEGMENT NUMBER
MOVE TAC,JBTSTS(TAC1)
TLNN TAC,JWP ;IS SEGMENT WRITE PROTECTED?
AOS (P) ;NO. WE MUST HAVE WON
JRST SEGXIT ;EXIT, HAVING WON OR LOST.
;ENTER UNPURS FROM SWAPPER (FINOUT) TO FINISH THE ACTION REQUESTED ABOVE.
;J←JOB NUMBER OF SEGMENT. TAC1←JOB NUMBER OF LOWER WHO'S REQUESTING UNPURE.
↑↑UNPURS:
MOVEI TAC,0 ;FREE THE UNPURIFICATION RESOURCE.
DPB TAC,[POINT 6,RTIME(J),35]
MOVE AC1,J ;AC1←JOB NUMBER OF OLD UPPER.
MOVE TAC,NJOBS(AC1) ;MAYBE BY NOW WE'RE THE ONLY USER
CAIG TAC,1
JRST UNPRS1 ;WE'RE THE ONLY USER...
PUSHJ P,ESTSEG ;J←JOB SLOT FOR NEW SEGMENT.
POPJ P, ;LOSE. NONE AVAILABLE.
PUSH P,TAC1 ;SAVE JOB NUMBER OF MAIN JOB.
PUSH P,AC1 ;SAVE JOB NUMBER OF OLD UPPER.
PUSH P,J ;SAVE JOB NUMBER OF NEW UPPER.
MOVE J,-2(P)
MOVE AC1,0(P)
PUSHJ P,UNPUR2 ;ADJUST NAME AND PROTECTION NOW.
MOVE J,0(P)
IFN FTPAGER,< MOVEI TAC,0
EXCH TAC,JBTMAP(AC1) ;OLD UPPER NEEDS NO MAP
MOVEM TAC,JBTMAP(J) ;BUT NEW UPPER NEEDS ONE. >;FTPAGER
MOVEI DSER,0
EXCH DSER,JBTPAG(AC1) ;RELEASE OLD UPPER'S CORE.
MOVEM DSER,JBTPAG(J) ;AND ASSIGN IT TO NEW UPPER.
IFN FTSTAT,< MOVEI TAC,CPSSTA(AC1) ;SEND NEW POSITION OF OLD UPPER
PUSHJ P,STAPTT
MOVEI TAC,0
PUSHJ P,STAPTT ;NEW POSITION IS ZERO.
MOVEI TAC,CPSSTA(J) ;SEND NEW POSITION OF NEW UPPER
PUSHJ P,STAPTT
HRRZ TAC,JBTPAG(J)
PUSHJ P,STAPTT
HLRZ TAC,JBTPAG(J) ;SIZE OF NEW UPPER
LSH TAC,6
IORI TAC,CSZSTA(J)
PUSHJ P,STAPTT >;FTSTAT
HLRZ AC1,JBTPAG(J) ;FIX CORTAB - OUT WITH THE OLD.
HRRZ DSER,JBTPAG(J)
MOVEI UCHN,0
PUSHJ P,CORSTG ;OUT WITH THE OLD JOB
MOVEI UCHN,(J) ;JOB NUMBER OF THE (NEW) UPPER
HLRZ AC1,JBTPAG(J)
IFN FTPAGER,< PUSHJ P,LMAPL ;SETUP PAGE MAP ENTRIES OF NEW UPPER
MOVEM AC2,(TAC1) > ;(MARK PAGES WRITEABLE)
PUSHJ P,CORSTG ;IN WITH THE NEW
MOVE TAC,-2(P) ;TAC←JOB NUMBER OF MAIN JOB.
MOVE J,-1(P) ;J←JOB NUMBER OF OLD UPPER.
IFN FTPAGER,< SKIPE JBTPAG(TAC) ;SKIP IF LOWER IS SWAPPED OUT (NO MAP)
PUSHJ P,ZSGMAP > ;FLUSH THE SEGMENT FROM LOWER'S PAGE MAP
SOS NJOBS(J)
MOVE J,-2(P) ;JOB NUMBER OF LOWER
MOVEI TAC,0
DPB TAC,PSEGN ;ZERO OLD SEGMENT FIELD
IFN FTSTAT,< PUSHJ P,SEGSTT >
MOVE J,-1(P) ;J←JOB NUMBER OF OLD SEGMENT
MOVE TAC,0(P) ;TAC←JOB NUMBE OF NEW SEGMENT
PUSHJ P,MAKSE2 ;COPY PARAMETERS FROM OLD SEG TO NEW
MOVE J,-2(P) ;J←JOB NUMBER OF MAIN JOB
DPB TAC,PSEGN ;THIS IS NOW OUR SEGMENT
IFN FTPAGER,< EXCH TAC,J ;J←NEW SEGMENT NUMBER, TAC←LOWER
SKIPE JBTPAG(TAC) ;LOWER MAY BE SWAPPED OUT ALREADY
PUSHJ P,ASGMAP ;PUT PAGES OF UPPER IN MAP OF LOWER
EXCH TAC,J >;FTPAGER
IFN FTSTAT,< PUSHJ P,SEGSTT >
;EVENTUALLY, THE CODE AT UNPNC5 WILL FIND A WRITEABLE UPPER.
MOVE J,-1(P) ;RESTORE OLD SEGMENT NUMBER FOR FINOUT
SUB P,[3,,3]
JRST CPOPJ1 ;RETURN TO FINOUT/SWAPSCAN
;AC1=J=JOB NUMBER OF SEGMENT. TAC1←JOB NUMBER OF LOWER WHO'S REQUESTING UNPURE.
;HERE, AFTER ALL THAT WORK, WE'RE THE ONLY USER.
UNPRS1: MOVSI TAC,JWP
ANDCAM TAC,JBTSTS(J) ;MARK SEGMENT AS WRITEABLE
MOVE J,TAC1 ;J←JOB NUMBER OF LOWER
PUSHJ P,UNPUR2
MOVE J,AC1 ;RESTORE JOB NUMBER OF UPPER
POPJ P, ;RETURN, LET FINOUT DO THE WORK
UNPNON: MOVEI TAC,4 ;HERE IF HE DOESN'T HAVE A REAL UPPER.
TDNE TAC,JBTPR2(J)
POPJ P, ;GETHI HACK, HE LOSES!
MOVSI TAC,1
TSNN TAC,JBTPR2(J) ;IF HE HAS RELATIVE PR2
POPJ P,
ANDCAM TAC,JBTPR2(J) ;THEN UNPROTECT IT
IFE FTPAGER,< JRST SEGXT1 > ;NOW UPDATE PR & JOBHRL & SKIP RETURN
IFN FTPAGER,< AOS (P) ;SET SUCESS RETURN.
JRST STPR2A > ;MAKE WRITEABLE ENTRIES IN MAP OF LOWER
;CORE2
;CALL: MOVE AC,<HIGHEST REL. ADR. IN UPPER, INCLUDING 0>
; CORE2 AC,
; <ERROR RETURN>
;SETS CORE SIZE OF UPPER ACCORDING TO THE ARGUMENT SPECIFIED BY USER.
↑CORE2: TRNE TAC,377777 ;IS HE REQUESTING ANY CORE AT ALL?
JRST CORE2A ;YES.
PUSHJ P,KILSEG ;NO. KILL THE SEGMENT
JRST SEGXT1 ;SET UP JOBRL2. LEAVE, GIVING SKIP RETURN
CORE2A: IORI TAC,1777 ;ROUND UP TO NORMAL BOUNDARY
ANDI TAC,377777 ;ZERO SOME BITS.
PUSH P,J
LDB J,PSEGN
JUMPN J,CORE2B ;JUMP IF WE HAVE A SEGMENT ALREADY.
POP P,J ;WE HAVE TO MAKE A NEW SEGMENT.
PUSH P,TAC ;SAVE DESIRED SEGMENT SIZE
PUSHJ P,MAKESEG ;MAKE A NEW SEG.
POP P,TAC
LDB TAC1,PSEGN ;LOOK TO SEE WHAT NUMBER WE GOT.
JUMPE TAC1,SEGXIT ;LOSE IF NO JOB SLOT AVAILABLE FOR NEW SEG
PUSH P,J ;SAVE JOB NUMBER OF MAIN JOB.
LDB J,PSEGN ;J←JOB NUMBER OF OUR NEW SEGMENT.
PUSHJ P,CORUUO ;ASSIGN CORE FOR NEW SEGMENT.
JRST CORE2E ;LOSE. RELEASE JOB ASSIGNED TO NEW SEGMENT
JRST CORE2N ;CORE ASSIGNED OK.
CORE2E: POP P,J ;HERE IF THERE'S NO CORE FOR NEW SEGMENT.
PUSHJ P,KILSEG
JRST SEGXIT
CORE2B: PUSH P,TAC ;SAVE DESIRED UPPER SIZE
PUSH P,-1(P) ;PUT JOB NUMBER ON TOP OF STACK FOR ACCESS!
PUSHJ P,ACCESS
JFCL ;LOSE.
SETZM -1(P) ;LOSE. FLAG CORE SIZE AS ZERO.
;NOTE: IF ACCESS GIVES ERROR RETURN, THEN TAC AS POPPED BELOW WILL BE ZERO
;AND CORUUO WILL ALWAYS GIVE ERROR RETURN FOR A ZERO ARGUMENT IN TAC.
SUB P,[1,,1] ;REMOVE JOB NUMBER
POP P,TAC ;GET BACK DESIRED UPPER SIZE
PUSHJ P,CORUUO ;ASSIGN CORE FOR THIS SEGMENT.
JRST CORE2D ;FAILED. (STORES USER'S AC)
CORE2N: ;CORE ASSIGNED OK.
IFN FTPAGER,< PUSHJ P,AUPMAP > ;SET UP MAP FOR EACH LOWER OF THIS UPPER
HLRZ TAC1,JBTPAG(J)
LSH TAC1,=9
SUBI TAC1,1 ;TAC1←UPPER'S JOBREL
CORE2X: TLNE TAC,JWP ;(ENTER HERE FROM SETUWP)
TLO TAC1,400000 ;SET JOBRL2 FOR EACH LOWER OF THIS UPPER.
MOVE TAC,J
TRO TAC1,400000
AOS -1(P) ;SET FOR SUCCESS RETURN
MOVE AC1,TAC1 ;AC1←NEW JOBHRL
PUSHJ P,UAPPLY ;APPLY TO ALL LOWERS OF THIS UPPER.
PUSHJ P,SETRLC ;(ARGUMENT TO UAPPLY - SEE SETUWP COMMAND)
CORE2D: POP P,J ;RESTORE JOB NUMBER OF MAIN JOB
PUSHJ P,APRMAP ;RESET MAP TO RUN THE CURRENT JOB
JRST SEGXIT
;ATTSEG - ATTACH HIGH SEGMENT
; CALLING . . .
; MOVE AC,<JOB NUMBER OR JOB NAME>
; ATTSEG AC,
; <NO CAN DO, ERROR CODE IN AC>
;
; ERROR CODES:
; 0 - PROTECTION VIOLATION
; 1 - AMBIGUOUS ADDRESSEE
; 2 - NOT A HIGH SEGMENT
; 3 - DOES NOT EXIST
; 4 - ALREADY HAVE A HIGH SEGMENT
↑ATTSEG:LDB TAC1,PSEGN
SKIPN JBTPR2(J) ;CAN'T ATTACH WHILE DOING PEEK-POKE
JUMPE TAC1,ATTSE5
MOVEI TAC,4
JRST ATTSER
ATTSE5: TDNE TAC,[-100]
JRST ATTSGJ ;TREAT AS SIXBIT JOB NAME
ATTSE1: MOVE TAC1,JBTSTS(TAC) ;SEE IF SPECIFIED JOB IS A SEGMENT
TLNE TAC1,JSEG
JRST ATTSE6 ;IT IS
MOVEI TAC,2
ATTSER: XCTR XW,[MOVEM TAC,(UCHN)] ;STORE ERROR CODE
POPJ P,
ATTSE6: PUSH P,J ;SAVE OUT JOB NUMBER
MOVE J,TAC ;GET NUMBER OF SEGMENT
PUSHJ P,ACCESS ;SEE IF WE HAVE ACCESS
JRST ATTSE7 ;NO ACCESS
JFCL ;READ ACCESS ONLY
MOVE TAC1,J ;JOB NUMBER OF SEGMENT
POP P,J ;GET BACK OUR JOB NUMBER
DPB TAC1,PSEGN ;MAKE IT OUR SEGMENT
IFN FTSTAT,<
PUSH P,TAC
PUSHJ P,SEGSTT
POP P,TAC
>;FTSTAT
AOS NJOBS(TAC1) ;BUMP COUNT OF JOBS PNTING TO THIS SEGMENT
SKIPN AC1,JBTDTS(J) ;DOES HE HAVE A LIST OF DETACHED SEGMENTS?
JRST ATTSE2 ;NO.
ATTSE3: LDB DAT,PDSEGN ;YES, IS THERE A SEGMENT NUMBER THERE
JUMPE DAT,ATTSE2 ;NO SEGMENTS LEFT IN LIST
CAME DAT,TAC1 ;IS THIS THE ONE IN QUESTION?
AOJA AC1,ATTSE3 ;NO, TRY THE NEXT ONE
MOVEI TEM,1(AC1) ;YES, RUN DOWN TO END OF LIST
ATTSE4: SKIPE (TEM) ;IS THIS THE END OF LIST?
AOJA TEM,ATTSE4 ;NO, TRY AGAIN
MOVE DAT,-1(TEM) ;MOVE LAST WORD ONTO WHERE WE'RE DELETING
MOVEM DAT,(AC1)
SETZM -1(TEM) ;ZERO THE END OF THE LIST
SUBI TEM,1
CAME TEM,JBTDTS(J) ;DOES HE HAVE ANY DETACHED SEGMENTS LEFT?
JRST ATTSE2 ;YES, WE ARE DONE
MOVE AC1,JBTDTS(J) ;NO, WE CAN GIVE BACK FREE STORAGE
PUSHJ P,FSGIVE
SETZM JBTDTS(J)
ATTSE2: AOS (P)
IFN FTPAGER,<
PUSH P,J
MOVE TAC,J ;OUR JOB NUMBER
MOVE J,TAC1 ;JOB NUMBER OF THE UPPER
PUSHJ P,ASGMAP ;ADD UPPER TO OUR PAGE MAP
POP P,J
>;FTPAGER
PUSHJ P,WSCHED ;MAKE SURE SEGMENT IS IN CORE
JRST SEGXIT ;NOW GO SET PROT-RELOC
;SEARCH FOR A SEGMENT OF A GIVEN NAME
ATTSGJ: MOVE DAT,JOBNM1
ATTSG1: CAME TAC,JOBNAM(DAT)
JRST ATTSG4
MOVE TAC1,JBTSTS(DAT)
TLNN TAC1,JSEG
JRST ATTSG4 ;IGNORE JOB OF THIS NAME IF NOT A SEGMENT
MOVE TAC1,DAT ;SAVE JOB NUMBER AND CHECK IF UNIQUE
JRST ATTSG2
ATTSG4: SOJG DAT,ATTSG1
MOVEI TAC,3 ;NO SUCH JOB NAME ERROR RETURN
JRST ATTSER
ATTSG3: CAME TAC,JOBNAM(DAT)
JRST ATTSG2
MOVE TEM,JBTSTS(DAT)
TLNN TEM,JSEG
JRST ATTSG2 ;NOT A SEGMENT, DON'T WORRY ABOUT IT
MOVEI TAC,1 ;AMBIGUOUS SEGMENT NAME
HRL TAC,DAT ;RETURN NUMBER OF SECOND ONE FROM TOP
JRST ATTSER
ATTSG2: SOJG DAT,ATTSG3 ;KEEP SEARCHING
MOVE TAC,TAC1 ;NO OTHERS, GET NUMBER IN TAC
JRST ATTSE1 ;GO TRY IT
ATTSE7: POP P,J
MOVEI TAC,0 ;GIVE PROTECTION VIOLATION ERROR
JRST ATTSER
;DETSEG DETACH SEGMENT
; CALLING . . .
; DETSEG AC,
; IF AC=0, THEN THE SEGMENT IS DETACHED AND PLACED INTO A LIST
; OF THE SEGMENTS THIS GUY HAS DETACHED, SUCH THAT WHEN THE
; SYSTEM CALLS RESET, ALL HIS DETACHED SEGMENTS GO AWAY. IF AC LOW
; ORDER BIT IS ON, SEGMENT WILL BE SPECIALLY DETACHED- WILL STICK AROUND
; UNTIL THE MAKER KJOBS.
↑DETSEG:
IFE FTPAGER,<
SKIPE JBTPR2(J) ;DOING PEEK-POKE?
JRST [ SETZM JBTPR2(J) ;FLUSH PEEK-POKE
JRST SEGXIT]
>;NOT FTPAGER
IFN FTPAGER,<
PUSHJ P,ZERPR2 ;TRY TO FLUSH JBTPR2, SKIP IF NONE
JRST SEGXIT
>;FTPAGER
LDB TAC1,PSEGN
JUMPE TAC1,CPOPJ ;NO HIGH SEGMENT HERE, HOW STRANGE!
SKIPE AC1,JBTDTS(J) ;PUT THIS ON THE LIST OF DETACHED SEGMENTS.
JRST DETSE1 ;HE HAS A DETACHED SEGMENT LIST ALREADY.
MOVEI AC3,JOBN ;NO, GET HIM ONE ABOUT THIS LONG.
PUSHJ P,UFSGET
HRRZM AC1,JBTDTS(J)
JRST DETSE2
DETSE1: SKIPE (AC1) ;NOW RUN DOWN TO END OF LIST
AOJA AC1,DETSE1
DETSE2: TRNE UCHN,1 ;DOES HE HAVE THE 1-BIT ON IN THE AC FIELD?
TLO TAC1,400000 ;YES, SET SPECIAL DET SEG.
MOVEM TAC1,(AC1) ;PUT THIS SEGMENT NUMBER IN THE TABLE
SOSGE NJOBS(TAC1)
PUSHJ P,NJERR
SETZB TAC,1(AC1) ;AND MARK THE END OF LIST
DPB TAC,PSEGN
IFN FTPAGER,<
PUSH P,J
MOVE TAC,J ;LOWER'S JOB NUMBER
MOVE J,TAC1 ;UPPER'S JOB NUMBER
PUSHJ P,ZSGMAP ;FLUSH THE PAGE MAP ENTRIES FOR THE UPPER
POP P,J
>;FTPAGER
IFN FTSTAT,<
PUSHJ P,SEGSTT
LDB TAC,PSEGN
>;FTSTAT
JRST SEGXIT
NJERR: PUSHACS
PUSHJ P,DISMES
ASCIZ /NJOB WENT NEGATIVE AT DETSEG
/
POPACS
SETZM NJOBS(TAC1)
POPJ P,
;SEGNUM, SEGSIZ, SEGNAM
;CALL: MOVE AC,[<JOB NUMBER>]
; CALL AC,['SEGSIZ']
;RETURNS IN AC THE JOB NUMBER OF THE SEGMENT BELONGING TO THE JOB SPECIFIED BY
;CONTENTS OF AC AT THE TIME OF THE CALL. ZERO IS RETURNED IF THERE IS NO SEGMENT
;IF THE ARGUMENT AC IS ZERO, THIS RETURNS YOUR SEGMENT NUMBER.
↑SEGNUM:CAIL TAC,0
CAIL TAC,JOBN
JRST UUOERR
CAIN TAC,0
MOVEI TAC,(J)
MOVEI J,(TAC)
LDB TAC,PSEGN
JRST STOTAC
;CALL: CALL AC,['SEGSIZ']
;RETURNS IN AC THE HIGHEST LEGAL ADDRESS IN UPPER SEGMENT - 400000.
;RETURNS ZERO IF YOU DO NOT HAVE AN UPPER SEGMENT
↑SEGSIZ:LDB TAC,PSEGN
JUMPE TAC,STOTAC
HLRZ TAC,JBTPAG(TAC)
LSH TAC,=9
JUMPE TAC,STOTAC
SOJA TAC,STOTAC
;CALL: CALL AC,['SEGNAM']
;THE NAME OF YOUR SEGMENT, OR 0, IS RETURNED IN AC.
↑SEGNAM:LDB TAC,PSEGN
MOVE TAC,JOBNAM(TAC)
JRST STOTAC
; SETNM2 CALLING . . .
; MOVE AC,[SIXBIT /<NAME YOU WISH YOUR UPPER TO HAVE>/]
; CALL AC,[SIXBIT /SETNM2/]
; <ERROR RETURN>
; IF YOU HAVE AN UPPER SEGMENT, GIVES IT THE NAME IN ACCUMULATOR AC.
; IF YOU DON'T HAVE AN UPPER, THIS UUO IS A NO-OP.
; UPON SUCCESS, AC IS CLEARED, UNLESS THERE IS ANOTHER SEGMENT OF THE SAME NAME,
; IN WHICH CASE YOU GET ITS JOB NUMBER
↑SETNM2:
LDB TAC1,PSEGN
JUMPE TAC1,CPOPJ1
PUSH P,TAC
PUSH P,J
MOVE J,TAC1
PUSHJ P,ACCESS
JFCL
JRST JTPOPJ
POP P,TAC1
POP P,JOBNAM(J)
IFN FTSTAT,<PUSHJ P,NAMSTT>
MOVEI TAC1,JOBN-1
SETNM3: MOVE DAT,JBTSTS(TAC1)
TLNN DAT,JSEG
JRST SETNM4
MOVE DAT,JOBNAM(TAC1)
CAME TAC1,J
CAME DAT,JOBNAM(J)
SETNM4: SOJG TAC1,SETNM3
XCTR XW,[MOVEM TAC1,(UCHN)]
JRST CPOPJ1
↑JTPOPJ:POP P,J
JRST TPOPJ
;LINKUP
; THIS UUO FIRST KILLS ANY HIGH SEGMENT YOU MAY HAVE.
; CALLING . . .
; CALL [SIXBIT /LINKUP/]
; <NO CAN DO>
; IT THEN ATTEMPTS TO MAKE A LINKUP WITH ANY HIGH SEGMENT
; IN CORE WITH YOUR CREDENTIALS.
↑LINKUP:
PUSHJ P,LINKSEG
POPJ P,
JRST ATTSE2 ; BRING UPPER INTO CORE, AND SKIP RETURN
; RETURNS LIST OF JOB NUMBERS WHO POINT TO YOUR UPPER SEGMENT.
; THE LIST TERMINATES WITH A ZERO
; IF YOU HAVE NO UPPER SEGMENT, ZERO IS RETURNED IN ADR
; ADR BETTER BE AT LEAST JOBN WORDS LONG.
; CALLING . . .
; POINTS ADR
↑POINTS:
LDB DAT,PSEGN
JUMPE DAT,POINT3
MOVEI J,JOBN-1
POINT2: LDB TAC1,PSEGN
CAME TAC1,DAT
JRST POINT1
XCTR XW,[MOVEM J,(UUO)]
ADDI UUO,1
POINT1: SOJG J,POINT2
POINT3: XCTR XW,[SETZM (UUO)]
POPJ P,
; SET PROTECTION ON A HIGH SEGMENT
; CALLING . . .
; MOVE AC,<0-8 NEW PROTECTION KEY; 30-35 SEGMENT NUMBER>
; CALL AC,[SIXBIT /SETPRO/]
; <NO CAN DO>
;
; IF SEGMENT NUMBER IS ZERO, REFERS TO YOUR OWN SEGMENT
↑SETPRO:
PUSH P,TAC
PUSH P,J
LDB J,[POINT 6,TAC,35]
JUMPN J,SETP3
MOVE J,(P)
LDB J,PSEGN
JUMPE J,JTPOPJ
SETP3: MOVE TAC1,JBTSTS(J)
TLNN TAC1,JSEG
JRST JTPOPJ
PUSHJ P,ACCESS
JFCL
JRST JTPOPJ
MOVE TAC1,(P)
MOVE TAC1,JBTPRV(TAC1)
TLNE TAC1,SEGPRV ;SKIP UNLESS HE HAS SEGMENT PRIV
JRST SETP2 ;SEG PRIV. HE WINS
TRNE TAC,400 ;PROTECTION PROTECTED?
JRST JTPOPJ
SETP2: MOVE TAC,-1(P)
LSH TAC,-=27
ANDI TAC,377 ;ONLY REAL BITS
DPB TAC,[POINT 9,JOBCRD(J),8]
AOS -2(P)
JRST JTPOPJ
BEND SEGUUO
SUBTTL INTUUO ;RUNMSK, INTORM, INTACM, INTENS, INTIIP, INTIRQ
;UUOS FOR NEW STYLE INTERRUPT SYSTEM
;SET THE PROCESSOR RUNNING MASK - NO-OP
;CALL: MOVE AC,[<RUN BITS>]
; CALL AC,[SIXBIT /RUNMSK/]
;THE RUN BITS ARE:
; BIT 35 - RUNNABLE ON P1
; BIT 34 - RUNNABLE ON P2
RUNMSK:
REPEAT 0,< DPB TAC,PRUNB >;REPEAT 0
POPJ P,
;INTORM - SET BITS IN INTERUPT ENABLE MASK
INTORM: PUSHJ P,INTCHK
MOVE AC1,TAC ;INTERRUPT BITS BEING TURNED ON
IORB TAC,JBTIEN(J) ;TAC MUST HAVE JBTIEN AT INTAPC
TLNE AC1,INTCLK
PUSHJ P,CLKENB ;PLANT CLOCK REQ FOR 1 TICK
JRST INTAPC
;INTACM - CLEARS BITS IN INTERRUPT ENABLE MASK
INTACM: PUSHJ P,INTCHK
MOVE AC1,TAC ;INTERRUPT BITS BEING TURNED OFF
ANDCAB TAC,JBTIEN(J)
TLNE AC1,INTCLK ;SKIP IF NOT CLEARING INTCLK
JRST INTEN1
INTAPC: ANDI TAC,CPUMSK
HRRZM TAC,APRIN2(PID) ;ONLY LEGAL BITS
XCTR XR,[IOR TAC,JOBENB]
ANDI TAC,CPUMSK!1000 ;MASK THIS TOO, SINCE IT'S UNPROTECTED
JRST APREN2 ;SET UP PROCESSOR CONO
;INTENS, INTIIP - RETURN INFORMATION
INTENS: SKIPA TAC,JBTIEN(J) ;RETURN STATE OF ENABLES
INTIIP: MOVE TAC,JBTIIP(J) ;RETURN STATE OF INTS IN PROGRESS
JRST STOTAC
;INTIRQ - RETURNS STATE OF PENDING INTERRUPTS
INTIRQ: MOVE TAC,JBTIRQ(J)
JRST STOTAC
;INTENB - ENABLE INTERRUPTS . . .
; MOVE AC,[MAGIC BITS]
; CALL AC,[SIXBIT /INTENB/]
INTENB: PUSHJ P,INTCHK ;CHECK FOR CONFLICTS BETWEEN OLD AND NEW.
MOVE AC1,JBTIEN(J) ;OLD ENABLINGS
MOVEM TAC,JBTIEN(J) ;NEW ENABLINGS
XOR AC1,TAC
TLNN AC1,INTCLK ;SKIP IF INTCLK CHANGING
JRST INTAPC ;INTAPC NEEDS TAC = JBTIEN
TLNN TAC,INTCLK ;SKIP IF TURNING INTCLK ON
JRST INTEN1 ;TURNING IT OFF
PUSHJ P,CLKENB ;PLANT CLOCK REQUEST IN APRLST FOR 1 TICK
JRST INTAPC
INTEN1: PUSHJ P,INTAPC
MOVSI TAC,INTCLK
ANDCAM TAC,JBTIRQ(J) ;FLUSH PENDING CLOCK INTERRUPT
JRST APRDKL ;KILL ANY CLOCK REQUESTS WE MIGHT HAVE
INTCHK: TLZ TAC,INTWAIT ;UUO WAIT IS THE ONLY PROTECTED INTERRUPT BIT
XCTR XR,[TDNN TAC,JOBENB]
POPJ P,
INTLOS: JSP TAC,UUOMES
ASCIZ /Interrupt enablings conflict, UUO/
; CLKENB, CLKENA - ENABLE FOR USER CLOCK INTERRUPTS
; CLKENA - SAME AS CLKENB EXCEPT TAC HAS NUMBER OF TICKS FOR REQ
CLKENB: PUSH P,TAC
TDZA TAC,TAC ;FLAG NOT TO STORE TIME
CLKENA: PUSH P,TAC
JUMPN PID,TPOPJ ;NO INTERRUPTS ON P2
CLKNB1: CONO PI,APROFF
SKIPN AC1,APRLST
JRST CLKNB2 ;HAVE TO CREATE APRLST BLOCK
CLKNBL: SKIPN AC2,(AC1) ;FIND THE FIRST BLANK SPOT
JRST CLKNB5 ;END OF LIST AND THIS JOB HAS NO REQ YET
CAIN J,(AC2) ;IS THERE AN ENTRY FOR THIS JOB?
JRST CLKNB4
ADDI AC1,2 ;LOOP AROUND
JRST CLKNBL
CLKNB2: CONO PI,APRON
MOVEI AC3,2*JOBN
PUSHJ P,UFSGET ;GET A BLOCK OF FREE STORAGE
SETZM (AC1)
CONO PI,APROFF
SKIPN APRLST ;SEE IF SOMEONE ELSE HAS MADE IT ALREADY
JRST CLKNB3 ;NO, WE STILL GET TO DO IT
CONO PI,APRON
PUSHJ P,FSGIVE ;FALSE ALARM
JRST CLKNB1
CLKNB3: MOVEM AC1,APRLST
JRST CLKNBL
CLKNB4: JUMPE TAC,CLKNB7 ;ALREADY AN ENTRY AND DON'T CHANGE TIME
CLKNB6: HRLM TAC,(AC1)
MOVNM TAC,1(AC1)
CLKNB7: CONO PI,APRON
JRST TPOPJ
CLKNB5: SETZM 2(AC1) ;MAKE A FRESH ENTRY
HRRZM J,(AC1)
JUMPN TAC,CLKNB6 ;STORE NEW TIME
AOJA TAC,CLKNB6
;DISMISS, DEBREAK
DISMIS: SKIPE INTACT(PID) ;DISMISS - TERMINATE CURRENT I-LEVEL RUN
JRST DISM2
SKIPE SPWUUF(PID)
JRST SPWXIT ;MUST LEAVE THROUGH HERE!
DISLOS: JSP TAC,UUOMES
ASCIZ /I-level UUO when not at I-level, UUO/
DEBREAK:SKIPN INTACT(PID) ;MAKE I-LEVEL PROCESS TAKE PLACE OF U-LEVEL PROCESS
JRST DISLOS
SKIPA AC1,[INTDEB] ;DISPATCH ADDRESS FOR INTDISP
DISM2: MOVEI AC1,INTDSM ;
DISM1: JUMPE UCHN,DISM3 ;NONZERO AC FIELD REQUEUES JOB AS SPEC BY C(AC)
MOVM TAC,JOBQUE(J)
XCTR XR,[MOVE TAC1,(UCHN)] ;LH(AC) IS MASK FOR LEGAL SOURCE Q'S
LSH TAC1,(TAC)
JUMPGE TAC1,DISM3 ;NOT IN LEGAL SOURCE Q
XCTR XR,[HRRZ TAC,(UCHN)] ;GET NEW CODE
CAIL TAC,NDISQS
JRST DISM3 ;OUT OF BOUNDS
MOVE TAC,DISQTB(TAC)
MOVEM TAC,JOBQUE(J)
PUSHJ P,REQUE
DISM3: CONO PI,PIOFF ;AVOID EXTRANEOUS CLK INTS
MOVEM AC1,INTDISP(PID)
HLLOS CLKFLG(PID) ;MAKE SURE CH7 KNOWS WE'RE COMING!
CONO PI,PION!1B24!1⊗(7-CLKCHN)
CONO PI,PION
HALT .+1
JUMPN PID,CL2INT
JRST CLKINT
DISQTB: TQ ;THESE ARE POSITIVE SO THEY WON'T GENERATE QXFER INTS
RUNQ
INTWQ
IOWQ
NDISQS←←.-DISQTB
;INTGEN, USKIP, UWAIT, IWAIT
INTGEN: SETCM AC1,JBTIEN(J) ;GENERATE AN INTERRUPT FOR YOURSELF
TDNN AC1,TAC
JRST INTGN1
JSP TAC,UUOMES
ASCIZ /Intgen of non-enabled interrupt, UUO/
INTGN1: IORM TAC,JBTIRQ(J)
SETOM INTREQ(PID)
SKIPN INTACT(PID)
JRST WSCHED
POPJ P,
USKIP: SKIPN INTACT(PID) ;TELL USER IF HE IS INSIDE A UUO
JRST DISLOS ;ILLEGAL WHEN NOT AT INT LEVEL
MOVE AC1,USRPC(PID) ;PC OF SUSPENDING MAIN JOB
TLNN AC1,USRMOD
AOS (P) ;IN EXEC MODE. MAKE UUO SKIP.
POPJ P,
;WAITS FOR UUO THAT WAS INTERRUPTED TO TERMINATE
UWAIT: PUSHJ P,USKIP ;SKIP IF INTERRUPTED OUT OF A UUO, RETURNING
JRST UWNPC ; IN AC1 THE PC OF THE SUSPENDED PROCESSES
MOVE DSER,JBTSTS(J) ; HE HAS BEEN REQUEUED IF HE IS IN INTERRUPT WAIT,
; NOW CHECK FOR SLEEPING.
TLNE DSER,CLKR ; DOES HE HAVE A SLEEP REQUEST IN?
PUSHJ P,UWAIT1 ; YES, GO WAKE HIM UP
MOVSI AC1,INTWAIT
IORM AC1,JBTIEN(J)
IORM AC1,JBTMSK(J)
MOVE AC1,UUOPC(J)
MOVEM AC1,JBTUPC(J) ;USER ADDRESS AFTER UWAIT
JRST DISMIS
UWAIT1: MOVE TAC,J ;SIMULATE UUO LEVEL CALL BY PUTTING JOB NUMBER IN TAC
JRST WAKE
UWNPC: XCTR XW,[MOVEM AC1,JOBTPC] ;STORE TRAP PC.
MOVE AC1,[JOBDAC,,JOBAC] ;MOVE DUMP ACS (20-37) TO REAL ACS (0-17)
XCTR XBLTRW,[BLT AC1,JOBAC+17] ;ACS WILL BE RESTORED UPON EXIT.
POPJ P,
IWAIT: MOVEI AC1,INTWQ ;WAIT UNTIL AWAKENED BY AN APPROPRIATE INTERRUPT
MOVNM AC1,JOBQUE(J)
JRST WSCHED
;IENBW, INTMSK, IMCALL, IMSKST, IMSKCL
;ENABLE INTERRUPTS AND THEN GO INTO INTERRUPT WAIT.
;CALL: MOVE AC,[<INTERRUPT BITS>]
; CALL AC,[SIXBIT /IENBW/]
;YOU ARE NOW IN INTERRUPT WAIT.
IENBW: MOVEI AC1,INTWQ ;PUT US IN INTERRUPT WAIT
MOVNM AC1,JOBQUE(J)
PUSHJ P,INTENB ;ENABLE INTERRUPTS
JRST WSCHED ;WAIT.
;UUO TO SET THE INTERRUPT MASK
;CALL: INTMSK [<MASK BITS>]
INTMSK: XCTR XR,[MOVE AC1,(UUO)]
MOVEM AC1,JBTMSK(J)
IMCALL: SKIPN INTACT(PID) ;DON'T CALL WSCHED IF ALREADY AT I-LEVEL
TDNN AC1,JBTIRQ(J) ;DOES HE HAVE ANY INTERRUPTS PENDING?
POPJ P,
SETOM INTREQ(PID) ;YES, GIVE THEM
JRST WSCHED
IMSKST: XCTR XR,[MOVE AC1,(UUO)] ;SET BITS IN THE MASK
IORM AC1,JBTMSK(J)
JRST IMCALL
IMSKCL: XCTR XR,[MOVE AC1,(UUO)] ;CLEARS BITS IN THE MASK
ANDCAM AC1,JBTMSK(J)
POPJ P,
; CLKINT UUO (CLKUUO) START UP A CLOCKED I-LEVEL JOB
; CALLING . . .
; CLKINT TIX
; TIX IS THE TIME IN TICKS BETWEEN STARTUPS
; IF TIX IS ZERO, ANY CLOCKED JOB IS FLUSHED
CLKUUO: TRNN UUO,-1 ;ZERO TIX?
JRST CLKUU2 ;YES, GO KILL JOB
MOVSI TAC,INTCLK
IORM TAC,JBTIEN(J) ;ENABLE CLOCK INTERRUPTS
ANDCAM TAC,JBTIRQ(J) ;FLUSH PENDING OLD CLOCK INTERRUPT
HRRZ TAC,UUO
JRST CLKENA ;PLANT THE CLOCK REQUEST
CLKUU2: PUSHJ P,APRDKL ;KILL CLOCK REQUEST
MOVSI TAC,INTCLK
ANDCAM TAC,JBTIEN(J)
ANDCAM TAC,JBTIRQ(J)
POPJ P,
;INTUUO - INTDEJ, IMSTW
; MULTI-PURPOSE INTERRUPT UUO
INTUUO: CAILE UCHN,INTMXU
JRST UUOERR
JRST @INTUTB(UCHN)
DEFINE UUOS{FOR X IN(INTDEJ,IMSTW,IWKMSK,INTDMP,INTIPI,IMSKCR)}
PSHSYS
LOSYS
UUOMAC INTUTB,INTUUO
INTMXU←←UUOCNT
POPSYS
; RESET INTERRUPT MASK AND JUMP TO ADDRESS UUO.
; CALLING . . .
; INTDEJ ADR
; WITH THE FOLLOWING DATA . . .
; ADR: <INTERRUPT BITS TO BE ORED INTO MASK>
; <PC WORD TO GO TO>
; THIS UUO DOES NOT RETURN, BUT INSTEAD JUMPS TO THE ADDRESS
INTDEJ: XCTR XR,[MOVE TAC,1(UUO)];FETCH PC WORD
TLO TAC,USRMOD ; KEEP THE LOSER OUT OF THE SYSTEM
PUSH P,TAC
PUSHJ P,IMSKST ; OR IN MASK BITS
POP P,UUOPC(J) ; SET UP RETURN ADDRESS
POPJ P, ; RETURN TO LOSER
; SET MASK FROM FIRST WORD OF UUO AND GO INTO WAIT STATE.
; CALLING . . .
; IMSTW ADR
;
; ADR: <MASK BITS>
IMSTW: MOVEI AC1,INTWQ ; PUT US INTO INTERRUPT WAIT FIRST
MOVNM AC1,JOBQUE(J)
PUSHJ P,INTMSK ; SET THE MASK
JRST WSCHED ; DO THE WAIT STATE THING.
; IWKMSK, IMSKCR
; SET MASK THAT ALLOWS THE MAIN JOB TO BE AWAKENED
; FROM IWAIT QUEUE.
; CALLING . . .
; IWKMSK ADR
;
; ADR: <INTERRUPT BITS WHICH SHOULD AWAKEN>
IWKMSK: XCTR XR,[MOVE TAC,(UUO)]
MOVEM TAC,JBTWKM(J)
POPJ P,
;CLEAR SPECIFIED BITS OF MASK (PDP-10 ONLY) AND RETURN OLD MASK
;CALL:
; IMSKCR ADR
;
;ADR: BITS TO TURN OFF IN MASK, REPLACED BY OLD MASK VALUE
IMSKCR: MOVE TAC,JBTMSK(J)
XCTR XR,[ANDCM TAC,(UUO)]
EXCH TAC,JBTMSK(J)
JRST STOTAC
;INTDMP
;UUO TO RETURN INFORMATION ABOUT A PARTICULAR JOB'S INTERRUPT CONDITION.
;CALL: INTDMP ADR
; <FAILURE - ERROR CODE IN ADR+1>
; <SUCCESS>
;
; BEFORE AFTER
;ADR: <JOB NUMBER OR JOB NAME> same
;ADR+1: <ENABLE BITS, OR ERROR CODE>
; <P1 INTERRUPT MASK>
; 0
; <WAKEUP MASK>
; <JOB QUEUE>
;ERROR CODES RETUNED IN ADR+1 ARE:
; 1 JOB NOT LOGGED IN
; 2 AMBIGUOUS JOB NAME
; 3 NON-EX JOB NAME
INTDMP: JSP AC3,GXJOBN ;TAC←JOB NUMBER FROM JOB NUMBER OR JOB NAME
MOVE AC1,JBTIEN(TAC) ;GIVE THE GUY HIS ENABLE BITS
XCTR XW,[MOVEM AC1,1(UUO)]
MOVE AC1,JBTMSK(TAC) ;AND HIS PROCESSOR MASKS
XCTR XW,[MOVEM AC1,2(UUO)]
XCTR XW,[SETZM 3(UUO)]
MOVE AC1,JBTWKM(TAC) ;HIS WAKEUP MASK
XCTR XW,[MOVEM AC1,4(UUO)]
MOVM AC1,JOBQUE(TAC) ;AND HIS CURRENT QUEUE
XCTR XW,[MOVEM AC1,5(UUO)]
JRST CPOPJ1 ;GIVE SUCCESS RETURN
;GXJOBN. INTDR1,INTDR2, ETC.
INTDR1: JSP AC1,INTDRX
INTDR2: JSP AC1,INTDRX
INTDR3: JSP AC1,INTDRX
INTDR4: JSP AC1,INTDRX
INTDR5: JSP AC1,INTDRX
INTDR6: JSP AC1,INTDRX
INTDRX: MOVEI AC1,-INTDR1(AC1) ;CONVERT STORED PC TO INDEX.
XCTR XW,[MOVEM AC1,1(UUO)]
POPJ P,
;JOB NUMBER OR NAME TO JOB NUMBER. CALL VIA JSP AC3,GXJOBN
;CALL WITH (UUO) POINTING TO ADDRESS WHERE WE CAN FIND A JOB NAME OR NUMBER.
;RETURNS JOB NUMBER IN TAC. ERRORS CALL INTDR1, INTDR2, OR INTDR3.
GXJOBN: XCTR XR,[MOVE TAC,(UUO)] ;PICK UP JOB NUMBER OR NAME.
CAIGE TAC,JOBN
JUMPGE TAC,GXJOB0 ;JUMP IF JOB NUMBER WAS GIVEN
MOVEI AC1,JOBN-1
GXJOB2: CAME TAC,JOBNAM(AC1)
GXJOB3: SOJG AC1,GXJOB2 ;LOOP LOOKING FOR MATCH.
JUMPLE AC1,INTDR3 ;JUMP IF NON-EX NAME
MOVE AC2,JBTSTS(AC1) ;FOUND A MATCH. MAKE SURE IT'S NOT A SEGMENT.
TLNE AC2,JNA ;SKIP IF LOSING
TLNE AC2,JSEG ;SKIP IF WINNING
JRST GXJOB3 ;KEEP LOOKING.
SKIPA AC2,AC1 ;SAVE THE JOB NUMBER WE LIKED.
GXJOB4: CAME TAC,JOBNAM(AC1)
GXJOB5: SOJG AC1,GXJOB4 ;MAKE SURE THERE'S NO AMBIGUITY.
JUMPLE AC1,GXJOB7 ;JUMP IF WINNING.
PUSH P,TAC
MOVE TAC,JBTSTS(AC1)
TLNE TAC,JNA
TLNE TAC,JSEG
JRST GXJOB6 ;IGNORE THIS MATCH. NOT LOGGED IN, OR SEGMENT
SUB P,[1,,1]
JRST INTDR2 ;AMBIGUOUS NAME.
GXJOB6: POP P,TAC
JRST GXJOB5
GXJOB7: MOVE TAC,AC2
JRST (AC3)
GXJOB0: SKIPG TAC ;SKIP IF NON-ZERO JOB NUMBER
MOVE TAC,J ;FOR ZERO JOB NUMBER, USE HIS OWN JOB.
MOVE AC2,JBTSTS(TAC)
TLNN AC2,JNA
JRST INTDR1 ;ERROR 1. BAD JOB NUMBER.
JRST (AC3) ;RETURN.
;INTIPI
;INTER-PROCESS INTERRUPT SYSTEM
;CALL: INTIPI ADR
; <ERROR RETURN. ERROR CODE RETURNED IN ADR+1>
; <SUCCESS RETURN>
;
;ADR: <JOB NUMBER OR NAME>
;ADR+1: <INTERRUPT BITS FOR THAT JOB>
;
;ERROR CODES RETUNED IN ADR+1 ARE:
; 1 JOB NOT LOGGED IN
; 2 AMBIGUOUS JOB NAME
; 3 NON-EX JOB NAME
; 4 JOB IS NOT ENABLED FOR THOSE INTERRUPTS
INTIPI: JSP AC3,GXJOBN ;TAC←JOB NUMBER, ELSE ERROR RETURN.
XCTR XR,[MOVE AC1,1(UUO)] ;INTERRUPT BITS
SETCM AC2,JBTIEN(TAC)
TDNE AC1,AC2
JRST INTDR4 ;ERROR - CLASS4
IORM AC1,JBTIRQ(TAC)
SETOM INTREQ(PID)
JRST CPOPJ1
SUBTTL UUOCON - STANFORD SPECIAL IO ROUTINES ;CHNSTS, BUFLEN
;UUO TO GET USE BITS FOR A CHANNEL
; CHNSTS <CHANNEL NUMBER>,ADR
;PUTS USRJDA IN ADR, 0 FOR UNUSED.
CHNSTS: CAMLE UCHN,USRHCU(PID)
TDZA TAC,TAC
HLRZ TAC,USRJDA(UCHN)
JRST STOTAC
;THIS UUO GETS THE STANDARD BUFFER LENGTH FOR A DEVICE
; MOVE AC,[DEVICE NAME IN SIXBIT]
; CALL AC,[SIXBIT /BUFLEN/]
; <RETURNS HERE WITH BUFFER LENGTH, OR 0, IN AC>
BUFLEN: PUSHJ P,FNDDDB ;LOOK FOR DEVICE WITH THIS NAME (OR CHANNEL #)
JRST RTZERO ;GIVE BACK A ZERO IF NOT FOUND
LDB TAC,PDVBLN ;RETURN BUFFER LENGTH
JRST STOTAC
; ROUTINE TO GET THE TIME CELLS AND CLEAR THEM
; CALLING . . .
; MOVE AC,<ADDRESS OF 2-WORD BUFFER>
; CALL AC,[SIXBIT /GDPTIM/]
; RETURNS KEYBOARD TIME IN <BUFFER> AND DISPLAY TIME IN <BUFFER>+1
; CLEARS BOTH CELLS IN THE MONITOR
; RETURNS ZEROS IF YOU ARE NOT A DPY
GDPTIM:
REPEAT 0 < ;GDPTIM UUO REMOVED 23-MAR-73
MOVE TAC1,JBTLIN(J) ;GET OUR LINE NUMBER
XCTR XR,[MOVE TAC,(UCHN)] ;FIND WHERE TO STUFF DATA
SETZB AC1,AC2 ;ZERO A PAIR OF AC'S
TLNE TAC1,DISLIN!DDDLIN ;SKIP IF NOT III OR DATA DISK
SKIPN DDB,LETAB-DPYL0(TAC1)
JRST NOTDPY ;NOT A DPY
EXCH AC1,DPKTIM(DDB)
EXCH AC2,DPGTIM(DDB)
NOTDPY: XCTR XW,[MOVEM AC1,(TAC)]
XCTR XW,[MOVEM AC2,1(TAC)]
>;END DELETION OF GDPTIM
POPJ P,
;;RETURNS A CODE TELING WHETHER A JOB NAME IS LOGGED IN
; MOVE AC,[<JOB NAME IN SIXBIT>]
; CALL AC,[SIXBIT /NAMEIN/]
; <NO SUCH JOB - ERROR CODE IN AC>
;
; ERROR CODE IS 3 FOR MULTIPLY DEFINED JOB NAME, 1 FOR NO SUCH NAME
NAMEIN:
MOVEI TAC1,JOBN-1
NAMEI1: CAME TAC,JOBNAM(TAC1) ; IS THIS IT?
NAMEI2: SOJG TAC1,NAMEI1
JUMPN TAC1,NAMEI4
MOVEI TAC,1
JRST STOTAC ; NO SUCH NAME, GIVE ERROR 1 RETURN
NAMEI4: MOVE AC1,JBTSTS(TAC1)
TLNN AC1,JNA ; NOW, IS IT A JOB?
JRST NAMEI2
MOVE AC2,TAC1 ;GIVE BACK JOB NUMBER
NAMEI3: SOJLE TAC1,NAMEI5 ; SEARCH REMAINDER OF NAMES FOR MATCH
CAME TAC,JOBNAM(TAC1)
JRST NAMEI3
MOVE AC1,JBTSTS(TAC1)
TLNN AC1,JNA
JRST NAMEI3
MOVEI TAC,3
JRST STOTAC
NAMEI5: MOVE TAC,AC2
AOS (P) ; SKIP RETURN
JRST STOTAC ; AND GIVE HIM THE JOB NUMBER
; DEVUSE - HOW MANY JOBS ARE WAITING FOR A PARTICULAR DEVICE.
; CALLING . . .
; MOVE AC,<DEVICE NAME>
; CALL AC,[SIXBIT /DEVUSE/]
; RETURNS NUMBER OF JOBS WAITING FOR THIS DEVICE IN AC (NOT INCLUDING YOUR JOB)
DEVUSE: PUSHJ P,FNDDDB ; PICK UP DEVICE DATA BLOCK ADDRESS
JRST RTZERO ; NO SUCH DEVICE, NOBODY WAITING FOR IT!
MOVEI AC1,JOBN-1 ; PREPARE TO SCAN JOB TABLES
SETZ TAC,
DEVUS1: CAME DDB,JBTDVW(AC1) ; IS THIS THE DEVICE?
DEVUS2: SOJG AC1,DEVUS1 ; NO, LOOP AROUND
JUMPE AC1,DEVUS3 ; RETURN ARGUMENT AND LEAVE
CAIN AC1,(J)
JRST DEVUS2 ; DON'T COUNT YOURSELF.
MOVE AC2,JBTSTS(AC1) ; SEE IF THE JOB EXISTS
MOVM AC3,JOBQUE(AC1) ; AND IF IT IS IN DEVICE WAIT
TLNE AC2,JNA
CAIE AC3,DWQ
JRST DEVUS2
AOJA TAC,DEVUS2 ; BUMP COUNT AND LOOP BACK
DEVUS3: MOVE TAC1,DEVMOD(DDB)
TLNE TAC1,DVUDP
JRST DEVUS4 ;COMPLICATED FOR UDP
LDB AC1,PJOBN ;GET JOB NUMBER OF DEVICE OWNER
TLNE TAC1,TTYATC
TRO AC1,100000
TRNE TAC1,ASSCON
TRO AC1,400000
TRNE TAC1,ASSPRG
TRO AC1,200000
HRL TAC,AC1
JRST STOTAC
DEVUS4: LDB AC1,PUNIT ;UDP, SCAN ALL DDBS FOR ASSCON, ASSPRG
MOVE AC2,DKDBML(AC1) ;MODEL DDB FOR THIS UDP
SKIPA AC3,DEVNAM(DDB) ;BH 5/22/75 CHECK MODEL DDB IN CASE SWAPPING
DEVUS5: HLR AC2,DEVSER(AC2)
CAME AC3,DEVNAM(AC2)
JRST DEVUS7 ;NO MORE DDBS
MOVE TAC1,DEVMOD(AC2)
TRNE TAC1,ASSCON
TLO AC2,400000
TRNE TAC1,ASSPRG
TLO AC2,200000
LDB AC1,[POINT 6,DEVCHR(AC2),5]
CAIE AC1,(J) ;EXTRA BITS FOR UDP ONLY,
JRST DEVUS6 ;NAMELY ASSCON AND ASSPRG FOR YOUR OWN JOB
TRNE TAC1,ASSCON
TLO AC2,40000
TRNE TAC1,ASSPRG
TLO AC2,20000
JRST DEVUS5
DEVUS6: TRNE TAC1,ASSCON ;AND SEPARATELY FOR OTHER JOBS
TLO AC2,10000
TRNE TAC1,ASSPRG
TLO AC2,4000
JRST DEVUS5
DEVUS7: LDB TAC1,PUNIT ;GET UDP NUMBER
HLRZ AC1,AC2 ;FLAGS INTO AC1
TRO AC1,2000 ;THIS IS PRIVATE OWNERSHIP FLAG
SKIPGE UDPOWN-1(TAC1) ;SKIP IF PRIVATE
TRZA AC1,2000 ;PUBLIC, TURN OFF PRIVATE FLAG
ADD AC1,UDPOWN-1(TAC1) ;JOB NUMBER OF OWNER OR 0 FOR PUBLIC
HRL TAC,AC1
JRST STOTAC
;JOBRD
;COPY DATA FROM SOME OTHER JOB'S CORE IMAGE TO YOURS.
;CALL: MOVEI AC,ADR
; CALL AC,['JOBRD ']
; <ERROR - CODE IN ADR+1>
;
;ADR: <JOB NAME OR NUMBER>
; <XWD -NWDS,HISADR>
; <ADDRESS IN YOUR CORE IMAGE WHERE YOU WANT THE DATA>
;
;ON ERROR RETURN, ADR+1 CONTAINS AN ERROR CODE:
; 1 JOB NOT LOGGED IN
; 2 AMBIGUOUS JOB NAME
; 3 NON-EX JOB NAME
; 4 ADDRESS OUT OF BOUNDS
; 5 JOB DISAPPEARED
; 6 BLOCK TOO LARGE
JOBRD: HRR UUO,TAC ;PUT DATA BLOCK ADDRESS IN UUO
SKIPE AC1,JBTFS(J) ;RETURN ANY FREE STORAGE HE MIGHT HAVE.
PUSHJ P,FSGIVE
SETZM JBTFS(J)
XCTR XR,[HLRO TAC,1(UUO)] ;PICK UP LENGTH OF TRANSFER
CAMGE 1,[-2000] ;MORE THAN ONE K?
JRST INTDR6 ;YES. ERROR 6. BLOCK TOO LARGE
JSP AC3,GXJOBN ;TAC←JOB NUMBER.
XCTR XR,[HLRO AC3,1(UUO)] ; PICK UP WORD COUNT
MOVN AC3,AC3
ADDI AC3,1 ;WE NEED ONE OVERHEAD WORD.
PUSHJ P,UFSGET
HRL AC1,TAC ;STORE JOB TO READ FROM IN LH. OF JBTFS.
MOVEM AC1,JBTFS(J) ;SOURCE JOB,,FREE STORAGE ADDRESS
XCTR XR,[MOVE AC2,1(UUO)]
MOVEM AC2,(AC1) ;STORE SOURCE IOWD IN FS BLOCK.
MOVE DAT,J ;ARG IS JOB NUMBER
HRLI DAT,JOBRCK ;ROUTINE TO CALL
PUSHJ P,DPYTIM ;ENTER CLOCK REQUEST.
JOBRDX: MOVNI AC3,IOWQ ;WAIT FOR IT TO HAPPEN.
MOVEM AC3,JOBQUE(J)
PUSHJ P,WSCHED ;DELAY.
SKIPN AC1,JBTFS(J) ;IS FS. BLOCK STILL THERE?
JRST INTDR4 ;NO. GIVE ILL ADDR ERROR (CROCK)
SKIPGE (AC1) ;DONE YET?
JRST JOBRDX ;NO, WAIT AGAIN
SKIPE TAC,(AC1) ;WAS THERE AN ERROR?
JRST JOBRDY ;RETURN ERROR CODE TO USER.
MOVEI TAC1,1(AC1) ;SOURCE ADDRESS OF BLT
XCTR XR,[HLRO AC3,1(UUO)] ;WC OF BLT
MOVN AC3,AC3
SUBI AC3,1
XCTR XR,[HRRZ AC2,2(UUO)] ;PICK UP ADDRESS IN HIS CORE
ADD AC3,AC2 ;ENDING ADDR. OF TRANSFER
HLRZ AC1,JBTPAG(J)
LSH AC1,=9 ;NUMBER OF WORDS IN OUR CORE IMAGE
MOVEI TAC,4 ;ASSUME ERROR CODE 4.
CAIGE AC2,(AC1)
CAIL AC3,(AC1)
JRST JOBRDY ;ADDRESS CHECK. TAC=4. RETURN ERROR CODE.
HRLI AC2,(TAC1) ;SOURCE ADDRESS TO LH OF BLT AC
XCTR XBLTW,[BLT AC2,(AC3)] ;DO THE TRANSFER. FREE STG. TO USER.
AOSA (P) ;WIN! SET SKIP RETURN. SKIP STORE OF ERROR
JOBRDY: XCTR XW,[MOVEM TAC,1(UUO)] ;STORE ERROR CODE
MOVE AC1,JBTFS(J)
SETZM JBTFS(J)
JRST FSGIVE ;RETURN BLOCK
;FREE STORAGE BLOCK LOCATIONS
; BEFORE AFTER
;0 -WC,,MA TO READ 0=SUCCESS, POSITIVE=ERROR
;1 RANDOM DATA TO END OF BLOCK
;2 .
;HERE AT CLOCK LEVEL (FROM DPYSER CLOCK QUEUE)
JOBRCK: HRRZ J,DAT ;J←JOB NUMBER OF READER.
SKIPN TEM,JBTFS(J) ;DID FREE STORAGE BLOCK GO AWAY?
POPJ P, ;YES, DISAPPEAR. (↑C KJOB HAPPENED)
HLRZ TAC,TEM ;GET JOB # WE ARE READING
MOVE AC1,JBTSTS(TAC)
TLNN AC1,JNA ;IS JOB STILL THERE?
JRST JOBRC3 ;NO, ERROR
TLNE AC1,SHF ;IF SHUFFLING
JRST DPYTIM ;JUST REPLANT CLOCK REQUEST
TLNN AC1,SWP ;SWAPPED OUT?
JRST JRDBLT ;NO. READ DATA NOW.
JOBRCQ: MOVE J,TAC ;TRANSFER CONTROL TO SWAP IN LIST
MOVSI TAC,JRDSNB
JRST SETSIN
;HERE, TAC=JOB TO READ FROM. J=JOB TO WRITE IN.
JRDBLT: SKIPN TEM,JBTFS(J) ;MAKE SURE FS BLOCK EXISTS
POPJ P,
HRRZ AC2,(TEM) ;PICK UP STARTING ADDRESS
HLRO AC3,(TEM) ;AND WORD COUNT
MOVNS AC3
HLRZ AC1,JBTPAG(TAC)
LSH AC1,=9
ADDI AC3,(AC2)
SUBI AC3,1 ;AC3←ENDING ADDR IN SOURCE CORE IMAGE
CAIL AC3,(AC1)
JRST JOBRC1 ;ADDRESS ERROR.
PUSH P,J
MOVE J,TAC ;J←JOB NUMBER OF SOURCE JOB
PUSHJ P,JRDBL1 ;NEED PUSHJ HERE FOR MAPSET
POP P,J
JRST JOBRC2
JRDBL1: PUSHJ P,MAPSET
SUBI AC3,-1(AC2) ;BACK UP TO JUST WORD COUNT - 1
HRLI AC2,1(TEM) ;PREPARE TO MOVE DATA
MOVS AC2,AC2
ADD AC3,TEM ;AC3←ENDING ADDRESS.
XCTR XBLTR,[BLT AC2,(AC3)] ;COPY FROM SOURCE JOB TO FREE STORAGE
SETZM (TEM) ;CLEAR THE ERROR FLAG
POPJ P, ;RETURN TO CALLER OF JRDBL1, RESTORING MAP
;ENTER HERE WITH TAC=JOB JUST SWAPPED IN, J=JOB # WHO WANTS TO READ HIM
;CALLED FROM FININ
↑JRDWIN:PUSH P,TEM ;FIRST SAVE SOME ACS
PUSH P,AC1
PUSH P,AC2
PUSH P,AC3
PUSHJ P,JRDBLT ;DO BLT
JRDLEV: POP P,AC3 ;NOW RESTORE ACS
POP P,AC2
POP P,AC1
POP P,TEM
POPJ P,
;CALLED FROM FININ
↑JRDLOS:PUSH P,TEM ;FIRST SAVE SOME ACS
PUSH P,AC1
PUSH P,AC2
PUSH P,AC3
PUSHJ P,JOBRC1 ;GIVE ADDR ERROR RETURN ON SWAP ERROR
JRST JRDLEV
;DONE, RESTART USER
JOBRC3: SKIPA TAC,[5] ;NO JOB THERE
JOBRC1: MOVEI TAC,4 ;ADDR ERROR
SKIPN TEM,JBTFS(J) ;MAKE SURE FS BLOCK EXISTS
POPJ P, ;NO FS. EXIT QUIETLY.
MOVEM TAC,(TEM)
JOBRC2: MOVM AC3,JOBQUE(J)
CAIE AC3,IOWQ ;IS HE WHERE WE LEFT HIM?
JRST JOBRC4 ;NO, GIVE BACK FS AND GO AWAY
MOVNI AC3,RUNQ
MOVEM AC3,JOBQUE(J)
JRST REQUE
JOBRC4: SKIPE AC1,JBTFS(J)
PUSHJ P,FSGIVE
SETZM JBTFS(J)
POPJ P,
;TMPCOR UUO - BEHAVES AS DESCRIBED IN DEC MANUAL
TMPMAX←←400 ;MAX TOTAL SIZE OF ONE JOB'S TMPCOR FILES
;FORMAT OF TMPCOR BLOCK
TMPLNK←←0 ;DOUBLE LINK WORD
TMPNAM←←1 ;NAME,,SIZE
TMPPPN←←2 ;PPN (ALIAS) OF TMP FILE
TMPDAT←←3 ;BEGINNING OF DATA
TMPCRD: XCTR XR,[HRRZ DSER,(TAC)] ;TMPCOR TO OTHER JOB
SKIPN DSER ;DSER←JOB NUMBER.
MOVEI DSER,(J) ;IF ZERO, USE OWN JOB.
MOVEI TAC1,0 ;IN CASE OF ACCIDENT, SETUP TO RETURN ZERO
CAMLE DSER,JOBNM1
JRST TMPCR1 ;ILLEGAL JOB NUMBER. RETURN ZERO.
MOVE AC1,JBTSTS(DSER)
TLNN AC1,JNA
JRST TMPCR1 ;NO SUCH JOB. RETURN ZERO.
XCTR XR,[SKIPN UUO,2(TAC)] ;GET ALIAS, IF ANY, FROM USER
MOVE UUO,PRJPRG(DSER) ;DEFAULT TO HIS OWN PPN
JRST TMPCO1 ;ACT LIKE TMPCOR
TMPCOR: MOVEI DSER,(J) ;TMPCOR TO YOURSELF. DSER←JOB NUMBER
SKIPN UUO,DSKPPN(DSER) ;UUO←YOUR ALIAS, OR PPN
MOVE UUO,PRJPRG(DSER)
TMPCO1: HLRZ TAC1,TAC ;TAC1←TMPCOR FUNCTION NUMBER.
CAIL TAC1,NUMTMP
JRST UUOERR ;ILLEGAL FUNCTION NUMBER.
CAIE DSER,(J) ;TMPCOR TO SELF?
SKIPGE TMPDSP(TAC1) ;NO. SKIP IF ILLEGAL FUNTION FOR TMPCRD
JRST .+2 ;LEGAL FUNCTION
JRST UUOERR
PUSHJ P,@TMPDSP(TAC1) ;PREFORM FUNCTION.
JRST .+2
AOS (P) ;SET SKIP RETURN FOR UUO.
TMPCR1: XCTR XW,[MOVEM TAC1,(UCHN)] ;RETURN PARAMETER FROM TAC1 (OFTEN SIZE)
POPJ P,
TMPDSP: SETZ TMPSZ1 ;SIGN BIT IF FUNCTION IS ALLOWED FOR TMPCRD
SETZ TMPRED
TMPRDD
TMPWRT
SETZ TMPDIR
TMPCLR
SETZ TMPALD ;TMPDIR IN ALL-ALIAS VERSION
TMPALC ;TMPCLR DITTO
NUMTMP←←.-TMPDSP
;SCAN A JOB'S TMPCOR FILES.
; EXECUTE 3 INSTRS FOLLOWING CALL:
; JSP DAT,TMPSCN
; INST1 ;CAME UUO,TMPPPN(AC1) OR CAIA
; INST2 ;IF THIS SKIPS, TMPSCN WILL SKIP RETURN
; INST3 ;IF THIS DOESN'T SKIP, TMPSCN WILL SKIP
; <NORMAL RETURN>
; <SKIP RETURN>
TMPSCN: HRRZ AC3,JBTTCR(DSER)
TMPSC1: SKIPN AC1,AC3
JRST 3(DAT)
HRRZ AC3,TMPLNK(AC1) ;SAVE LINK NOW IN CASE WE ARE DELETING
XCT (DAT) ;SKIP IF ALIAS IS OK.
JUMPN UUO,TMPSC1 ;BUT, UUO = 0 MEANS ALL ALIAS.
XCT 1(DAT)
XCT 2(DAT) ;THIS ONE USUALLY SKIPS
JRST 4(DAT) ;BUT SKIP RETURN NOW IF NOT
JRST TMPSC1
;CALCULATE AMOUNT OF ROOM LEFT (TMPMAX-CURRENT TOTAL)
TMPSZ1: AOS (P) ;FUNCTION ZERO. GIVE SKIP RETURN.
TMPSIZ: MOVEI TAC1,TMPMAX
JSP DAT,TMPSCN
CAIA ;IGNORE ALIAS
SUB TAC1,TMPNAM(AC1) ;COMPUTE FREE SPACE.
TLZA TAC1,-1
POPJ P,
;CHECK TMPCOR WCMA
;RETURNS TAC1=FIRST RELATIVE ADDRESS OF XFER. AC2=MINIMUM WORD COUNT.
;IF WORD COUNT IS ZERO, THE NON-SKIP RETURN IS TAKEN.
;ENTER AT TMPSET FOR WRITE OPERATIONS. AT TMPST1 FOR READ.
TMPSET: MOVEI TAC1,-1 ;UPPER LIMIT ON WC IS INFINTE (WRITE)
TMPST1: XCTR XR,[HLRE AC2,1(TAC)] ;-WC
JUMPGE AC2,CPOPJ ;DIRECT RETURN IF WC=0
MOVN AC2,AC2 ;+ WC
CAILE TAC1,(AC2) ;USE MIN OF FILE & USER WC'S
SKIPA TAC1,AC2
MOVEI AC2,(TAC1)
XCTR XR,[HRRZ AC3,1(TAC)] ;START ADR-1. (BOTH AC2 AND TAC1 HAVE WC)
PUSH P,AC1
ADDI TAC1,(AC3) ;CALCULATE END ADR
PUSHJ P,RELOCA ;CHECK IT
JRST UUOERR
MOVEI TAC1,1(AC3) ;START ADR
PUSHJ P,RELOCB ;CHECK THAT TOO
JRST UUOERR
POP P,AC1
XCTR XR,[HRRZ TAC1,1(TAC)] ;TAC1←STARTING ADDRESS-1
AOJA TAC1,CPOPJ1 ;SET TAC1 TO STARTING ADDRESS. SKIP.
;FIND REQUESTED TMPCOR FILE
TMPFND: XCTR XR,[HLLZ TAC1,(TAC)]
JSP DAT,TMPSCN
CAME UUO,TMPPPN(AC1) ;ONLY MATCH CURRENT ALIAS
HLLZ AC2,TMPNAM(AC1)
CAMN AC2,TAC1
POPJ P,
JRST CPOPJ1
;READ TMPCOR FILE
TMPRED: PUSHJ P,TMPFND ;LOOK FOR FILE
JRST TMPSIZ ;NOT THERE - RETURN FREE SIZE
HRRZ TAC1,TMPNAM(AC1) ;LIMIT TRANSFER TO SIZE OF FILE.
PUSHJ P,TMPST1 ;SETUP FOR TRANSFER.
JRST TMPRDX ;USER SPECIFIED 0 WC. RETURN FILE SIZE.
HRLI TAC1,TMPDAT(AC1) ;SOURCE IN LH. USER ADDRESS IN RH
ADDI AC2,(TAC1) ;USER'S FIRST ADDR+SIZE = ENDING ADDR+1
XCTR XBLTW,[BLT TAC1,-1(AC2)] ;MOVE DATA FROM SYSTEM TO USER.
TMPRDX: HRRZ TAC1,TMPNAM(AC1) ;RETURN ACTUAL FILE SIZE.
JRST CPOPJ1
;WRITE TMPCOR FILE
TMPWRT: PUSHJ P,TMPFND ;SEE IF IT ALREADY EXISTS
JRST .+2 ;NO.
PUSHJ P,TMPDEL ;YES - DELETE IT
PUSHJ P,TMPSET ;CHECK ARGUMENTS.
JRST TMPSIZ ;NO TRANSFER.
PUSHJ P,TMPSIZ
CAILE AC2,(TAC1)
POPJ P, ;NOT ENOUGH ROOM LEFT
MOVEI AC3,TMPDAT(AC2) ;AC3←SIZE OF FREE STORAGE BLOCK NEEDED.
PUSHJ P,UFSGET ;GET A BLOCK
XCTR XR,[HLRE AC2,1(TAC)] ;-WC
MOVN AC2,AC2 ;+ WC
XCTR XR,[HRRZ TAC1,1(TAC)] ;TAC1←STARTING ADDRESS-1
MOVSI DAT,1(TAC1) ;SOURCE OF BLT. USER TO SYSTEM
MOVSI TAC1,JBTTCR(DSER)
HRR TAC1,JBTTCR(DSER) ;& LINK IT IN
MOVEM TAC1,TMPLNK(AC1)
HRRM AC1,JBTTCR(DSER)
HRLM AC1,(TAC1)
XCTR XR,[HLL AC2,(TAC)] ;GET NAME (SIZE STILL IN RH OF AC2)
MOVEM AC2,TMPNAM(AC1) ;STORE NAME & SIZE
MOVEM UUO,TMPPPN(AC1) ;AND ALIAS WITH TMP FILE
HRRI DAT,TMPDAT(AC1) ;MAKE BLT PNTR
ADDI AC2,(DAT) ;CALCULATE ENDING ADDRESS+1
XCTR XBLTR,[BLT DAT,-1(AC2)] ;MOVE DATA. USER TO SYSTEM.
JRST TMPSZ1 ;SKIP RETURN WITH NEW FREE CNT
;READ & DELETE TMPCOR FILE
TMPRDD: PUSHJ P,TMPRED ;TRY TO READ FILE
POPJ P, ;READ FAILED.
AOS (P) ;SET SKIP. FALL INTO TMPDEL
;DELETE TMPCOR FILE SPECIFIED BY (AC1)
TMPDEL: MOVE AC2,TMPLNK(AC1) ;FETCH DOUBLE LINK WORD
TRNE AC2,-1 ;SKIP IF FORWARD LINK IS ZERO
HLLM AC2,(AC2) ;STORE REVERSE LINK IN NEXT BLOCK
MOVS AC2,AC2
HLRM AC2,(AC2) ;STORE FORWARD LINK IN PREVIOUS BLOCK
JRST FSGIVE ;RETURN BLOCK TO FREE STORAGE.
;READ TMPCOR DIRECTORY
TMPALD: MOVEI UUO,0 ;LIST ALL REGARDLESS OF ALIAS
TMPDIR: MOVEI TEM,CPOPJ ;NO DELETING
TMPDR2: PUSHJ P,TMPSET
JFCL
MOVSI AC2,1(AC2) ;ADJUST BY 1 FOR TOP-TESTING AOBJN
MOVN AC2,AC2
HRRI AC2,(TAC1) ;AOBJN POINTER RELATIVE TO USER CORE.
MOVEI TAC1,0 ;INITIALIZE ITEM COUNT. (RETURNED TO USER)
JSP DAT,TMPSCN
CAME UUO,TMPPPN(AC1) ;MUST MATCH ALIAS (UNLESS UUO=0)
PUSHJ P,TMPDR0
CAIA
JRST CPOPJ1
TMPDR0: JUMPN UUO,TMPDR1 ;ALL-ALIAS LISTING HAS 2-WD ENTRIES
AOBJP AC2,.+3 ;(BUT ONLY IF IT FITS)
MOVE TAC,TMPPPN(AC1) ;FIRST WORD IS ALIAS
XCTR XW,[MOVEM TAC,-1(AC2)]
TMPDR1: MOVE TAC,TMPNAM(AC1) ;GET NAME & SIZE
AOBJP AC2,.+2
XCTR XW,[MOVEM TAC,-1(AC2)] ;STORE IF ROOM
AOJA TAC1,(TEM) ;COUNT ITEM & DO EXIT THING
;READ & CLEAR TMPCOR DIRECTORY
TMPALC: MOVEI UUO,0 ;CLEAR ALL REGARDLESS OF ALIAS
TMPCLR: JSP TEM,TMPDR2 ;SET TEM TO CALL TMPDEL FOR EACH ITEM
PUSH P,AC2 ;NEED TO SAVE THIS FOR TMPDR0
PUSHJ P,TMPDEL
POP P,AC2
POPJ P,
;DELETE ALL TMPCOR FILES (IGNORE ALIAS) - HERE FROM JOBKL
TMPKIL: MOVEI DSER,(J) ;THIS ROUTINE DOES OWN JOB!
JSP DAT,TMPSCN ;FIND ALL TMP FILES.
CAIA ;IGNORE ALIAS
PUSHJ P,TMPDEL ;DELETE EACH ONE
CAIA
POPJ P,
;MAIL UUO, FNDJOB
UMAIL: CAILE UCHN,MAXMAIL ;AC FIELD IN BOUNDS?
JRST UUOERR ;NO LOSE.
JRST @MALTBL(UCHN) ;DISPATCH TO APPROPRIATE ROUTINE
DEFINE UUOS{FOR X IN(SEND,WRCV,SRCV,SKPME,SKPHIM,SKPSEN)}
PSHSYS
LOSYS
UUOMAC MALTBL,MAIL
MAXMAIL←←UUOCNT-1
POPSYS
SKPSEN: JSP AC3,FNDJOB ;THIS JSP MUST BE LABELED SKPSEN
JRST SEND1 ;ADDRESSEE EXISTS, BEHAVE LIKE "SEND" UUO
SEND: JSP AC3,FNDJOB ;DAT ← JOB# OF RECEIVING JOB
SEND1: XCTR XR,[HRRZ TAC,1(UUO)] ;GET THE ADDRESS OF THE MAIL BLOCK
XCTR XR,[MOVE AC2,37(TAC)] ;ADDRESS CHECK LAST WORD OF MAIL BLOCK
MOVEI AC3,40 ;GET SOME FREE STORAGE.
PUSHJ P,UFSGET
HRRZ TAC1,JBTMAIL(DAT) ;DOES THIS GUY HAVE MAIL ALREADY?
JUMPN TAC1,FSGIVE ;YES. CAN'T DO IT. RETURN FS BLOCK.
HRRM AC1,JBTMAIL(DAT) ;STORE ADDRESS OF MAIL (KEEP MAIL WAIT FLAG)
HRLI AC1,(TAC) ;USER-RELATIVE SOURCE ADDRESS.
MOVEI AC2,37(AC1) ;AC2←ENDING ADDRESS IN FREE STORAGE
XCTR XBLTR,[BLT AC1,(AC2)] ;BLT FROM USER TO FREE STORAGE
MOVEI J,(DAT) ;J←RECEIVER'S JOB NUMBER
HLLZ TAC,JBTMAIL(J)
JUMPE TAC,NOWAKE ;JUMP IF HE'S NOT WAITING IN WRCV.
HRRZS JBTMAIL(J) ;CLEAR WRCV FLAG
SKIPL JBTSTS(J) ;IF NOT RUNNABLE, DON'T REQUE HIM
JRST NOWAKE
MOVEI TAC,RUNQ
MOVNM TAC,JOBQUE(J)
PUSHJ P,REQUE
NOWAKE: MOVSI AC1,INTMAIL ;IS HE ENABLED FOR A MAIL INTERRUPT?
TDNN AC1,JBTIEN(J)
JRST CPOPJ1 ;NO RETURN QUICK
IORM AC1,JBTIRQ(J) ;YES, GIVE HIM THE INTERRUPT.
SETOM INTREQ(PID)
SKIPN INTACT(PID) ;SKIP IF SENDER IS ALREADY AT I-LEVEL
PUSHJ P,WSCHED ;SHUT US OFF TO GET THE INTERRUPT PROCESSED.
JRST CPOPJ1 ;DON'T TRY TO RESCHEDULE IF AT I-LEVEL
WRCV: PUSHJ P,SRCV ;WAIT FOR MAIL AND RECIEVE IT. ANY THERE?
TROA AC1,IOWQ ;NO ONE HOME (AC1 IS RETURNED AS 0)
POPJ P, ;THERE WAS A LETTER AND HE'S BEEN GIVEN IT.
HRROS JBTMAIL(J) ;STORE -1,,0 IN JBTMAIL TO FLAG WAITING
MOVNM AC1,JOBQUE(J)
PUSHJ P,WSCHED
JRST WRCV
SRCV: HRRZ AC1,JBTMAIL(J) ;RECIEVE MAIL AND SKIP IF THERE'S SOME.
JUMPE AC1,CPOPJ ;DIRECT RETURN IF NO MAIL
MOVSI TAC,(AC1) ;SOURCE ADDRESS FOR MAIL
HRRI TAC,(UUO) ;GET RELATIVE ADDRESS OF DESTINATION
MOVEI TAC1,37(TAC)
XCTR XBLTW,[BLT TAC,(TAC1)] ;MOVE DATA FROM FREE STORAGE TO USER
SETZM JBTMAIL(J) ;(IN CASE OF ADDRESS CHECK, DON'T ZERO
PUSHJ P,FSGIVE ; POINTER TO FS UNTIL READY)
JRST CPOPJ1
SKPME: SKIPA DAT,J ;SKIP IF THERE'S MAIL FOR ME.
SKPHIM: JSP AC3,FNDJOB ;SKIP IF THERE'S MAIL FOR SOME OTHER JOB
HRRZ AC3,JBTMAIL(DAT)
JUMPG AC3,CPOPJ1
POPJ P,
;GET THE JOB NUMBER OF THE ADDRESSEE.
↑FNDJOB:XCTR XR,[MOVE DAT,(UUO)] ;GET USER'S ARGUMENT (CALLED FROM DPYSER)
CAIGE DAT,JOBN ;IS IT TOO BIG FOR A JOB NUMBER?
JUMPG DAT,GJ1 ;YES. IF POSITIVE, THIS IS A JOB NUMBER.
MOVSI TAC,-JOBN ;SEARCH ALL JOB NAMES.
CAME DAT,JOBNAM(TAC) ;IS THIS ONE?
AOBJN TAC,.-1 ;NOT A MATCH. LOOP.
JUMPGE TAC,GJERR ;JUMP IF NO NAMES MATCHED
SKIPA TAC1,TAC ;CONTINUE SCAN. LOOK FOR ANOTHER
CAME DAT,JOBNAM(TAC1) ;SAME NAME?
AOBJN TAC1,.-1 ;NO.
JUMPL TAC1,GJERR2 ;MATCH OR END OF LOOP. JUMP IF AMBIGUOUS
MOVEI DAT,(TAC) ;DAT←JOB NUMBER OF UNIQUE MATCH
GJ1: MOVE TAC,JBTSTS(DAT) ;GET JOB STATUS
TLNE TAC,JNA ;IS THIS JOB SLOT ASSIGNED?
JRST (AC3) ;YES. RETURN WITH JOB NUMBER IN DAT
GJERR: SKIPA TAC,[GTGAR1] ;GET ADDRESS OF ERROR ROUTINE
GJERR2: MOVEI TAC,GTGARP ;PICKUP THE AMBIGUOUS NAME ERROR MESSAGE
HRRZ AC3,AC3 ;FIND OUT WHO CALLED FNDJOB
CAIN AC3,SKPSEN+1 ;WAS IT SKPSEN UUO?
JRST CPOPJ2 ;YES, TERMINATE THE UUO
PUSHJ P,HNGMES ;NO, COME BACK WHEN HE TYPES CONTINUE
JRST FNDJOB ;
GTGAR1: ASCIZ /? Non-ex job name or number
/
GTGARP: ASCIZ /? ambiguous job name
/
SUBTTL UUOCON IO SECTION
;FOR PURPOSES OF COMMENTING THIS SUBROUTINE THE
;TERM 'BUFFER HEADER' SHALL REFER TO THE 3 WORD HEADER
;WHICH IS USED BY THE USER PROGRAM AND THIS EXEC FOR
;REFERING TO THE RING BUFFERS.
;THE CONTENTS OF THE 3 WORD HEADER (AS SET BY THE MONITOR
; ON EACH INPUT AND OUTPUT UUO).
; BIT 18-35=ADDRESS OF SECOND WORD OF THE
; CURRENT BUFFER IN RING WHICH USER IS REFERENCING
; WORD 2: BYTE POINTER TO CURRENT ITEM.
; WORD 3: POSITIVE ITEM COUNT (NO. OF ITEMS LEFT ON
; INPUT, NO. OF FREE ITEMS TO GO ON OUTPUT).
;EACH BUFFER IN THE RING HAS FOLLOWING FORMAT (AS THE USER SEES IT)
; WORD 1: RESERVED FOR BLOCK NUMBER FOR FIXED ADDRESS DEVICES
; WORD 2: BIT 0=USE BIT FOR THIS BUFFER
; BIT 1-17=NO. OF WORDS WHICH FOLLOW (LENGTH OF BUFFER)/
; BIT 18-35=ADDRESS OF SECOND WORD OF NEXT BUFFER IN RING
; WORD 3: LH=LINK TO NEXT BLOCK (SET BY MONITOR FOR DECTAPE)
; RH=NO. OF WORDS OF DATA WHICH FOLLOW (USUALLY
; SET BY EXEC EXCEPT IF THE USER HAS SPECIFIED
; THAT HE WANTS TO COMPUTE WORD COUNT
; HIMSELF INSTEAD OF HAVING THE MONITOR DO IT
; USING THE BYTE POINTER IN THE 3 WORD HEADER).
;IOPUSH, IOPOP, IOPDL
;IOPUSH CHN,ID
; PUSH DEVICE ON CHANNEL "CHN" ON STACK WITH ID "ID"
IOPUSH: SKIPE AC1,JBTIOP(J)
JRST IOPSH1
MOVEI AC3,IOPDLN
PUSHJ P,UFSGET
MOVEM AC1,JBTIOP(J)
IOPSH1: HLRZ AC3,AC1
CAIN AC3,-IOPDLN
POPJ P, ;NO SPACE ERROR
SUBM AC1,AC3
CAMLE UCHN,USRHCU
TDZA DDB,DDB
MOVE DDB,USRJDA(UCHN)
MOVEM DDB,(AC3)
SETZM USRJDA(UCHN)
SKIPN TAC,USRHCU
JRST IOPSH2 ;USRHCU STAYS AT 0 EVEN IF NO CHANNELS OPEN
IOPSH3: SKIPN USRJDA(TAC)
SOJG TAC,IOPSH3
MOVEM TAC,USRHCU
IOPSH2: MOVEM UCHN,1(AC3)
HRLM UUO,1(AC3) ;SAVE ID ON STACK WITH CHANNEL NUMBER
SUB AC1,[2,,0]
IOPOP3: MOVEM AC1,JBTIOP(J)
JRST CPOPJ1
;IOPOP CHN,ID
; RELEASE DEVICE ON CHANNEL "CHN", POP DEVICE WITH ID "ID" INTO CHANNEL "CHN"
IOPOP: PUSHJ P,FIOPID ;FIND ID WHICH USER SPECIFIED
POPJ P, ;NO STACK, OR NOT FOUND
IOPOP0: SKIPE DDB,USRJDA(UCHN) ;IS A DEVICE ALREADY ASSIGNED TO THIS CHAN?
CAMLE UCHN,USRHCU(PID) ;YES, IS THIS CHAN. LE HIGHEST CHAN. FOR THIS USER?
JRST IOPOP2 ;NO, NO PREVIOUS DEVICE TO RELEASE
HRRZ DSER,DEVSER(DDB)
PUSH P,AC3 ;SAVE POINTER TO ENTRY WE WILL POP
PUSHJ P,RELEA0 ;RELEASE PREVIOUS DEVICE ON THIS CHAN.
POP P,AC3
IOPOP2: MOVE DDB,(AC3) ;THIS POINTS TO STACK ENTRY
MOVEM DDB,USRJDA(UCHN) ;NEW DEV ON THIS CHANNEL
JUMPE DDB,IOPOP4 ;DON'T READJUST USRHCU IF POPPING A NULL CHANNEL
CAMG UCHN,USRHCU
JRST IOPOP4
IOPOP1: AOS TAC,USRHCU
CAMN UCHN,USRHCU
JRST IOPOP4
SETZM USRJDA(TAC)
JRST IOPOP1
IOPOP4: MOVE AC1,JBTIOP(J)
ADD AC1,[2,,0]
JUMPG AC1,IOPOP5
HLRE AC2,AC1
SUBM AC1,AC2
HRRZ AC3,AC3
CAIN AC3,(AC2) ;ARE WE THE END ENTRY?
JRST IOPOP3 ;YES, SKIP BLT
HRLI AC3,2(AC3) ;BLT DOWN ONE ENTRY
BLT AC3,-1(AC2) ;LAST WORD OF LAST ENTRY
JRST IOPOP3
IOPOP5: SETZM JBTIOP(J)
AOS (P)
JRST FSGIVE
IOPDL: CAIL UCHN,IOPDLL ;LEGAL IOPDL FUNTION?
JRST UUOERR ;NO
JRST @IOPDLD(UCHN) ;DISPATCH
;IOPDL 0,
; RETURN ALL STACKED DEVICES TO WHERE THEY CAME FROM
IOPDL0: SKIPL AC3,JBTIOP(J)
POPJ P,
HLRE AC1,AC3
SUB AC3,AC1
HRRZ UCHN,-1(AC3) ;GET JUST CHANNEL NUMBER
TRZ UUO,-1 ;MAKE SURE WE GET TOP OF STACK
PUSHJ P,IOPOP
POPJ P,
JRST IOPDL0 ;LOOP TO RESTORE MORE PUSHED CHANNELS
;IOPDL 1,
; RELEASE ALL STACKED DEVICES
IOPDL1: SKIPL JBTIOP(J)
POPJ P, ;DONE
TRZ UUO,-1 ;DO IT TO TOP OF STACK
PUSHJ P,IOPDL2 ;RELEASE IT
POPJ P, ;FOO
JRST IOPDL1 ;LOOP TILL ALL GONE
;IOPDL 2,ID
; RELEASE STACKED DEVICE WITH ID "ID".
IOPDL2: PUSHJ P,FIOPID
POPJ P, ;NOT FOUND
MOVE DDB,(AC3) ;GET DEVICE HE WANTS RELEASED
EXCH DDB,USRJDA ;EXCHANGE WITH CHAN 0
MOVEM DDB,(AC3) ;WHICH WE SAVE ON STACK
SETZ UCHN, ;NOW RELEASE CHANNEL 0 AND POP OLD ONE BACK THERE
JRST IOPOP0
IOPDLD: IOPDL0
IOPDL1
IOPDL2
IOPDLL←←.-IOPDLD
FIOPID: SKIPL AC3,JBTIOP(J) ;ANY STACK AT ALL?
POPJ P, ;NO
HLRE AC1,AC3
SUBI AC3,2(AC1) ;POINT TO TOP OF STACK
MOVNI AC1,2(AC1)
HRL AC3,AC1 ;PUT COUNT IN LEFT HALF
TRNN UUO,-1 ;ANY ID?
JRST CPOPJ1 ;NO, 0 IS ALWAYS TOP OF STACK
IOPID1: HLRZ AC1,1(AC3) ;GET ID
CAIN AC1,(UUO)
JRST CPOPJ1 ;FOUND IT
SUB AC3,[2,,2]
JUMPG AC3,IOPID1 ;MORE TO GO?
POPJ P, ;NO, NOT FOUND
; CLOSE UUO - CALLING SEQUENCE
; CLOSE D,
; EXIT ALWAYS RETURNS HERE
; THIS ROUTINES PROCESSES THE CLOSE UUO AND DETERMINES WHETHER THE
;OUTPUT ROUTINE SHOULD BE CALLED IF OUTPUT WERE ACTIVE, CLEARS
;THE INPUT BUFFER AREA IF INPUT WERE ACTIVE, AND CLEARS THE
;ITEM COUNTS OF BOTH INPUT AND OUTPUT HEADERS SERVING TO BOTH
;TERMINATE THE USE OF THE DEVICE AND SET THE I/O ROUTINES TO
;ACCEPT ANOTHER INPUT OR OUTPUT COMMAND IN A CLEAR STATE.
;IN THE CASE OF OUTPUT DEVICES, THE CLOSE ROUTINE OF THE DEVICE HANDL-
;ING ROUTINE IS CALLED IN CASE ANY SPECIAL HANDLING IS REQUIRED.
;CLOSE UUO, CLOSE INPUT - WAIT FOR IO TO FINISH, FLUSH BUFFERS - CLOSE1
;DEVICE SERVICE ROUTINES ARE EXPECTED TO PRESERVE DDB, UUO
↑CLOSE1:
PUSH P,UCHN ;BULLETPROOFING!
PUSHJ P,WAIT1 ; WAIT UNTIL DEVICE IS INACTIVE
ANDCMI UUO,777774 ;ZERO ALL BUT CLOSE-INHIBIT BITS IN RH OF UUO
TRNN UUO,CLSIN ;SUPPRESS INPUT CLOSE?
TLOE DDB,ICLOSB ;NO. INPUT ALREADY BEEN CLOSED?
JRST UCLS2 ;YES
LDB TAC,PIOMOD ;NO
CAIL TAC,SD ;DUMP MODE?
JRST UCLS5 ;YES - GO CLOSE DUMP INPUT.
MOVE TAC,DEVMOD(DDB) ;CLOSE BUFFERED INPUT.
TLNN DDB,INBFB+INPB ;WAS AN INPUT BUFFER SETUP?
JRST UCLS4 ;NO. FORGET ABOUT CLOSE (EXCEPT DISK OR IMP)
TLNE TAC,DVLNG ;LONG DISPATCH TABLE?
PUSHJ P,DCLI(DSER) ;YES, THEN CALL DEVICE TO CLOSE BUFFERED INPUT
HRRZ TAC1,DEVBUF(DDB)
XCTR XR,[HRRZ DAT,(TAC1)] ;PICK UP FIRST WORD OF BUFFER HEADER
LDB AC3,PDVBLN ;PICK UP BUFFER LENGTH
ADDI AC3,(DAT) ;ADD IN BUFFER ADDRESS
XCTR XRW,[MOVES (AC3)] ;ADDRESS CHECK BUFFER ADDRESS
XCTR XR,[HRR TAC1,(TAC1)] ;REMEMBER CURRENT BUFFER IN TAC1
MOVSI TAC,IOUSE ;USED BOTH FOR HEADER AND EACH BUFFER
JUMPE DAT,UCLS1 ;HAS A RING BEEN SETUP?(NO IF 0)
MOVEI AC1,0
LDB TEM,PDVBLN ;FIGURE OUT THE MAXIMUM NUMBER OF BUFFERS
HLRZ AC3,JBTPAG(J)
LSH AC3,=9
IDIVI AC3,(TEM)
ADDI AC3,2 ;AND THIS IS CERTAINLY A GOOD UPPER BOUND!
UCLS0: XCTR XR,[HRR DAT,(DAT)] ; ADVANCE CURRENT INPUT BUFFER ADDRESS
CAIN AC1,(DAT) ;IS THIS THE SAME BUFFER AS LAST ONE?
JRST UCLS1 ;YES. BAD RING. LOOPING ON ITSELF.
MOVEI AC1,(DAT) ;IS ADDRESS OK?
XCTR XRW,[ANDCAM TAC,(DAT)] ;CLEAR USE BIT IN BUFFER
SOJL AC3,UCLS1
CAME TAC1,DAT ;DONE?
JRST UCLS0
UCLS1: HRRZ DAT,DEVBUF(DDB)
XCTR XRW,[IORM TAC,(DAT)] ;FLAG AS VIRGIN BUFFER IN HEADER
XCTR XW,[SETZM 2(DAT)] ;CLEAR INPUT ITEM COUNT
MOVE IOS,[XWD IOEND,IODEND]
ANDCAB IOS,DEVIOS(DDB)
JRST UCLS2 ;GO CLOSE THE OUTPUT SIDE
UCLS4: TLNE TAC,DVDSK!DVIMP ;NO INPUT BUFFERS BUT FOR DSK & IMP MUST CALL DEVICE
UCLS5: PUSHJ P,DCLI(DSER) ;CLOSE DUMP MODE INPUT. PRESERVE UUO,DDB
JRST UCLS2 ;NOW CLOSE OUTPUT SIDE
;CLOSE OUTPUT
UCLS2: MOVE DSER,DEVSER(DDB) ;IN CASE OF ACCIDENTS.
LDB J,PJOBN ;IMPSER CLOBBERS J, DSER AND WHATEVER ELSE
TRNN UUO,CLSOUT ;SUPPRESS OUTPUT CLOSE?
TLOE DDB,OCLOSB ;NO. OUTPUT ALREADY CLOSED?
JRST UCLS3 ;YES
LDB TAC,PIOMOD ;NO.
CAIL TAC,SD ;DUMP MODE?
JRST UCLS7 ;YES - GO CLOSE DUMP OUTPUT
TLNN DDB,OUTBFB+OUTPB ;CLOSE BUFFERED OUTPUT
JRST UCLS6 ;NO BUFFERS WERE SETUP
HLR DAT,DEVBUF(DDB) ;RESTORE DAT NOW.
XCTR XR,[SKIPG (DAT)] ;BUFFERS SET UP?
JRST UCLS6 ;NO. DON'T CLOSE UNLESS DISK OR IMP
HLRZ AC1,JBTPAG(J) ;NUMBER OF PAGES IN THE LOWER
LDB AC2,PSEGN
HLRZ AC2,JBTPAG(AC2) ;NUMBER OF PAGES IN THE UPPER
ADD AC1,AC2
LSH AC1,=9 ;TOTAL NUMBER OF WORDS
LDB AC2,PDVBLN ;SIZE OF DATA PORTION OF BUFFER
IDIVI AC1,2(AC2) ;GET MAXIMUM NUMBER OF BUFFERS HE COULD HAVE
PUSH P,AC1 ;AND SAVE IT
UCLS2A: MOVE DSER,DEVSER(DDB)
MOVE AC1,DEVOAD(DDB)
SOSL (P) ;DECREMENT BUFFER COUNT
XCTR XR,[SKIPL (AC1)] ;HAS DEVICE WRITTEN ITS NEXT BUFFER YET?
JRST UCLS2B ;YES, OR WE LOOKED AT TOO MANY BUFFERS
TRZ IOS,760000 ;NO. START OUTPUT DEVICE.
PUSH P,UUO ;UUO GETS CLOBBERED BY SOMEONE
PUSHJ P,DOU(DSER) ;KICK DEVICE
LDB J,PJOBN ;GODDAM IMPSER
POP P,UUO ;RESTORE UUO
PUSHJ P,WAIT1 ;WAIT TILL MOST BUFFERS EMPTIED
TRNN IOS,760000 ;ERROR?
JRST UCLS2A ;NO - TRY TO EMPTY MORE BUFERS
UCLS2B: SUB P,[XWD 1,1] ;THROW AWAY MAXIMUM BUFFER COUNT
MOVE DSER,DEVSER(DDB)
PUSHJ P,DCL(DSER) ;CLOSE BUFERED OUTPUT
HLRZ DAT,DEVBUF(DDB)
MOVSI TAC,IOUSE
XCTR XRW,[IORM TAC,(DAT)]
XCTR XW,[SETZM 2(DAT)]
PUSHJ P,WAIT1
JRST UCLS3
UCLS6: MOVSI TAC,DVDSK!DVIMP ;NO OUTPUT BUFFERS TO CLOSE.
TDNE TAC,DEVMOD(DDB) ;FOR DISK OR IMP ALWAYS CALL DEVICE
UCLS7: PUSHJ P,DCL(DSER) ;CLOSE DUMP OUTPUT.
UCLS3: POP P,UCHN ;BULLETPROOFING. UCHN←AC FIELD OF UUO.
HLLM DDB,USRJDA(UCHN)
MOVE DSER,DEVSER(DDB) ;IN CASE OF ACCIDENTS. RESTORE J AND DSER
LDB J,PJOBN
POPJ P, ;EXIT THIS UUO
; INBUF - CALLING SEQUENCE
; INBUF D,N
; EXIT RETURNS HERE IF MEMORY NOT EXCEEDED
;CALLING SEQUENCE
; OUTBUF D,N
; EXIT RETURNS HERE IF MEMORY NOT EXCEEDED
; SETS UP AN N BUFFER RING FOLLOWING THE USER'S PROGRAM FOR DEVICE
; D AND INITIALIZES THE JOB BUFFER AREA HEADER:
; JBFADR0:=1, JBFADR 1-17:=0
; JBFADR 18-35:=ADDRESS OF FIRST BUFFER IN RING
;INPUT SETS DEVIAD:=ADDRESS OF FIRST BUFFER IN RING
;OUTPUT SET DEVOAD:=ADDRESS OF FIRST BUFFER IN RING
;BUFPNT IS RESTORED.
;UOUTBF, UINBF, MINBF, MOUTBF. INBUF, OUTBUF, UINBF, UOUTBF - SETUP BUFFERS
;OUTBUF
UOUTBF: TLNN DDB,OBUFB ;SEE IF THERE EXISTS AN OUTPUT BUFFER HEADER
JRST ILLOBF ;NO HEADER, GIVE ERROR MESSAGE
TLO DDB,OUTBFB ;FLAG OUTBUF UUO DONE
PUSH P,BUFPNT ;SAVE BUFPNT ON STACK
PUSHJ P,BUFCLC ;SET UP BUFFER RING
UOBF2: HLR TAC,DEVBUF(DDB) ;TAC←OUTPUT BUFFER AREA HEADER ADDRESS
HRRM BUFPNT,DEVOAD(DDB) ;DEVOAD←ADDRESS OF FIRST BUFFER IN RING
UOBF1: XCTR XW,[MOVEM BUFPNT,(TAC)] ;BUFFER HEADER←IOUSE,,ADDR. OF FIRST BUFFER
LDB TAC,PUUOAC
MOVEM DDB,USRJDA(TAC)
POP P,BUFPNT ;RESTORE BUFPNT FROM STACK
POPJ P,
;INBUF
UINBF: TLNN DDB,IBUFB ;IS THERE AN INPUT BUFFER HEADER?
JRST ILLIBF ;NO, ERROR
TLO DDB,INBFB ;FLAG INBUF UUO DONE
PUSH P,BUFPNT ;SAVE BUFPNT ON STACK
PUSHJ P,BUFCLC ;SET UP BUFFER RING
UINBF1: HRRM BUFPNT,DEVIAD(DDB) ;DEVIAD←ADDRESS OF FIRST BUFFER IN RING
HRR TAC,DEVBUF(DDB) ;TAC←INPUT BUFFER AREA HEADER ADDRESS
JRST UOBF1
; UINBF - CALLING SEQUENCE . . .
; UINBF D,ADR
; WHERE D IS CHANNEL NUMBER AND ADR IS ADDRESS OF TWO WORD BLOCK
; THE FIRST WORD OF WHICH IS THE NUMBER OF BUFFERS YOU WANT
; THE SECOND WORD IS THE LENGTH OF EACH BUFFER
MINBF: SKIPE DDB,USRJDA(UCHN) ;GET ADRESS OF DEVICE DATA BLOCK
CAMLE UCHN,USRHCU(PID) ;IS IT LESS THAN OR EQUAL TO HIGHEST
JRST IOIERR ;IO TO UNASSIGNED CHANNEL.
TLNN DDB,IBUFB ;IS THERE A BUFFER HEADER ADDRESS?
JRST ILLIBF ;NO, GO COMPLAIN
TLO DDB,INBFB ;MARK WE HAVE PERFORMED INBUF
PUSH P,BUFPNT
PUSHJ P,MBFSET ;DO ALL THE DIRTY WORK
JRST UINBF1
;UOUTBF - SAME CALLING SEQUENCE AS UINBF
MOUTBF: SKIPE DDB,USRJDA(UCHN) ;GET ADRESS OF DEVICE DATA BLOCK
CAMLE UCHN,USRHCU(PID) ;IS IT LESS THAN OR EQUAL TO HIGHEST
JRST IOIERR ;IO TO UNASSIGNED CHANNEL.
TLNN DDB,OBUFB
JRST ILLOBF
TLO DDB,OUTBFB
PUSH P,BUFPNT
PUSHJ P,MBFSET
JRST UOBF2
MBFSET: MOVE AC1,UUO
XCTR XR,[HRR UUO,(AC1)] ;MAKE UUO LOOK LIKE NORMAL INBUF
XCTR XR,[MOVM TAC,1(AC1)] ;AND PICK UP BUFFER LENGTH
JRST BUFCLM ;GO MAKE THE BUFFERS.
;ERROR MESSAGES FOR THE ABOVE.
ILLOBF: JSP TAC,ERRPTU ;PRINT A BIT, SET UP TTY DDB
ASCIZ /Output /
PUSHJ P,ERNAM ;PRINT "DEVICE XXX"
JSP TAC,UUOMES ;PRINT MESSAGE AND STOP JOB
ASCIZ / has no output buffer header, UUO/
ILLIBF: JSP TAC,ERRPTU ;SET UP FOR ERROR PRINTOUT
ASCIZ /Input /
PUSHJ P,ERNAM ;PRINT "DEVICE XXX"
JSP TAC,UUOMES
ASCIZ / has no input buffer header, UUO/
;INIT AND OPEN UUOS
;OPEN UUO - PERFORMS SAME OPERATION AS INIT
;MAY BE USED EASILY BY REENTRANT PROGRAMS
;CALLING SEQUENCE FROM USER AREA
; OPEN D,ADR
; ERROR RETURN
; DEVICE INITED
;
;LH(ADR)=0,RH(ADR)=DATA MODE THIS INIT
;LH(ADR+1)=OUTPUT BUFFER HEADER ADDRESS
;RH(ADR+1)=INPUT BUFFER HEADER ADDRESS
;C(ADR+2,...,ADR+5)=SAME AS LOOKUP OR ENTER
;
; INIT - CALLING SEQUENCE
; INIT D,MODUS D=JOB DEVICE CHANNEL
; MODUS=IORDEL,IOCON,IOWC,MODE.
; SIXBIT/NAME/ DEVICE NAME
; XWD OBUF,IBUF BUFFER AREA HEADER ADDRESSES
; EXIT1 DEVICE NOT AVAILABLE
; EXIT2 DEVICE PROPERLY ASSIGNED
;THE LEFT HALF OF NAME CONTAINS THE THREE LETTER DEVICE MNEMONIC,
; THE RIGHT HALF IS EITHER ZERO (SYSTEM WILL ASSIGN AN ARBITRARY
; UNIT) OR NON-ZERO TO REQUEST A SPECIFIC UNIT (LEFT JUSTIFIED).
;IF THE SELECTED DEVICE IS NOT AVAILABLE, CONTROL RETURNS TO EXIT1.
;OTHERWISE, THE DEVICE IS ASSIGNED TO THE USER AND ATTACHED TO HIS
;CHANNEL D. THE DEVICE IS INITIALIZED IN THE FOLLOWING MANNER AFTER
;IOACT IS ZERO:
; IOBEG:=1
; DATA MODE:=BITS 32-35 OF AC UUO
; IOCON:=BIT 31 OF AC UUO
; IOWC:=BIT 30 OF AC UUO
; IORDEL:=BIT 29 OF AC UUO
; IOACT:=IODEND:=IOBKTL:=IODTER:=IODERR:=IOIMPM:=0
; JBFADR:=JBFCTR:=0 FOR THE SPECIFIED BUFFERS.
; DEVBUF:=OBUF,IBUF
; INIT CODE - FIRST FIND DEVICE AND TRY TO ASSIGN IT
↑UINIT: MOVE DAT,UUOPC(J) ;SETUP DAT WITH REL ADR OF ARGUMENTS TO INIT
PUSHJ P,UINIT0 ;DO THE INIT
JRST .+2 ;NOW SET UP KLUDGEY MULTIPLE SKIP RETURN
AOS UUOPC(J) ;(ONLY AFTER ALL THRU WAITING, ETC.)
AOS UUOPC(J)
JRST CPOPJ1 ;RETURN WITH ONE MORE SKIP
↑UOPEN: XCTR XR,[SKIP 2(UUO)] ;ADDRESS CHECK GOODIE TABLE
MOVEI DAT,1(UUO) ;SETUP REL ADR OF ARGUMENTS
XCTR XR,[HRR UUO,(UUO)] ;SET UP RH WITH DATA MODE TO LOOK LIKE INIT
UINIT0: PUSH P,DAT ;SAVE POINTER TO ARGUMENT LIST.
SETZM JBTDVW(J) ;FLAG WE NEVER NEEDED TO WAIT FOR DEVICE
;(IF A GOTCHA! FAILS, WE'LL WAIT AGAIN AUTOMATICALLY)
UINITG: SKIPE DDB,USRJDA(UCHN) ;IS A DEVICE ALREADY ASSIGNED TO THIS CHAN?
CAMLE UCHN,USRHCU(PID) ;IS THIS REALLY AN ACTIVE CHANNEL?
JRST UINITA ;NO PREVIOUS DEVICE TO RELEASE
PUSH P,UUO ;SAVE UUO
PUSH P,DAT ;SAVE POINTER TO ARGS.
PUSHJ P,RELEA0 ;RELEASE PREVIOUS DEVICE ON THIS CHAN.
POP P,DAT ;RESTORE REL. ADR. OF ARGS.
POP P,UUO ;RESTORE UUO
UINITA: XCTR XR,[MOVE TAC,(DAT)] ;GET DEVICE NAME FROM USER
UINITK: MOVE J,JOB(PID) ;JOB NUMBER
PUSHJ P,DEVSRC ;SEARCH FOR DEVICE NAME
JRST UINXIT ;NO SUCH DEVICE. ADJUST STACK AND EXIT.
;(DEVSRC WILL SET SYSDEV BIT IN LH OF DDB IF THIS IS SYSTEM TAPE)
MOVE AC1,DEVMOD(DDB)
TLNN AC1,DVUDP ;IS THIS A UDP?
JRST UNITDX ;NO
LDB AC1,PUNIT ;YES, IS OK TO INIT WITHOUT HAVING ASSIGNED
SKIPLE UDPCNT-1(AC1) ; PROVIDING SOMEBODY ELSE HAS IT AS PUBLIC
SKIPL UDPOWN-1(AC1)
UNITDX: SKIPA AC1,DEVCMR(DDB)
JRST UNITAD ;WIN
TLNE AC1,DEVMAS ;SKIP UNLESS MUST ASSIGN FIRST
JRST UNITAC ;CHECK IF ASSIGNED
UNITAD: MOVE TAC,DEVNAM(DDB) ;PHYSICAL DEVICE NAME
CAMN TAC,[SIXBIT /ELF/] ;ELF NEEDS TO KNOW WHEN OPENED (PMF 4/14/76)
PUSHJ P,ELFOPN
CAME TAC,[SIXBIT /DSK/] ;NOT DISK?
CAME TAC,SYSTAP ;SYSTEM TAPE DEVICE?
JRST UINITB ;NO, DISK OR NOT SYSTEM TAPE
CAMN J,STUSER ;IS THIS JOB ALREADY THE S.T. USER?
JRST UINITB ;YES, WE CAN USE IT AGAIN (DTCSER WILLING)
AOSE STREQ ;SYSTEM TAPE, INCREMENT REQUEST COUNT
PUSHJ P,STWAIT ;SYSTEM TAPE BUSY, PUT JOB IN WAIT
MOVEM J,STUSER ;SET THIS JOB AS ONLY USER OF SYSTEM TAPE
;CONTROL C DOES NOT STOP JOB WHILE USING ST
UINITB: MOVEI TAC1,ASSPRG ;TRY TO ASSIGN IT BY PROGRAM
PUSHJ P,ASSASG
JRST UINITW ;NOT AVAILABLE, SEE IF HE WILL WAIT FOR IT
PUSHJ P,SETMOD ;SET DDB IOS STATUS WORD
JRST UINITR ;LOSE. ILLEGAL MODE.
MOVSI IOS,IOBEG ;FLAG INIT JUST DONE
IORB IOS,DEVIOS(DDB) ;FROM RT. HALF OF UUO
MOVE TAC,DEVMOD(DDB) ;GET GOOD BITS
TLNE TAC,DVTTY ;IS IT A TTY?
TLNE TAC,TTYATC ;AND NOT HIS CONSOLE?
JRST UINITL ;NO
MOVSI IOS,TPMON
ANDCAB IOS,DEVIOS(DDB) ;TTY IS NOT IN MONITOR MODE ANY MORE
UINITL: SKIPGE USRHCU(PID) ;IS USRHCU SCREWED UP?(NEGATIVE?)
SETZM USRHCU(PID) ;YES, ZERO IT
UINITM: CAMG UCHN,USRHCU(PID) ;IS THIS CHAN .GT. HIGHEST CHAN. IN USE?
JRST UINITC ;NO
AOS TAC,USRHCU(PID) ;YES, BUMP HIGHEST SO FAR BY ONE
SETZM USRJDA(TAC) ;AND CLEAR IT OUT
JRST UINITM ;AND KEEP LOOKING
UNITAC: PUSH P,DDB ;SAVE MODEL DDB
UNTAC1: LDB AC1,PJOBN ;CHECK FOR ASSIGNED OR INITED ALREADY
CAIN AC1,(J)
JRST UNTAD1 ;SAME JOB MEANS ASSIGNED OR INITED
PUSHJ P,DEVLP2 ;CONTINUE SEARCH
CAIA
JRST UNTAC1 ;GOT ANOTHER, KEEP CHECKING
POP P,DDB
TRNE UUO,400 ;USER DESIRES ERROR RETURN?
JRST UINXIT ;YES. GIVE IT NOW.
JSP TAC,ERRPTU ;RAN OUT, HE LOSES
ASCIZ /Must assign /
PUSHJ P,ERNAM ;TYPE "DEVICE MUMBLE"
JRST EXCALP ;AT USER/EXEC XXX
UNTAD1: POP P,(P)
JRST UNITAD
; INIT - SET UP BUFFERS AND INITIALIZE THEM
UINITC: POP P,DAT ;RESTORE POINTER TO ARGUMENT LIST
TLO DDB,INITB ;SET INIT UUO BIT
XCTR XR,[HLRZ TAC1,1(DAT)] ;OUTPUT BUFFER HEADER FROM USER
JUMPE TAC1,UINIT4 ;WAS ONE SPECIFIED?
HRLM TAC1,DEVBUF(DDB) ;YES, SET DEVICE DATA BLOCK
TLO DDB,OBUFB ;SET OUTPUT BUFFER SPECIFIED BIT
PUSHJ P,UINITZ ;INITIALIZE OUTPUT BUFFER HEADER
UINIT4: XCTR XR,[HRRZ TAC1,1(DAT)] ;INPUT BUFFER HEADER FROM USER
JUMPE TAC1,UINIT5 ;WAS ONE SPECIFIED?
HRRM TAC1,DEVBUF(DDB) ;YES, SET DEVICE DATA BLOCK
TLO DDB,IBUFB ;SET INPUT BUFFER SPECIFIED BIT
MOVSI IOS,IOEND ;CLEAR END OF FILE FLAG
ANDCAB IOS,DEVIOS(DDB) ;AND RETAIN IOS
PUSHJ P,UINITZ ;INITIALIZE INPUT BUFFER HEADER
UINIT5: MOVEM DDB,USRJDA(UCHN) ;STORE UUO BITS AND DDB ADDRESS
JRST CPOPJ1 ;SUCCESS RETURN
UINXIT: POP P,DAT ;RESTORE STACK LOSER EXIT.
POPJ P,
;UINITZ - SET TAC1 TO ADDRESS OF USER'S BUFFER HEADER.
;CLEARS FIRST AND THIRD WORD OF THE BUFFER HEADER. SETS BYTE SIZE IN
;THE SECOND WORD OF THE BUFFER HEADER, ACCORDING TO IO MODE.
UINITZ: XCTR XW,[SETZM (TAC1)] ;CLEAR FIRST WORD OF BUFFER HEADER
XCTR XW,[SETZM 2(TAC1)] ;AND LAST WORD OF BUFFER HEADER
HRLI TAC,700 ;ASSUME A 7 BIT MODE. (0 OR 1)
TRNE IOS,10 ;SKIP IF MODE IS LESS THAN 10.
HRLI TAC,4400 ;36 BIT MODE. IMAGE, BINARY, OR IB
XCTR XRW,[HLLM TAC,1(TAC1)] ;SET BYTE SIZE IN BUFFER HEADER.
POPJ P, ;RETURN
UINITR: PUSH P,DDB ;SAVE LOSER DDB
JSP TAC,ERRPTU
ASCIZ /Illegal data mode for /
PUSHJ P,ERNAM
EXCH DDB,(P) ;SAVE TTY DDB, GET LOSER DDB
PUSHJ P,RELEA7 ;RELEASE DEVICE.
POP P,DDB ;RESTORE TTY DDB
JRST EXCALP ;SEND THE BEDBUG LETTER
DEFINE TYPE (S) <
PUSHJ P,TTYFUW ;WAIT FOR OUTPUT TO FINISH
PUSHJ P,INLMES
ASCIZ /S
/
PUSHJ P,TYPGO ;START UP TTY
>
;UNITW. ASK HIM IF HE IS WILLING TO WAIT FOR THE DEVICE
; PUT HIM IN DEVICE WAIT (DWQ) IF HE WANTS TO WAIT
; ROUTINE TO WAIT FOR DEVICE TO BECOME AVAILABLE FOR INIT
UINITW: TRNE UUO,400 ;DOES HE WANT ERROR RETURN?
JRST UINXIT ;YES. GIVE IT NOW
IFN FTDEVLUP,<
MOVE TAC1,JBTPRV(J)
TLNE TAC1,LUPPRV ;LOCAL-USER?
JRST UINTW1 ;YES BYPASS TEST FOR SPECIAL DEV
MOVE TAC1,DEVCMR(DDB)
TLNE TAC1,DEVLUP
JRST UINXIT >;END IFN FTDEVLUP
UINTW1: PUSH P,UUO
PUSH P,UUOPC(J)
PUSH P,UCHN
SKIPE JBTDVW(J) ;WERE WE HERE BEFORE FOR THIS INIT?
JRST SETWAT ;YES. WE MUST HAVE LOST THE RACE.
HRRZM DDB,JBTDVW(J) ;SAVE THE DEVICE DATA BLOCK ADDRESS
TRNE UUO,IOPAR ;DO WE ASK HIM?
JRST SETWAT ;NO, WAIT AUTOMATICALLY
PUSHJ P,TTYFUW ;WAIT FOR OUTPUT, SET UP DAT AND DDB
HRRZ TAC1,JBTDVW(J)
MOVE TAC1,DEVNAM(TAC1)
PUSHJ P,PRNAME
PUSHJ P,INLMES
ASCIZ / is busy. Will you wait? /
PUSHJ P,TYPGO
CLRBFI ;CLEAR INPUT BUFFER TYPEAHEAD
PUSHJ P,UCTEXT
HRRZ DDB,JBTDVW(J) ;PICK UP DDB ADDRESS OF DESIRED DEVICE
LDB TEM,PJOBN ;JOB NUMBER FROM DDB
CAIN TEM,(J)
JRST GOTIT ;ALREADY ASSIGNED TO US
JUMPN TEM,SETRC ;JUMP IF ASSIGNED TO ANYONE ELSE
MOVE TAC,[TTYATC,,ASSCON!ASSPRG]
TDNN TAC,DEVMOD(DDB) ;SKIP IF THE DEVICE IS ALREADY CLAIMED.
JRST GOTIT ;NOT CLAIMED. JUMP IF PJOBN=0
SETRC: CAME TAC1,[SIXBIT /Y/]
CAMN TAC1,[SIXBIT /YES/]
JRST SETWAT ;GO WAIT.
TYPE {Would you do IO to the disk instead?}
CLRBFI
PUSHJ P,UCTEXT
CAME TAC1,[SIXBIT /Y/]
CAMN TAC1,[SIXBIT /YES/]
JRST SETERZ ;OK. MAKE IO HAPPEN TO DISK.
POP P,UCHN ;EXIT, LOSING.
POP P,UUOPC(J)
POP P,UUO
HRRZ DDB,JBTDVW(J) ;IN CASE WE NEED THIS ANYWAY (FOR ERR PRINT)
JRST UINXIT
SETERZ: MOVSI TAC,'DSK' ;SET IO TO DSK.
POP P,UCHN
POP P,UUOPC(J)
POP P,UUO
JRST UINITK
SETWAT: MOVEI TAC1,DWQ
MOVNM TAC1,JOBQUE(J)
PUSHJ P,WSCHED
HRRZ DDB,JBTDVW(J)
LDB TEM,PJOBN
CAIN TEM,(J) ;SEE IF WE HAVE IT ALREADY (REASSIGN)
JRST GOTIT
JUMPN TEM,SETWAT ;JUMP IF SOMEONE ELSE HAS IT.
MOVE TAC,[TTYATC,,ASSCON+ASSPRG]
TDNE TAC,DEVMOD(DDB)
JRST SETWAT ;DEVICE MAY BE ASSIGNED TO JOB ZERO!
GOTIT: TYPE {Gotcha!}
POP P,UCHN
POP P,UUOPC(J)
POP P,UUO
MOVE DAT,(P)
JRST UINITG
UCTEXT: INCHWL JOBTM5 ;INPUT A CHARACTER WHICH WE WILL THROW AWAY!
MOVEI DAT,TTIBUF(DDB) ;SET UP ADDRESS OF DATA BUFFER
PUSHJ P,CTEXT1
PUSHJ P,SKPBRK ;MOVE OUT TO END OF LINE
POPJ P,
;ENTER, LOOKUP - LONG DISPATCH TABLE UUOS
;HERE ONLY IF DEVICE HAS LONG DISPATCH TABLE
;DISPATCH TO DEVICE DEPENDENT SERVICE ROUTINE
;ENTER UUO - ENTER FILE NAME IN DIRECTORY
UDEN: MOVEI TAC,CLSIN
TLNN DDB,ENTRB ;HAS THIS FILE BEEN OPENED FOR WRITING?
JRST UDEN1 ;NO, SUPRESS CALL ON CLOSE CODE
TLNN DDB,OCLOSB ;FILE OPEN?
PUSHJ P,UDLKC ;YES. CLOSE IT.
UDEN1: TLO IOS,IOBEG
TRZ IOS,776000
MOVEM IOS,DEVIOS(DDB)
TLO DDB,ENTRB
TLZ DDB,OCLOSB
HLLM DDB,USRJDA(UCHN) ;STORE UUO BITS
JRST DEN(DSER)
UDLKC: PUSH P,UUO
HRRI UUO,(TAC)
PUSHJ P,CLOSE1
POP P,UUO
JRST WAIT1
;LOOKUP UUO - LOOKUP FILE NAME IN DIRECTORY
UDLK: MOVEI TAC,CLSOUT
TLNN DDB,ICLOSB ;FILE OPEN?
PUSHJ P,UDLKC ;YES. CLOSE IT
TDZ IOS,[IOEND,,776000]
MOVEM IOS,DEVIOS(DDB)
TLO DDB,LOOKB
TLZ DDB,ICLOSB
HLLM DDB,USRJDA(UCHN) ;STORE UUO BITS
JRST DLK(DSER)
;RENAME, UTPCLR, USETO, USETI, UGETF, MTAPE
;RENAME UUO - HERE ON SHORT DISPATCH TABLE DEVICES TOO
URENAM: MOVE TAC,DEVMOD(DDB) ;IS THIS DEVICE A LONG DISPATCH TABLE?
TLNE TAC,DVLNG
JRST DRN(DSER) ;YES, DISPATCH TO SERVICE ROUT.
JRST CPOPJ1 ;NO. GIVE SKIP RETURN TO USER
UDSO: JRST DSO(DSER) ;USETO UUO - SET NEXT OUTPUT BLOCK NUMBER
UDSI: JRST DSI(DSER) ;USETI UUO - SET NEXT INPUT BLOCK NUMBER
UDGF: JRST DGF(DSER) ;UGETF UUO - GET NEXT FREE BLOCK
UMTAPE: JRST DMT(DSER) ;MTAPE UUO - CONTROL FUNCTIONS.
;UTPCLR - CLEAR DECTAPE DIRECT.
UTPCLR: MOVE TAC,DEVMOD(DDB) ;IS THIS A LONG DISPATCH TABLE?
TLNN TAC,DVLNG
POPJ P, ;NO,RETURN
JRST DCLR(DSER) ;YES, DISPATCH
;SETFILE - GET A FILE NAME FROM USER'S TERMINAL
;CALLED FROM INPUT (OUTPUT) UUOS WHEN A LOOKUP (ENTER) IS NEEDED.
CLRIN: PUSHJ P,SKPBRK
SETFILE:TYPE { Please type file name: }
CLRBFI
INCHWL JOBTM5
MOVEI DAT,TTIBUF(DDB) ;GODDAMN SYSTEM
PUSHJ P,CTEXT1 ;READ IN FILE NAME IF ANY
JUMPE TAC1,CLRIN ;ERROR IF NOTHING WAS TYPED.
XCTR XW,[MOVEM TAC1,JOBTM1] ;STORE FILE NAME.
PUSHJ P,CTEXT1 ;SCAN EXTENSION
XCTR XW,[HLLZM TAC1,JOBTM2]
XCTR XW,[SETZM JOBTM3]
PUSHJ P,PJPGNO ;SEEK PPN
XCT SGPPN ;NONE GIVEN. USE DEFAULT
XCTR XW,[MOVEM AC2,JOBTM4]
JRST SKPBRK ;SCAN TO END OF LINE, RETURN.
;INPUT UUO
;1) IF OUTPUT ACTIVE ON THIS CHANNEL, WAIT FOR IT TO COMPLETE.
;2) IF DUMP MODE, WAIT FOR DEVICE INACTIVE, CALL SERVICE
; ROUTINE TO START INPUT, WAIT TILL COMPLETE, THEN RETURN TO USER.
;3) IF NO BUFFER RING SETUP, SET UP 2 RING BUFFER.
;4) IF FIRST REFERENCE, START SERVICE ROUTINE, GO TO
;5) FLAG CURRENT BUFFER AS FREE TO RECEIVE MORE INPUT
; (USE BIT SET TO 0).
; START SERVICE ROUTINE FILLING FIRST BUFFER WITH USE BIT 0
; (NEXT BUFFER OR ONE AHEAD OF IT)
; (SERVICE ROUTINE WILL SET USE BIT WHEN IT FINISHES FILLING
; BUFFER).
;7) IF NEXT INPUT BUFFER IS FULL OF DATA, GO TO 10).
;8) PUT JOB IN IO WAIT TILL NEXT BUFFER FILLED.
;9) IF NEXT INPUT BUFFER STILL NOT FILLED, CHECK FOR END
; OF FILE OR ERROR BITS SET BY SERVICE ROUTINE.
;10) CONVERT WORD COUNT AS STORED BY SERVICE ROUTINE IN THIRD
; WORD OF BUFFER TO ITEM COUNT AND STORE IN THIRD WORD
; OF HEADER (ITEM COUNT) ALSO SET BYTE POINTER (SECOND
; WORD OF HEADER) AND RETURN TO USER.
;INPUT UUO.
↑IN: MOVE TAC,DEVMOD(DDB)
TLNE TAC,DVDSK ;SKIP IF DEVICE DOESN'T NEED A LOOKUP
TLNE DDB,LOOKB ;SKIP IF NO LOOKUP WAS DONE.
JRST IN2 ;NO LOOKUP NEEDED, OR ALREADY DONE.
PUSH P,UUO ;SAVE COPY OF THE ORIGINAL UUO
PUSH P,UUOPC(J) ;SAVE OUR RETURN PC
PUSH P,UCHN ;AND CHANNEL NUMBER
TYPE {Lookup needed.} ;MESSAGE TO USER.
JRST IN4
IN5: TYPE {Lookup failed.} ;HERE FROM BELOW.
IN4: PUSHJ P,SETFILE ;GET FILE NAME FROM USER
MOVE UUO,[LOOKUP JOBTM1] ;IMAGE OF A UUO TO XCT.
MOVE UCHN,(P) ;RELOAD UCHN FROM STACK (CHANNEL NO.)
DPB UCHN,PUUOAC ;STORE CHANNEL NUMBER INTO AC UUO
XCT UUO ;LOOKUP, WITH PROPER CHANNEL NO.
JRST IN5 ;LOOKUP FAILED.
POP P,UCHN ;LOOKUP OK. RESTORE STATE.
POP P,UUOPC(J)
POP P,UUO
MOVE DDB,USRJDA(UCHN) ;RESTORE OTHER IMPORTANT THINGS.
HRRZ DSER,DEVSER(DDB)
MOVE IOS,DEVIOS(DDB)
IN2: TLNE IOS,IO ;IS DEVICE DOING OUTPUT NOW?
PUSHJ P,WAIT1 ;WAIT FOR OUTPUT TO FINISH.
TLO DDB,INPB ;FLAG INPUT UUO HAS BEEN DONE.
TLZ DDB,ICLOSB ;NO INPUT CLOSE YET
HLLM DDB,USRJDA(UCHN) ;FLAGS GO TO LH OF JDA ENTRY
LDB TAC,PIOMOD ;IO MODE
CAIL TAC,SD ;DUMP MODE? (SD,D,DR)
JRST INDMP ;YES.
TLNN DDB,IBUFB ;WAS THERE AN INPUT BUFFER HEADER IN INIT?
JRST ADRERR ;NO. LOSE NOW.
IN1: HRR JBUF,DEVBUF(DDB) ;GET ADDRESS OF BUFFER HEADER
MOVSI TAC,IOUSE ;BUFFER IN USE BIT
MOVE IOS,DEVIOS(DDB) ;GET A NEW COPY OF IOS
;BUFFER HEADER (JBUF) WILL BE 0 IF VIRGIN, OR NEGATIVE IF INBUF WAS DONE.
XCTR XR,[SKIPG (JBUF)] ;SKIP IF BUFFER IS SETUP AND HAS BEEN USED
JRST INPUTF ;SET UP BUFFER IF NECESSARY. DO FIRST IN
PUSHJ P,BCHECK ;CHECK ADDRESS OF BUFFERS.
JRST ADRERR ;ADDRESS CHECK
XCTR XR,[MOVE TAC1,(JBUF)] ;TAC1←ADDRESS OF CURRENT BUFFER.
MOVE IOS,DEVIOS(DDB)
XCTR XR,[TDNN TAC,(TAC1)] ;SKIP IF BUFFER HAD BEEN BUSY.
JRST INPT1 ;MUST BE VIRGIN BUFFER. GO KICK DEVICE.
;FLAG CURRENT BUFFER AS FREE TO RECEIVE MORE INPUT
XCTR XRW,[ANDCAB TAC,(TAC1)] ;CLEAR IOUSE. GET POINTER TO NEXT BUFFER
XCTR XRW,[HRRM TAC,(JBUF)] ;ADVANCE BUFFER HEADER TO NEXT BUFFER
TRNE IOS,IOACT ;IS DEVICE ALREADY ACTIVE?
JRST INPT0C ;YES. SEE IF THERE'S A BUFFER READY
MOVE AC1,DEVMOD(DDB)
TLNN AC1,DVTTY ;TTY? (FILL ONE BUFFER AT A TIME)
XCTR XR,[HRR TAC,(TAC)] ;NO. GET POINTER 1 BUFFER AHEAD OF NEXT BUF
XCTR XR,[SKIPL (TAC)] ;IS THE USE BIT SET?
PUSHJ P,CALIN ;NO, START DEVICE FILLING EMPTY BUFFER
INPT0C: XCTR XR,[HRR TAC1,(TAC1)] ;GET USE BIT FOR NEXT BUFFER
INPT0A: XCTR XR,[SKIPGE (TAC1)] ;SKIP UNLESS BUFFER ALREADY FULL.
JRST INPUT2 ; HERE'S A BUFFER FOR THE USER
INPT2: PUSHJ P,WSYNC ;WAIT UNTIL BUFFER FILLED.
XCTR XR,[SKIPL (TAC1)] ;CHECK TO MAKE SURE BUFFER IS FILLED
JRST INEOF ;NO, MUST BE EOF OR ERROR
INPUT2: XCTR XR,[HRRZ ITEM,1(TAC1)] ;GET ACTUAL WC FROM THE BUFFER.
JRST IOSETC ;SET ITEM COUNT AND BYTE POINTER. RETURN.
INPT1: TRNN IOS,IOACT ;IS DEVICE ALREADY ACTIVE?
PUSHJ P,CALIN ;NO. KICK IT.
JRST INPT2 ;WAIT FOR IT.
;HERE IF WE GOT BACK FROM DEVICE SERVICE WITHOUT A FULL BUFFER.
INEOF: TDNN IOS,[IOEND,,IODEND!IODERR!IOBKTL!IODTER!IOIMPM] ;EOF OR ERROR?
JRST INEOFE ;NO, SYSTEM ERROR.
TLNE IOS,IOEND ;IS THIS EOF?
TRO IOS,IODEND ;YES, SET USER EOF BIT.
IORM IOS,DEVIOS(DDB)
POPJ P, ;RETURN TO USER'S PROGRAM
INEOFE: JSP DAT,UERROR ;MONITOR ERROR AT UUO LEVEL
POPJ P,
;MORE INPUT - BCHECK, CALLIN, INPUTF, INDMP
;HERE WHEN BUFFERS ARE EITHER NON EXISTANT, OR HAVE NEVER BEEN USED.
INPUTF: XCTR XRW,[ANDCAB TAC,(JBUF)] ;MARK HEADER - BUFFERS HAVE BEEN USED
JUMPE TAC,INPUT3 ;JUMP IF NO BUFFERS EXIST YET.
PUSHJ P,BCHECK ;CHECK BUFFERS THAT HE'S GOT
JRST ADRERR ;ADDRESS CHECK
XCTR XR,[MOVE TAC1,(JBUF)] ;POINTER TO FIRST BUFFER
XCTR XR,[SKIPG (TAC1)] ;SKIP IF BUFFER IS FREE TO BE FILLED.
JRST INPUT2 ;BUFFER IS FULL. GIVE IT TO USER ????
HRRM TAC,DEVIAD(DDB) ;STORE BUFFER ADDRESS FOR DEVICE.
PUSHJ P,CALIN ;START DEVICE.
JRST INPT0A ;WAIT FOR IT TO FILL.
INPUT3: HRRI UUO,2 ;NO BUFFERS EXIST YET - MAKE 2
PUSHJ P,UINBF
HRRI UUO,0 ;CLEAR RIGHT HALF
JRST IN1 ;BACK TO IN1 AND INPUTF AGAIN.
;HERE FOR DUMP MODE INPUT. NOTE THAT ADCSER (XGPSER) THINK THEY CAN RETURN
;TO USER WITHOUT WAITING BY "JRST TPOPJ" TO SKIP WSYNC
INDMP: PUSHJ P,DDI(DSER) ;CALL SERVICE ROUTINE
JRST WSYNC ;WAIT FOR IO TO FINISH AND RETURN TO USER.
CALIN: TLNE IOS,IOEND ;CALL DEVICE SERVIC INPUT ROUTINE
POPJ P, ;END OF FILE ALREADY. RETURN.
PUSH P,TAC1
PUSH P,JBUF
HRRZ AC1,DEVIAD(DDB) ;CHECK BUFFER ADDRESS.
CAIG AC1,JOBPFI
JRST ADRERR ;ERROR - IN PROTECTED PART OF JOBDAT
XCTR XR,[HLRZ AC2,(AC1)] ;GET LENGTH OF BUFFER
TRZ AC2,IOUSE ;CLEAR USE BIT IN CASE IT IS ON(TTY)
ADD AC1,AC2
XCTR XRW,[MOVES (AC1)] ;ADDRESS CHECK LAST ADDRESS OF BUFFER
PUSHJ P,DIN(DSER) ;DISPATCH TO IO SERVICE ROUTINE
POP P,JBUF
POP P,TAC1
POPJ P,
↑BCHECK:MOVEI AC1,(JBUF)
CAIG AC1,JOBPFI ;CHECK PROTECTED PART THIS WAY
POPJ P,
XCTR XRW,[MOVES AC1,(AC1)] ;AND THE REST THIS WAY
HRRZ AC1,AC1
CAIG AC1,JOBPFI
POPJ P,
XCTR XRW,[MOVES (AC1)]
JRST CPOPJ1
;OUTPUT UUO - CALLING SEQUENCE
; OUTPUT D,
; EXIT
;OR
; OUTPUT D, ADR
; EXIT
;IF INPUT IS ACTIVE, WAIT FOR IT TO COMPLETE.
;IF DUMP MODE WAS SELECTED BY THE LAST INIT UUO OR SETSTS UUO
; THE PROGRAM WAITS UNTIL THE DEVICE IN INACTIVE AND THEN
; WRITES THE DUMPFILE AND RETURNS CONTROL TO THE USER'S PROGRAM
; WHEN IO HAS COMPLETED.
;IF THE MODE IS NOT DUMP, THEN
;1) IF ADR IS NOT ZERO, WAIT FOR DEVICE TO BECOME INACTIVE THEN SET THE
; CURRENT BUFFER ADDRESS EQUAL TO ADR AND AN INDICATOR (JBFADR0)
; SPECIFYING THAT THIS BUFFER RING HAS NEVER BEEN REFERENCED FROM THE
; USER'S PROGRAM BY AN INPUT OR AN OUTPUT UUO. OTHERWISE, GO TO
; 2) DIRECTLY.
;2) IF THE BUFFER RING HAS NEVER BEEN REFERENCED (JBFADR0=1), THE
; BUFFER IS CLEARED, IOUSE SET TO ZERO AND
; IF THE CURRENT BUFFER ADDRESS IS ZERO, A TWO BUFFER RING IS SET UP.
; THEN GO TO 8
;
;3) IF THE BUFFER RING HAS BEEN REFERENCED (JBFADR0=0 ,THEN A CHECK IS
; MADE TO DETERMINE IF THE WORD COUNT IS TO BE COMPUTED.
; IF THE WORD COUNT IS TO BE COMPUTED (IOWC=0), IT IS SET EQUAL
; TO THE ADDRESS FOR THE LAST DATA WORD MINUS THE ADDRESS OF THE
; BUFFER MINUS ONE.
;4) IOUSE IS SET TO ONE, INDICATING THAT THE BUFFER IS FULL OR BEING
; EMPTIED, AND THE CURRENT BUFFER ADDRESS IS ADVANCED.
;5) IF THE DEVICE IS NOT ACTIVE (IOACT=0), OUTPUT IS STARTED.
;6) IF THE CURRENT BUFFER IS FULL OR BEING EMPTIED (IOUSE=1),
; THE PROGRAM WAITS UNTIL THE DEVICE FINISHES THE BUFFER
; (THE OUTPUT SERVICE ROUTINE CLEARS THE USE BIT WHEN
; IT FINISHES OUTPUTTING A BUFFER).
;7) THE CURRENT BUFFER IS CLEARED.
;8) THE ITEM POINTER IS INITIATED TO THE CURRENT BUFFER ADDRESS+1
; AND THE ITEM COUNT IS SET TO THE PRODUCT OF THE BUFFER SIZE
; MINUS ONE AND THE INTEGER PART OF 36/BYTE SIZE.
;9) RETURN TO THE USER'S PROGRAM
;UOUT - OUTPUT UUO
UOUT: MOVE TAC,DEVMOD(DDB)
TLNE TAC,DVDSK
TLNE DDB,ENTRB
JRST UOUT1 ;NOT DISK OR ALREADY ENTERED.
PUSH P,UUO
PUSH P,UUOPC(J)
PUSH P,UCHN
TYPE {Enter needed.}
JRST OUT4
OUT3: TYPE {Enter failed.}
OUT4: PUSHJ P,SETFILE
MOVE UUO,[LOOKUP JOBTM1]
MOVE UCHN,(P)
DPB UCHN,PUUOAC
XCTR XR,[PUSH P,JOBTM4] ;LOOKUP CLOBBERS THIS.
XCT UUO ;LOOKUP
JRST OUT5 ;DOESN'T EXIST OR ENTER WILL DETECT ERROR
XCTR XW,[POP P,JOBTM4]
TYPE {File already exists. Is it OK to delete it?}
CLRBFI
INCHWL JOBTM5
MOVEI DAT,TTIBUF(DDB)
PUSHJ P,CTEXT1
PUSHJ P,SKPBRK
CAME TAC1,['Y ']
CAMN TAC1,['YES ']
JRST OURDN ;LET'S GO OVERWRITE.
JRST OUT4 ;LET HIM TRY AGAIN.
OUT5: XCTR XW,[POP P,JOBTM4] ;RESTORE PPN
OURDN: XCTR XRW,[HLLZS JOBTM2] ;CLEAR CRUD FROM LOOKUP
XCTR XW,[SETZM JOBTM3]
MOVE UUO,[CLOSE]
MOVE UCHN,(P)
DPB UCHN,PUUOAC
XCT UUO ;MAKE SURE WE DON'T GET INTO ALTER MODE
MOVE UUO,[ENTER JOBTM1]
MOVE UCHN,(P)
DPB UCHN,PUUOAC
XCT UUO
JRST OUT3 ;ENTER FAILED. LOOP.
POP P,UCHN
POP P,UUOPC(J)
POP P,UUO
MOVE DDB,USRJDA(UCHN)
MOVE IOS,DEVIOS(DDB)
HRRZ DSER,DEVSER(DDB)
UOUT1: TLO DDB,OUTPB ;SET OUTPUT UUO BIT. ENTER HAS BEEN DONE
TLZ DDB,OCLOSB ;CLEAR CLOSE OUTPUT BIT. FALL INTO OUT.
;OUT
;HERE FROM DEVICE SERVICE ROUTINES ON CLOSE UUO
↑OUT: TLNN IOS,IO ;IS THIS DEVICE ALREADY DOING INPUT?
PUSHJ P,WAIT1 ;YES, WAIT TILL IT BECOMES INACTIVE
HLLM DDB,USRJDA(UCHN) ;SAVE NEW BIT SETTINGS.
LDB TAC,PIOMOD ;GET DATA MODE SET BY INIT OR SETSTS.
CAIL TAC,SD ;IS IT DUMP MODE(SD,DR,D)?
JRST OUTDMP ;YES.
TLNN DDB,OBUFB ;IS THERE AN OUTPUT BUFFER HEADER?
JRST ADRERR ;NO, ERROR
TRNN UUO,777774 ;IS USER CHANING RING ADDRESS?
JRST OUT1 ;NO
PUSHJ P,WAIT1 ;WAIT FOR DEVICE
HLR JBUF,DEVBUF(DDB) ;GET ADDRESS OF BUFFER HEADER
XCTR XRW,[HRRM UUO,(JBUF)] ;STORE NEW RING ADDRESS IN HEADER
HRRM UUO,DEVOAD(DDB) ;SET ADDRESS OF NEXT BUFFER FOR DEVICE
MOVSI TAC,IOUSE
XCTR XRW,[IORM TAC,(JBUF)] ;FLAG THE RING IS NOT INITIALIZED.
OUT1: HLR JBUF,DEVBUF(DDB) ;ADDRESS OF OUTPUT BUFFER HEADER
XCTR XR,[SKIPG TAC1,(JBUF)] ;SKIP IF RING HAS BEEN REFERENCED.
JRST OUTF ;RING NOT SET UP OR FIRST REFERENCE TO RING
PUSHJ P,BCHECK ;RING SET-UP, CHECK IT
JRST ADRERR ;ADDRESS CHECK
XCTR XR,[SKIPG (TAC1)];DID WE GET BACK TO HIM WITH NO FREE BUFFERS?
JRST OUTAGN ;YES, LET DEVICE WORRY ABOUT IT!
AOS JBUF ;COMPUTE WORD COUNT FROM BYTE POINTER
XCTR XR,[HRRZ TAC,(JBUF)] ;GET RH OF BYTE POINTER.
ADDI TAC1,1 ;REL. ADDR. OF 3RD WORD IN BUFFER.
SKIPN TAC ;BYTE POINTER INITIALIZED ;DWP(JS)
TDZA TAC,TAC ;NO. SET WORD COUNT = 0 ;DWP(JS)
SUB TAC,TAC1 ;DISTANCE FILLED BY USER.
TRNE IOS,IOWC ;DOES USER WANT SYSTEM TO COMPUTE WORD
;COUNT FROM BYTE POINTER?
JRST OUT2 ;NO.
HRRZ AC1,TAC1 ;YES, PROCEED IF ADDR. OF WORD COUNT IN BOUNDS
ADDI AC1,(TAC) ;CHECK ENDING ADDRESS.
XCTR XRW,[MOVES (AC1)]
SUBI TAC1,1 ;BACK UP POINTER TO LENGTH AND LINK WORD
XCTR XLB,[LDB AC1,[POINT 17,(TAC1),17]]
CAMLE TAC,AC1 ;IS THERE MORE DATA THAN THERE IS BUFFER?
JRST ADRERR ;YES, USER ERROR
ADDI TAC1,1 ;RESET BUFFER WORD COUNT POINTER
XCTR XRW,[HRRM TAC,(TAC1)] ;STORE WORD COUNT IN 3RD WORD OF BUFFER.
; OUTPUT UUO - HERE, WE ADVANCE BUFFER ADDRESS, START OUTPUT, AND WAIT FOR
; OUTPUT TO FINISH BEFORE RETURNING TO USER
OUT2: SUBI JBUF,1 ;REL. ADDR. OF 1ST WORD IN HEADER
;(POINTER TO CURRENT BUFFER).
SUBI TAC1,1 ;REL. ADDR. OF 2ND WORD IN BUFFER
;(LINK TO NEXT BUFFER).
MOVSI TAC,IOUSE ;FLAG CURRENT BUFFER CONTAINS ACTIVE DATA.
XCTR XRW,[IORB TAC,(TAC1)]
XCTR XRW,[HRRM TAC,(JBUF)] ;ADVANCE CURRENT BUFFER ADDRESS
XCTR XRW,[HLLZS 1(JBUF)] ;ZERO RH OF BYTE PTR - NOT INITIALIZED
OUTAGN: XCTR XW,[SETZM 2(JBUF)] ;CAN'T USE NEXT BUFFER YET!! RPH
MOVE IOS,DEVIOS(DDB) ;IS DEVICE ACTIVE?
MOVSI AC1,DEVAOA ;CAN WE CALL SERVICE ROUTINE ANYWAY?
TDNN AC1,DEVCMR(DDB) ;SKIP IF WE CAN CAN SERVICE ROUTINE.
TRNN IOS,IOACT ;ONLY CALL SERVICE ROUTINE IF IOACT OFF.
PUSHJ P,DOU(DSER) ;CALL DEVICE TO START (OR CONTINUE) OUTPUT.
HLR JBUF,DEVBUF(DDB) ;JBUF ← REL. ADDR. OF BUFFER HEADER
XCTR XR,[MOVE TAC1,(JBUF)] ;TAC1 ← REL. ADDR. OF 2ND WORD OF BUFFER.
XCTR XR,[SKIPL (TAC1)] ;HAS SERVICE ROUTINE EMPTIED NEXT BUFFER
JRST OUTS ;YES, CLEAR AND RETURN
TRNE IOS,740000 ;ANY ERRORS TO SHOW LOSER? RPH
POPJ P, ;YES, LET HIM SEE THEM RPH
PUSHJ P,WSYNC ;NO, WAIT.
JRST OUTS ;BUFFER SHOULD BE FREE. CLEAR IT AND RETURN
OUTF: XCTR XR,[SKIPE TAC1,(JBUF)] ;FIRST OUTPUT. SETUP BUFFER RING.
JRST OUTF1
HRRI UUO,2
PUSHJ P,UOUTBF
HLR JBUF,DEVBUF(DDB)
OUTF1: PUSHJ P,BCHECK ;CHECK BUFFER ADDRESSES
JRST ADRERR ;ADDRESS CHECK
MOVSI TAC,IOUSE
XCTR XRW,[ANDCAB TAC,(JBUF)] ;IOUSE←0
HRRM TAC,DEVOAD(DDB)
OUTS: XCTR XR,[HRRZ TAC,(JBUF)] ;CLEAR NEXT OUTPUT BUFFER.
PUSHJ P,BUFCLR ;CLEAR BUFFER. (MAY BOMB VIA UADRER)
XCTR XR,[HRR TAC1,(JBUF)]
XCTR XLB,[LDB ITEM,[POINT 17,(TAC1),17]]
SOJA ITEM,IOSETC
;ADDRESS+1
;JBFCTR:=(BUFFER SIZE-1)*[36/BYTE SIZE]
;RETURN TO USER'S PROGRAM
OUTDMP: PUSHJ P,DDO(DSER) ;NOTE THAT XGPSER (AND ADCSER) THINK THEY CAN RETURN
; WITHOUT WAITING BY JRST TPOPJ
JRST WSYNC ;WAIT BEFORE RETURNING TO USER
;RELEASE A DEVICE
RELEA0:
↑RELEA3:
TRZ UUO,-1 ;CLOSE BOTH INPUT AND OUTPUT. HERE FROM IORELS
↑RELEA1: ;ALLOW SUPPRESION ON RELEASE UUO
PUSHJ P,CLOSE1 ;(CLOSE PRESERVES J AND DSER)
PUSHJ P,WAIT1 ;WAIT FOR DEVICE TO BECOME INACTIVE
↑RELEA5:
PUSHJ P,DRL(DSER) ;DISPATCH TO DEVICE SERVICE ROUTINE
LDB J,PJOBN ;MAKE SURE J IS SET TO JOB NUMBER
MOVEI IOS,IOACT ;CLEAR IO ACTIVE BIT
ANDCAB IOS,DEVIOS(DDB) ;AND RETURN WITH IOS SET
SETZB DAT,USRJDA(UCHN) ;CLEAR DEVICE ASSIGNMENT
SKIPGE TAC,USRHCU(PID)
MOVEI TAC,17
RELEA4: HRRZ TAC1,USRJDA(TAC)
JUMPN DAT,RELE4A ;NON-ZERO CHAN. ALREADY?
MOVE DAT,TAC1 ;NO, SET DAT WHEN FIRST(HIGHEST) FOUND
MOVEM TAC,USRHCU(PID) ;STORE HIGHEST IN USE CHANNEL
RELE4A: CAIE TAC1,(DDB) ;IS THIS DEVICE SAME AS ONE BEING RELEASED?
SOJGE TAC,RELEA4
JUMPGE TAC,CPOPJ ;DON'T FLUSH THIS DDB IF OPEN ON ANOTHER CHANNEL
SKIPL TAC,JBTIOP(J)
JRST RELE4B
RELE4C: HRRZ TAC1,(TAC) ;ALSO SEARCH IOPDL FOR EXISTING SAME DDB
CAIN TAC1,(DDB)
POPJ P,
ADD TAC,[1,,1]
AOBJN TAC,RELE4C
RELE4B: HLLZS DEVIAD(DDB) ;CLEAR INPUT BUFFER ADDRESS
HLLZS DEVOAD(DDB) ;AND OUTPUT BUFFER ADDRESS.
;CALLED FROM ERROR STOP ROUTINE(ESTOP)
↑RELEA9:
MOVE TAC,DEVNAM(DDB) ;IS THIS SYSTEM TAPE?
CAME TAC,[SIXBIT /DSK/] ;DSK IS NEVER QUEUED
CAME TAC,SYSTAP
JRST RELEA7 ;IS DISK OR NOT SYSTEM TAPE
MOVSI TAC,777760 ;PREPARE TO ZERO OUT MOST OF DEVIAD AND DEVOAD
ANDCAM TAC,DEVIAD(DDB)
ANDCAM TAC,DEVOAD(DDB)
SKIPN STUSER ;HAS COUNT ALREADY BEEN REDUCED AT ESTOP?
JRST RELEA7 ;YES
SETZM STUSER ;YES, CLEAR SYSTEM USER NO.
SOSL STREQ ;YES, REDUCE COUNT
SETOM STAVAL ;SOMEONE IS WAITING, SET AVAILABLE FLAG/
RELEA7: MOVEI TAC1,ASSPRG ;CLEAR ASSIGNED BY PROGRAM BIT
↑RELEA6:
ANDCAB TAC1,DEVMOD(DDB) ;CALLED FROM DEASSIGN
TRZ TAC1,777 ;CLEAR JOB NO. FIELD
TDNE TAC1,[XWD TTYATC,ASSCON+ASSPRG]
POPJ P, ;DEVICE ASSIGNED BY OTHER MEANS TOO
DPB TAC1,PJOBN ;CLEAR JOB NUMBER
MOVE TAC1,DEVCMR(DDB)
TLNN TAC1,DEVSHR ;SHARABLE DEV?
JRST RELDVW ;NO - WAKE UP WAITERS IF ANY
PUSH P,DAT ;IF AT COMMAND LEVEL, SAVE TTY POINTER
PUSH P,DDB ;AND DDB ADDRESS
PUSH P,DSER
HRRZ DSER,DEVSER(DDB) ;GET POINTER TO DEVICE DEPENDENT ROUTINES
PUSHJ P,DGIVDD(DSER) ;RETURN DDB TO STORAGE
POP P,DSER
POP P,DDB
POP P,DAT ;RESTORE COMMAND POINTER
POPJ P,
;RELDVW (RELEAS) - IF THERE IS ANYONE WAITING FOR THE DEVICE WAKE HIM UP.
RELDVW: PUSH P,DDB
PUSH P,UUO
PUSH P,DAT
PUSH P,J ;SAVE OLD JOB NUMBER
HRRZS DDB
MOVEI DAT,DVWSCAN ; SCAN ALL JOBS IN DEVICE WAIT
JSP UUO,QSCAN
JRST RELDVX
CAME DDB,JBTDVW(J)
JRST (AC1) ; GO RESCAN
MOVEI AC1,RUNQ
MOVNM AC1,JOBQUE(J) ; WAKE HIM UP
PUSHJ P,REQUE
RELDVX: POP P,J
POP P,DAT
POP P,UUO
POP P,DDB
POPJ P,
;STATO, STATZ, GETSTS UUOS. USTATO, USTATZ, USTATS
;CALL: STATO D,MASK
; EXIT1 ALL SELECTED BITS ARE 0
; EXIT2 SOME SELECTED BITS ARE 1
;TESTS THOSE BITS OF I/O STATUS WORD OF DEVICE ON USER'S CHANNEL D
;WHICH ARE SELECTED BY MASK.
USTATO: TRNN IOS,(UUO) ;SKIP IF ANY INDICATED BITS ARE ONE
POPJ P, ;RETURN TO USER
JRST CPOPJ1 ;SKIP RETURN TO USER.
;CALL: GETSTS D,ADR
; EXIT ALWAYS RETURNS HERE
;STORES I/O STATUS WORD OF DEVICE ON CHANNEL D IN LOCATION ADR.
USTATS: HRRZ TAC,IOS ;GET USER HALF OF IOS
JRST STOTAC ;ADDRESS CHECK AND STORE IN USER AREA
;CALL: STATZ D,MASK
; EXIT1 SOME SELECTED BITS ARE 1
; EXIT2 ALL SELECTED BITS ARE 0
;TESTS THOSE BITS OF I/O STATUS WORD OF DEVICE ON USER'S CHANNEL D
;WHICH ARE SELECTED BY MASK.
USTATZ: TRNE IOS,(UUO) ;SKIP IF ALL INDICATED BITS ARE ZERO
POPJ P,
JRST CPOPJ1
;TIN, TOUT - IN AND OUT UUOS.
;IN UUO - LIKE INPUT - SKIPS IF EOF OR ERRORS
TIN: PUSHJ P,IN ;DO INPUT UUO
TRNE IOS,IOBKTL+IODTER+IODERR+IOIMPM+IODEND
JRST CPOPJ1
POPJ P,
;OUT UUO - LIKE OUTPUT - SKIPS IF ERRORS
TOUT: PUSHJ P,UOUT ;DO OUTPUT UUO
TRNE IOS,IOBKTL+IODTER+IODERR+IOIMPM
JRST CPOPJ1
POPJ P,
;SPACEWAR UUOS
SPCWGO: MOVEI UUO,(TAC) ;SETUP STARTING ADDRESS.
HLLZ UCHN,TAC ;MODE BITS IN UCHN LEFT
HLR UCHN,TAC ;TICKS IN UCHN RIGHT
AND UCHN,[740000,,17] ;FLUSH IRRELEVANT BITS
JRST SPCWG1
;UUO43 IS THE SPACEWAR UUO. SEE SPWSER FOR MORE DETAILS - JS
USPCWAR:ANDI UCHN,17 ;TICKS ONLY
SPCWG1: MOVE TAC,JBTPRV(J)
TLNE TAC,LUPPRV
JRST SPWCON ;LET SPACE WAR SERVICE FIGURE OUT WHAT TO DO
JRST UUOERR ;ILLEGAL FOR REMOTE JOBS
BEND APRSER